Consider the following Clairaut partial differential equation.

u(x,y) = x*diff(u(x,y),x)+y*diff(u(x,y),y)+diff(u(x,y),x)*diff(u(x,y),y);

$u\left(x\,y\right)=x\left(\frac{\partial }{\partial x}u\left(x\,y\right)\right)+y\left(\frac{\partial }{\partial y}u\left(x\,y\right)\right)+\left(\frac{\partial }{\partial x}u\left(x\,y\right)\right)\left(\frac{\partial }{\partial y}u\left(x\,y\right)\right)$

Represent it by the differential polynomial $p$ with a more compact syntax, called jet notation.

p := -u[]+x*u[x]+y*u[y]+u[x]*u[y];

$p≔x{u}_x+y{u}_y+u_x{u}_y-u\left[\right]$

Before any manipulation of this differential polynomial, define a differential polynomial ring it belongs to:

R := differential_ring(ranking=[u], derivations=[x,y], notation=jet);

$R≔\mathrm{PDE\_ring}$

The Clairaut equation under consideration has a singular solution. This is shown by Rosenfeld_Groebner. The result of Rosenfeld_Groebner is a list of tables (appearing as characterizable), each defining a characterizable component.

Clairaut := Rosenfeld_Groebner({p}, R);

$\mathrm{Clairaut}≔\left[\mathrm{characterizable}\,\mathrm{characterizable}\right]$

Each characterizable component is defined by a differential characteristic set that can be accessed using the equations command. The nonsingular zeros of this differential characteristic set are the zeros at which some additional differential polynomials do not vanish. They can be accessed using the inequations command.

equations(Clairaut[1]), inequations(Clairaut[1]);

$\left[x{u}_x+y{u}_y+u_x{u}_y-u\left[\right]\right],\left[x+u_y\right]$

equations(Clairaut[2]), inequations(Clairaut[2]);

$\left[xy+u\left[\right]\right],\left[\right]$

The second component represents the singular solution of this Clairaut equation while the first represents the general solution of the Clairaut equation.

Consider the 3 following differential polynomials.

p1:=diff(u(x,y),x)+v(x,y)-y;

$\mathrm{p1}≔\frac{\partial }{\partial x}u\left(x\,y\right)+v\left(x\,y\right)-y$

p2:=diff(u(x,y),y)+v(x,y);

$\mathrm{p2}≔\frac{\partial }{\partial y}u\left(x\,y\right)+v\left(x\,y\right)$

p3:=diff(v(x,y),x)-diff(v(x,y),y);

$\mathrm{p3}≔\frac{\partial }{\partial x}v\left(x\,y\right)-\frac{\partial }{\partial y}v\left(x\,y\right)$

They define the system of differential equations $S\:\mathrm{p1}\=0\,\mathrm{p2}\=0\,\mathrm{p3}\=0$. Before any manipulation of these differential polynomials, define a structure they belong to. It is possible to work with the Maple notation of derivatives.

R := differential_ring(ranking=[u,v], derivations=[x,y], notation=diff);

$R≔\mathrm{PDE\_ring}$

Convert to the jet notation, introduced in the previous example.

denote(p1, 'jet', R), denote(p2, 'jet', R), denote(p3, 'jet', R);

$u_x+v\left[\right]-y,u_y+v\left[\right],v_x-v_y$

What does Rosenfeld_Groebner tell us about the system $S$?

Rosenfeld_Groebner({p1,p2,p3}, R);

This indicates that the system bears a contradiction: $\mathrm{p1}$, $\mathrm{p2}$, and $\mathrm{p3}$ have no common zero. In this case it is quite easy to detect the contradiction. Differentiating $\mathrm{p1}$ with respect to $y$ produces:

differentiate(p1, y, R);

$\frac{{\partial }^2}{\partial x\partial y}u\left(x\,y\right)+\frac{\partial }{\partial y}v\left(x\,y\right)-1$

The meromorphic solutions of $S$, if they exist, shall make this differential polynomial vanish. They shall also make the following differential polynomial vanish

differentiate(p2, x, R)- p3;

$\frac{{\partial }^2}{\partial x\partial y}u\left(x\,y\right)+\frac{\partial }{\partial y}v\left(x\,y\right)$

The two equations cannot be satisfied simultaneously: the system $S$ bears a contradiction $1=0$ and therefore admits no solution.

