There are four ways to construct a Matrix in Maple. Which method you use depends on your data and needs. The following are some guidelines on when to use which method.

Use the Matrix construction shortcuts to quickly construct a Matrix with a small number of elements.

Use the Matrix palette to specify the initial type and shape for the Matrix as well as its data type.

Use the Matrix function to access more initialization options (for example, using a procedure or lists as initializers) and options that maximize the efficiency of reading from the Matrix, storing the Matrix, or both.

Use the ImportMatrix function to import data stored in a file into a Matrix.

Use a pair of matching angle brackets (< >) to enclose the comma-separated values of the Matrix elements.

To have sequences of comma-separated values define the rows of your Matrix, separate the rows with a semicolon (;).

Matrix1 := <a , b , c ; d , e , f>;

$\mathrm{Matrix1}≔\left[\begin{array}{ccc}a& b& c\\ d& e& f\end{array}\right]$

To have sequences of comma-separated values define the columns of your Matrix, separate the columns with a vertical bar (|).

Matrix2 := <a , b , c | d , e , f>;

$\mathrm{Matrix2}≔\left[\begin{array}{cc}a& d\\ b& e\\ c& f\end{array}\right]$

Vectors and Matrices can be used for the elements of a Matrix. The type of Vector (that is, row or column) determines whether the Vectors are interpreted as rows or columns in the Matrix.

Use either a comma or a semicolon to separate the rows of the Matrix when the elements are row Vectors.

RowVector1 := <1 | 2 | 3>;

$\mathrm{RowVector1}≔\left[\begin{array}{ccc}1& 2& 3\end{array}\right]$

RowVector2 := <4 | 5 | 6>;

$\mathrm{RowVector2}≔\left[\begin{array}{ccc}4& 5& 6\end{array}\right]$

Matrix3 := <RowVector1; RowVector2>;

$\mathrm{Matrix3}≔\left[\begin{array}{ccc}1& 2& 3\\ 4& 5& 6\end{array}\right]$

Use the vertical bar (|) to separate the columns of the Matrix when the elements are column Vectors.

ColumnVector1 := <7, 8, 9>;

$\mathrm{ColumnVector1}≔\left[\begin{array}{c}7\\ 8\\ 9\end{array}\right]$

ColumnVector2 := <10, 11, 12>;

$\mathrm{ColumnVector2}≔\left[\begin{array}{c}10\\ 11\\ 12\end{array}\right]$

Matrix4 := <ColumnVector1 | ColumnVector2>;

$\mathrm{Matrix4}≔\left[\begin{array}{cc}7& 10\\ 8& 11\\ 9& 12\end{array}\right]$

You can also concatenate a Matrix with Vectors and other Matrices to create a new Matrix. The same separators apply (vertical bar to append columns and either a comma or semicolon to append rows).

Matrix5 := <Matrix4 | <13, 14, 15>>;

$\mathrm{Matrix5}≔\left[\begin{array}{ccc}7& 10& 13\\ 8& 11& 14\\ 9& 12& 15\end{array}\right]$

Matrix6 := <Matrix3, <7 | 8 | 9>>;

$\mathrm{Matrix6}≔\left[\begin{array}{ccc}1& 2& 3\\ 4& 5& 6\\ 7& 8& 9\end{array}\right]$

<Matrix5; Matrix6>;

$\left[\begin{array}{ccc}7& 10& 13\\ 8& 11& 14\\ 9& 12& 15\\ 1& 2& 3\\ 4& 5& 6\\ 7& 8& 9\end{array}\right]$

For more information, see Matrix and Vector Construction Shortcuts.

If you are using the standard worksheet interface, the Matrix palette can be used to specify additional properties for a Matrix.

The following are the additional properties that you can specify with the Matrix palette.

For more information on using the Matrix palette, see Use the Matrix Palette or watch the Matrix Palette Training Video.

The Matrix function gives you access to a wider variety of initializer options. These options include using a procedure to define the Matrix elements

f:= (i,j) -> z^(i+j-1):

p:=Matrix(2,f);

$p≔\left[\begin{array}{cc}z& z^2\\ z^2& z^3\end{array}\right]$

z:=3:

p;

$\left[\begin{array}{cc}z& z^2\\ z^2& z^3\end{array}\right]$

M := Matrix([[1, -1, 0], [1, 1, 0], [0, 0, 1]]);

$M≔\left[\begin{array}{ccc}1& \mathrm{-1}& 0\\ 1& 1& 0\\ 0& 0& 1\end{array}\right]$

A := Array(0..2, 0..1, {(0, 0) = 1, (0, 1) = 2, (1, 0) = 3, (1, 1) = 4, (2, 0) = 5, (2, 1) = 6 } );

M := Matrix(A);

$M≔\left[\begin{array}{cc}1& 2\\ 3& 4\\ 5& 6\end{array}\right]$

sym := Matrix([[1], [2, 3], [4, 5, 6]], storage=triangular[lower], shape=symmetric );

$\mathrm{sym}≔\left[\begin{array}{ccc}1& 2& 4\\ 2& 3& 5\\ 4& 5& 6\end{array}\right]$

sym[1, 3] := -8:

sym;

$\left[\begin{array}{ccc}1& 2& \mathrm{-8}\\ 2& 3& 5\\ \mathrm{-8}& 5& 6\end{array}\right]$

MATLAB® binary

MATLAB® ASCII

Matrix Market

Comma-Separated Values (CSV)

Generic Delimited