restart:

# Invoke the Maplets Elements subpackage.
with( Maplets[Elements] ):

# Define the Maplet application.
maplet := Maplet(
    
    # Create a standard color dialog window
    # from which the user can select a color.
    ColorDialog['CD1']( 'onapprove' = Shutdown(['CD1']),
    'oncancel' = Shutdown() )
):

# Run the Maplet application.
Maplets[Display](maplet):

restart:

with(Maplets[Elements]):
maplet := Maplet(
    ColorDialog['CD1']( 'onapprove' = Shutdown(['CD1']),
    'oncancel' = Shutdown(), 'title' = "Select a color" )
):

# Run the Maplet application. Assign result to the value returned by
# the Maplet application.
result := Maplets[Display](maplet):

# Specify the default value if no color is selected.
if result = NULL then
    "#FF0000"; # red
else
    result[1];
end if;

restart:

# Define the module MyModule.
MyModule := module()

    # Declare the module as a package and
    # protect its exports.
    option package;

    # Declare mymaplet as a local variable.
    local mymaplet;

    # Declare MyProc as an export.
    export MyProc;

    # Invoke the Maplets Elements subpackage.
    use Maplets[Elements] in

        # Define the Maplet application mymaplet.
        mymaplet := Maplet(

            # Call ColorDialog.
            ColorDialog['CD1'](
                'onapprove' = Shutdown(['CD1']),
                'oncancel' = Shutdown(),
                'title' = "Select a color"
            )
        ):
    end use;

    # Define the procedure MyProc.
    MyProc := proc()
        local result;

        # Run the Maplet application. Assign result to the value
        # returned by the Maplet application.
        result := Maplets[Display]( mymaplet );

        if result = NULL then
            'COLOR( RGB, 1, 0, 0 )'; # default color
        else
            result := result[1];

            # Convert the color into a COLOR(RGB, r, g, b)
            # data structure.
            'COLOR'( 'RGB',
                convert( result[2..3], 'decimal', 16 )/255,
                convert( result[4..5], 'decimal', 16 )/255,
                convert( result[6..7], 'decimal', 16 )/255
            );
        end if;
    end proc;
end module:

# Invoke the module MyModule.
with(MyModule):

# Call the procedure MyProc.
MyProc();

?Maplets[Examples][GetColor]

print( Maplets[Examples][GetColor] );