To perform a chain resolution of a system of ordinary differential equations, use an elimination ranking. Consider the differential system defined by the following set $S$ of differential polynomials in the unknown functions $x\left(t\right),y\left(t\right),z\left(t\right)$.

S := [diff(x(t),t)-x(t)*(x(t)+y(t)), diff(y(t),t)+y(t)*(x(t)+y(t)), diff(x(t),t)^2+diff(y(t),t)^2+diff(z(t),t)^2-1];

$S≔\left[\frac{\ⅆ}{\ⅆt}x\left(t\right)-x\left(t\right)\left(x\left(t\right)+y\left(t\right)\right)\,\frac{\ⅆ}{\ⅆt}y\left(t\right)+y\left(t\right)\left(x\left(t\right)+y\left(t\right)\right)\,{\left(\frac{\ⅆ}{\ⅆt}x\left(t\right)\right)}^2+{\left(\frac{\ⅆ}{\ⅆt}y\left(t\right)\right)}^2+{\left(\frac{\ⅆ}{\ⅆt}z\left(t\right)\right)}^2-1\right]$

Using an elimination ranking where $z\left(t\right)>y\left(t\right)>x\left(t\right)$, you obtain differential characteristic sets containing a differential polynomial in $x\left(t\right)$ alone, a differential polynomial determining $y\left(t\right)$ in terms of $x\left(t\right)$, and finally a differential polynomial determining $z\left(t\right)$ in terms of $y\left(t\right)$ and $x\left(t\right)$. To see more clearly the dependencies of these differential polynomials, use the rewrite_rules command, which is an alternative to the equations command.

R := differential_ring(ranking=[z,y,x], derivations=[t], notation=diff):

G :=Rosenfeld_Groebner(S, R);

$G≔\left[\mathrm{characterizable}\,\mathrm{characterizable}\right]$

rewrite_rules(G[1]); inequations(G[1]);

$\left[{\left(\frac{\ⅆ}{\ⅆt}z\left(t\right)\right)}^2=-\frac{2{\left(\frac{\ⅆ}{\ⅆt}x\left(t\right)\right)}^2{x\left(t\right)}^4-2{\left(\frac{\ⅆ}{\ⅆt}x\left(t\right)\right)}^3{x\left(t\right)}^2-{x\left(t\right)}^4+{\left(\frac{\ⅆ}{\ⅆt}x\left(t\right)\right)}^4}{{x\left(t\right)}^4}\,y\left(t\right)=\frac{-{x\left(t\right)}^2+\frac{\ⅆ}{\ⅆt}x\left(t\right)}{x\left(t\right)}\,\frac{{\ⅆ}^2}{\ⅆt^2}x\left(t\right)=2\left(\frac{\ⅆ}{\ⅆt}x\left(t\right)\right)x\left(t\right)\right]$

$\left[x\left(t\right)\,\frac{\ⅆ}{\ⅆt}z\left(t\right)\right]$

rewrite_rules(G[2]); inequations(G[2]);

$\left[{\left(\frac{\ⅆ}{\ⅆt}z\left(t\right)\right)}^2=-{y\left(t\right)}^4+1\,\frac{\ⅆ}{\ⅆt}y\left(t\right)=-{y\left(t\right)}^2\,x\left(t\right)=0\right]$

$\left[\frac{\ⅆ}{\ⅆt}z\left(t\right)\right]$

Perform a chain resolution to both components of the result. Note that the singular solution $x\left(t\right)=0$ must be discarded in the resolution of the first component, as indicated by the differential polynomials of its inequations. The correct complete solution with $x\left(t\right)=0$ is given by the second component.

Consider the set of differential polynomials describing the motion of a pendulum, that is, a point mass $m$ suspended from a massless rod of length $l$ under the influence of gravity $g$, in Cartesian coordinates $x,y$. The Lagrangian formulation leads to two second order differential equations with an algebraic constraint. $T$ is the Lagrangian multiplier.

P := [m*diff(y(t),t,t)+T(t)*y(t)+g, m*diff(x(t),t,t)+T(t)*x(t), x(t)^2+y(t)^2-l^2];

