The EvaluatePolynomial command evaluates a dense univariate polynomial at a ComplexBox object. It does this in a manner that sometimes produces a smaller radius than simple evaluation using the standard arithmetic operations.

The first argument is a ComplexBox object, representing the value at which the polynomial is to be evaluated.

The second argument is a list of $n+1$ coefficients of the polynomial to be evaluated, where $n$ is the degree of the polynomial. The first entry is the constant coefficient, the second the linear coefficient, and so on. Each coefficient can be a ComplexBox object or a complex constant.

Consider the polynomial $49x^4-188x^2+72x+292$. Evaluate it at the ComplexBox object with center $\mathrm{-1.47}$ and radius $0.01$ in the imaginary direction. We first use simple evaluation using the regular arithmetic operators.

poly := 292 + 72*x - 188*x^2 + 49*x^4;

$\mathrm{poly}≔49x^4-188x^2+72x+292$

cb := ComplexBox(RealBox(-1.47), RealBox(0, 0.01));

$\mathrm{cb}≔⟨\text{ComplexBox:}\text{[-1.47 +/- 1.16415e-10]}+\text{[0 +/- 0.01]}\cdot \mathrm{I}⟩$

eval(poly, x = cb);

$⟨\text{ComplexBox:}\text{[8.71575 +/- 0.0823313]}+\text{[0 +/- 12.4735]}\cdot \mathrm{I}⟩$

The radius of the result is smaller if we first convert the polynomial to Horner form.

poly_horner := convert(poly, 'horner');

$\mathrm{poly\_horner}≔292+\left(72+\left(49x^2-188\right)x\right)x$

eval(poly_horner, x = cb);

$⟨\text{ComplexBox:}\text{[8.71575 +/- 0.0611543]}+\text{[0 +/- 6.24749]}\cdot \mathrm{I}⟩$

However, this is still a severe overestimation of the radius. We write $x=-1.47+\mathrm{I}\mathrm{\epsilon }$ and expand $\mathrm{poly}$ as a polynomial in $\mathrm{\epsilon }$:

poly_eps := evalc(eval(poly, x = -1.47 + epsilon * I));

$\mathrm{poly\_eps}≔8.7157517-447.3046{\mathrm{\epsilon }}^2+49{\mathrm{\epsilon }}^4+\mathrm{I}\left(2.121492\mathrm{\epsilon }+288.12{\mathrm{\epsilon }}^3\right)$

We now plot the real and imaginary parts of the resulting polynomial as $\mathrm{\epsilon }$ varies between $\mathrm{-0.01}$ and $0.01$.

poly_im, poly_re := selectremove(has, poly_eps, I);

$\mathrm{poly\_im},\mathrm{poly\_re}≔\mathrm{I}\left(2.121492\mathrm{\epsilon }+288.12{\mathrm{\epsilon }}^3\right),8.7157517-447.3046{\mathrm{\epsilon }}^2+49{\mathrm{\epsilon }}^4$

plot(poly_re, epsilon=-0.01 .. 0.01);

plot(poly_im/I, epsilon=-0.01 .. 0.01);

We see that the real part achieves its maximum at $\mathrm{\epsilon }=0$ and its minimum at $\mathrm{\epsilon }=0.01$, and the imaginary part achieves its maximum at $\mathrm{\epsilon }=0.01$ and its minimum at $\mathrm{\epsilon }=\mathrm{-0.01}$.

eval(poly_re, epsilon=0), eval(poly_re, epsilon=0.01);

$8.7157517,8.67102173$

eval(poly_im/I, epsilon=0.01), eval(poly_im/I, epsilon=-0.01);

$0.02150304,\mathrm{-0.02150304}$

So ideally we would like the result to have a center of about $8.694$, the real part should have a radius of about $0.023$, and the imaginary part should have a radius of about $0.022$. We don't quite achieve that with EvaluatePolynomial, but we get much closer than with the other options above.

EvaluatePolynomial(cb, PolynomialTools:-CoefficientList(poly, x));

$⟨\text{ComplexBox:}\text{[8.71575 +/- 0.044731]}+\text{[0 +/- 0.021503]}\cdot \mathrm{I}⟩$

The ComplexBox:-EvaluatePolynomial command was introduced in Maple 2024.

For more information on Maple 2024 changes, see Updates in Maple 2024.