$P≔\left[m\left(\frac{{\ⅆ}^2}{\ⅆt^2}y\left(t\right)\right)+T\left(t\right)y\left(t\right)+g\,m\left(\frac{{\ⅆ}^2}{\ⅆt^2}x\left(t\right)\right)+T\left(t\right)x\left(t\right)\,{x\left(t\right)}^2+{y\left(t\right)}^2-l^2\right]$

To manipulate this system, declare the additional constants $m,l,g$ appearing in the coefficients of these differential polynomials.

K := field_extension(transcendental_elements=[m,l,g]);

$K≔\mathrm{ground\_field}$

Orderly Ranking

To find the lowest order differential polynomials vanishing on the zeros of the system modeling the pendulum and in particular all the algebraic constraints (that is, the differential polynomials of order $0$), use an orderly ranking.

RO := differential_ring(ranking=[[T,x,y]], derivations=[t], field_of_constants=K, notation=diff):

GO:= Rosenfeld_Groebner(P, RO);

$\mathrm{GO}≔\left[\mathrm{characterizable}\,\mathrm{characterizable}\right]$

rewrite_rules(GO[1]);

$\left[\frac{\ⅆ}{\ⅆt}T\left(t\right)=-\frac{3\left(\frac{\ⅆ}{\ⅆt}y\left(t\right)\right)g}{l^2}\,{\left(\frac{\ⅆ}{\ⅆt}y\left(t\right)\right)}^2=-\frac{-T\left(t\right)l^4+T\left(t\right){y\left(t\right)}^2{l}^2-y\left(t\right)l^{2}g+{y\left(t\right)}^{3}g}{l^{2}m}\,{x\left(t\right)}^2=-{y\left(t\right)}^2+l^2\right]$

inequations(GO[1]);

$\left[x\left(t\right)\,\frac{\ⅆ}{\ⅆt}y\left(t\right)\right]$

rewrite_rules(GO[2]);

$\left[T\left(t\right)=-\frac{y\left(t\right)g}{l^2}\,x\left(t\right)=0\,{y\left(t\right)}^2=l^2\right]$

inequations(GO[2]);

$\left[y\left(t\right)\right]$

The second component in the output of Rosenfeld_Groebner corresponds to the equilibria of the pendulum. From the first component of the output, it can be seen that the actual motion is described by two first order differential equations with a constraint: the solution depends on only two arbitrary constants.

Mixed Ranking

To obtain the differential system satisfied by $x$ and $y$ alone, eliminate $T$:

RM := differential_ring(ranking=[T,[x,y]], derivations=[t], field_of_constants=K, notation=diff):

GM:= Rosenfeld_Groebner(P, RM);

$\mathrm{GM}≔\left[\mathrm{characterizable}\,\mathrm{characterizable}\right]$

rewrite_rules(GM[1]);

$\left[T\left(t\right)=-\frac{{\left(\frac{\ⅆ}{\ⅆt}y\left(t\right)\right)}^{2}m{l}^2-y\left(t\right)l^{2}g+{y\left(t\right)}^{3}g}{l^2\left({y\left(t\right)}^2-l^2\right)}\,\frac{{\ⅆ}^2}{\ⅆt^2}y\left(t\right)=\frac{{\left(\frac{\ⅆ}{\ⅆt}y\left(t\right)\right)}^{2}y\left(t\right)m{l}^2+{y\left(t\right)}^{4}g-2{y\left(t\right)}^2{l}^{2}g+l^{4}g}{l^{2}m\left({y\left(t\right)}^2-l^2\right)}\,{x\left(t\right)}^2=-{y\left(t\right)}^2+l^2\right]$

rewrite_rules(GM[2]);

$\left[T\left(t\right)=-\frac{y\left(t\right)g}{l^2}\,x\left(t\right)=0\,{y\left(t\right)}^2=l^2\right]$

Note here that the motion is given by a second order differential equation in $y\left(t\right)$. Then the Lagrange multiplier is given explicitly in terms of $y\left(t\right)$ and its first derivative.

To solve overdetermined systems of partial differential equations it is interesting to compute first the ordinary differential equations satisfied by the solutions of the system. For this purpose, a lexicographic ranking must be chosen. Consider the differential system $S$ defining the infinitesimal generators of the symmetry group of the Burgers equations.

Burgers_pde := diff(u(t,x),t)=diff(u(t,x),x,x)-u(t,x)*diff(u(t,x),x);

$\mathrm{Burgers\_pde}≔\frac{\partial }{\partial t}u\left(t\,x\right)=\frac{{\partial }^2}{\partial x^2}u\left(t\,x\right)-u\left(t\,x\right)\left(\frac{\partial }{\partial x}u\left(t\,x\right)\right)$

BurgersSymm := PDEtools:-DeterminingPDE(Burgers_pde, u(t, x), [V1, V2, V3](t, x, u));

$\mathrm{BurgersSymm}≔\left\{\frac{\partial }{\partial u}\mathrm{V1}\left(t\,x\,u\right)=0\,\frac{\partial }{\partial x}\mathrm{V1}\left(t\,x\,u\right)=0\,\frac{\partial }{\partial t}\mathrm{V2}\left(t\,x\,u\right)=\frac{\left(\frac{\partial }{\partial t}\mathrm{V1}\left(t\,x\,u\right)\right)u}{2}+\mathrm{V3}\left(t\,x\,u\right)\,\frac{\partial }{\partial u}\mathrm{V2}\left(t\,x\,u\right)=0\,\frac{\partial }{\partial x}\mathrm{V2}\left(t\,x\,u\right)=\frac{\frac{\partial }{\partial t}\mathrm{V1}\left(t\,x\,u\right)}{2}\,\frac{\partial }{\partial t}\mathrm{V3}\left(t\,x\,u\right)=-\frac{\left(\frac{{\partial }^2}{\partial t^2}\mathrm{V1}\left(t\,x\,u\right)\right)u}{2}\,\frac{\partial }{\partial u}\mathrm{V3}\left(t\,x\,u\right)=-\frac{\frac{\partial }{\partial t}\mathrm{V1}\left(t\,x\,u\right)}{2}\,\frac{\partial }{\partial x}\mathrm{V3}\left(t\,x\,u\right)=\frac{\frac{{\partial }^2}{\partial t^2}\mathrm{V1}\left(t\,x\,u\right)}{2}\,\frac{{\partial }^3}{\partial t^3}\mathrm{V1}\left(t\,x\,u\right)=0\right\}$

Seek the ordinary differential equations with respect to $t$ satisfied by the solutions of this system.

R := differential_ring(ranking=[lex[V3,V2,V1]], derivations=[u,x,t], notation=diff);

$R≔\mathrm{PDE\_ring}$

G := Rosenfeld_Groebner(map(lhs-rhs, BurgersSymm), R);

$G≔\left[\mathrm{characterizable}\right]$

rewrite_rules(G[1]);

$\left[\frac{\partial }{\partial u}\mathrm{V3}\left(u\,x\,t\right)=-\frac{\frac{\partial }{\partial t}\mathrm{V1}\left(u\,x\,t\right)}{2}\,\frac{\partial }{\partial u}\mathrm{V2}\left(u\,x\,t\right)=0\,\frac{\partial }{\partial u}\mathrm{V1}\left(u\,x\,t\right)=0\,\frac{\partial }{\partial x}\mathrm{V3}\left(u\,x\,t\right)=-\frac{\frac{\partial }{\partial t}\mathrm{V3}\left(u\,x\,t\right)}{u}\,\frac{\partial }{\partial x}\mathrm{V2}\left(u\,x\,t\right)=\frac{\frac{\partial }{\partial t}\mathrm{V1}\left(u\,x\,t\right)}{2}\,\frac{\partial }{\partial x}\mathrm{V1}\left(u\,x\,t\right)=0\,\frac{{\partial }^2}{\partial t^2}\mathrm{V3}\left(u\,x\,t\right)=0\,\frac{{\partial }^2}{\partial t^2}\mathrm{V1}\left(u\,x\,t\right)=-\frac{2\left(\frac{\partial }{\partial t}\mathrm{V3}\left(u\,x\,t\right)\right)}{u}\,\frac{\partial }{\partial t}\mathrm{V2}\left(u\,x\,t\right)=\frac{u\left(\frac{\partial }{\partial t}\mathrm{V1}\left(u\,x\,t\right)\right)}{2}+\mathrm{V3}\left(u\,x\,t\right)\right]$

There are three independent ordinary differential polynomials with respect to $t$ (the last three of the differential characteristic set). All other ordinary (in $t$) differential polynomials vanishing on the solutions of $\mathrm{BurgersSymm}$ can be written as linear combination of these three with their derivatives.