Boundary Conditions for PDEs

All Products Maple MapleSim

Home : Support : Online Help : Mathematics : Differential Equations : Example Worksheets : Boundary Conditions for PDEs

Partial Differential Equations: Exact Solutions Subject to Boundary Conditions
This document gives examples of Fourier series and integral transform (Laplace and Fourier) solutions to problems involving a PDE and boundary and/or initial conditions. It also describes how, for certain problems, pdsolve can automatically adjust the arbitrary functions and constants entering the solution of the partial differential equations (PDEs) such that the boundary conditions (BCs) are satisfied.

Two Examples Solved Automatically and Step-by-step

Example 1: Adjusting an Arbitrary Function _F1(...)

>	$restart &semi;$ $with (PDEtools) &colon;$

>	$U ≔ diff_table (u (x, t)) &colon;$

A substance convecting through a tube at velocity c (for example, a radioactive decaying chemical dissolved in water) has its density $u (x, t)$ modeled by a convection-decay type of equation

>	${pde}_{1} ≔ U_{t} + c U_{x} = - λ U []$

${pde}_{1} ≔ c (\frac{\partial}{\partial x} u (x, t)) + \frac{\partial}{\partial t} u (x, t) = - λ u (x, t)$

(1)

where the size of $λ$ indicates how fast the substance is decaying. In this case, the boundary condition is a generic function of $x$ indicating the value of the density at $t = 0$ .

>	${bc}_{1} ≔ eval (U [], t = 0) = φ (x)$

${bc}_{1} ≔ u (x, 0) = φ (x)$

(2)

Step-by-step Solution

The following is an exact solution for ${pde}_{1}$ . For now, ${bc}_{1}$ is not considered.

>	${sol}_{1} ≔ pdsolve ({pde}_{1})$

${sol}_{1} ≔ u (x, t) = f__1 (\frac{t c - x}{c}) {&ExponentialE;}^{- \frac{λ x}{c}}$

(3)

Perform the following steps to find the form of the mapping of $_F1$ that matches ${bc}_{1}$ when $t = 0.$

Consider $t = 0.$

>	$e1 ≔ eval (\binom{{sol}_{1}}{} \| \binom{}{t = 0}, {bc}_{1})$

$e1 ≔ φ (x) = f__1 (- \frac{x}{c}) {&ExponentialE;}^{- \frac{λ x}{c}}$

(4)

Introduce a new variable q equal to the argument of _F1.

>	$tr ≔ q = - \frac{x}{c} &semi;$ $itr ≔ isolate (tr, x)$

$tr ≔ q = - \frac{x}{c}$

$itr ≔ x = - q c$

(5)

Evaluate at this value of x and then isolate _F1(q). The following mapping is obtained.

>	$eval (e1, itr)$

$φ (- q c) = f__1 (q) {&ExponentialE;}^{λ q}$

(6)

>	$e2 ≔ isolate (,_F1 (q))$

$e2 ≔ f__1 (q) = \frac{φ (- q c)}{{&ExponentialE;}^{λ q}}$

(7)

>	$ans_F ≔_F1 = unapply (rhs (), q)$

$ans_F ≔ f__1 = (q \mapsto \frac{φ (- q \cdot c)}{{&ExponentialE;}^{λ \cdot q}})$

(8)

The solution to the PDE and BC is obtained evaluating the general solution at this value of _F1.

>	${sol}_{1}$

$u (x, t) = f__1 (\frac{c t - x}{c}) {&ExponentialE;}^{- \frac{λ x}{c}}$

(9)

>	${ans}_{1} ≔ simplify (eval (, ans_F), \exp)$

${ans}_{1} ≔ u (x, t) = φ (- c t + x) {&ExponentialE;}^{- λ t}$

(10)

Verify this result using pdetest.

>	$pdetest ({ans}_{1}, [{pde}_{1}, {bc}_{1}])$

$[0, 0]$

(11)

Summary: The system of PDEs and BCs is

>	${sys}_{1} ≔ [{pde}_{1}, {bc}_{1}]$

${sys}_{1} ≔ [c (\frac{\partial}{\partial x} u (x, t)) + \frac{\partial}{\partial t} u (x, t) = - λ u (x, t), u (x, 0) = φ (x)]$

(12)

The following is the solution computed by pdsolve automatically by performing the steps explained in the Step-by-step Solution section above.

>	$pdsolve ({sys}_{1})$

$u (x, t) = φ (- c t + x) {&ExponentialE;}^{- λ t}$

(13)

The approach used in this example serves also to address nonlinear equations of the form $\frac{\partial}{\partial t} u (x, t) + c (\frac{\partial}{\partial x} u (x, t)) = Φ (x, t, u (x, t))$

Example 2: Periodic Boundary Conditions

Consider the heat equation that models the temperature $u (x, t)$

>	${pde}_{2} ≔ U_{t} = κ U_{x, x}$

${pde}_{2} ≔ \frac{\partial}{\partial t} u (x, t) = κ (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

(14)

where $κ$ is any constant of proportionality.

Assume that the boundary conditions at $x = 0$ and $x = L$ are as follows:

>	${bc}_{2} ≔ u (0, t) = 0, u (L, t) = 0$

${bc}_{2} ≔ u (0, t) = 0, u (L, t) = 0$

(15)

Step-by-step Solution

Similar to Example 1, the following is a solution for ${pde}_{2}$ . For now, ${bc}_{2}$ is not considered.

>	${sol}_{2} ≔ pdsolve ({pde}_{2}, build)$

${sol}_{2} ≔ u (x, t) = c__3 {&ExponentialE;}^{κ {_c}_{1} t} c__1 {&ExponentialE;}^{\sqrt{{_c}_{1}} x} + \frac{c__3 {&ExponentialE;}^{κ {_c}_{1} t} c__2}{{&ExponentialE;}^{\sqrt{{_c}_{1}} x}}$

(16)

This time, pdsolve computes a complete (that is, not the most general) solution using separation of variables. The solution appears in terms of arbitrary constants $_C1,_C2,_C3$ and the separation variable ${_c}_{1}$ .

The integration constants can be redefined to absorb $_C3 &colon;$

>	$zz ≔_C1 = \frac{_C1}{_C3},_C2 = \frac{_C2}{_C3}$

$zz ≔ c__1 = \frac{c__1}{c__3}, c__2 = \frac{c__2}{c__3}$

(17)

Now, evaluate the solution at $x = 0$ and $x = L$ and impose the given boundary conditions to build a system (e1 and e2, so two equations) to be solved for these three constants.

>	$e1 ≔ eval (eval (\binom{{sol}_{2}}{} \| \binom{}{x = 0}, ({bc}_{2}) [1]), \{zz\})$

$e1 ≔ 0 = c__1 {&ExponentialE;}^{κ {_c}_{1} t} + {&ExponentialE;}^{κ {_c}_{1} t} c__2$

(18)

>	$e2 ≔ eval (eval (\binom{{sol}_{2}}{} \| \binom{}{x = L}, ({bc}_{2}) [2]), \{zz\})$

$e2 ≔ 0 = {&ExponentialE;}^{κ {_c}_{1} t} c__1 {&ExponentialE;}^{\sqrt{{_c}_{1}} L} + \frac{{&ExponentialE;}^{κ {_c}_{1} t} c__2}{{&ExponentialE;}^{\sqrt{{_c}_{1}} L}}$

(19)

Solve for the constants.

>	$_EnvAllSolutions ≔ true$

$_EnvAllSolutions ≔ true$

(20)

>	$solve (\{e1, e2\}, \{_C1,_C2, {_c}_{1}\})$

$\{c__1 = 0, c__2 = 0, {_c}_{1} = {_c}_{1}\}, \{c__1 = - c__2, c__2 = c__2, {_c}_{1} = - \frac{π^{2} {_Z1~}^{2}}{L^{2}}\}$

(21)

The first solution above leads to a solution of no interest: $u (x, t) = 0$ . The second solution above is the one we want.

>	${ans}_{2} ≔ eval ({sol}_{2}, [2])$

${ans}_{2} ≔ u (x, t) = - c__3 {&ExponentialE;}^{- \frac{κ π^{2} {_Z1~}^{2} t}{L^{2}}} c__2 {&ExponentialE;}^{\sqrt{- \frac{π^{2} {_Z1~}^{2}}{L^{2}}} x} + \frac{c__3 {&ExponentialE;}^{- \frac{κ π^{2} {_Z1~}^{2} t}{L^{2}}} c__2}{{&ExponentialE;}^{\sqrt{- \frac{π^{2} {_Z1~}^{2}}{L^{2}}} x}}$

(22)

Here pdetest verifies the answer for pde[2] and the first boundary condition, but fails with the second one.

>	$pdetest ({ans}_{2}, [{pde}_{2}, {bc}_{2}])$

$[0, 0, - c__2 c__3 ({&ExponentialE;}^{2 π \sqrt{- \frac{1}{L^{2}}} L |_Z1~|} - 1) {&ExponentialE;}^{- \frac{π_Z1~ (L^{3} \sqrt{- \frac{1}{L^{2}}} signum (_Z1~) + π_Z1~ κ t)}{L^{2}}}]$

(23)

However, the answer computed is correct. The second boundary condition can be constructed by evaluating the answer at $x = L$ . This task can be performed within pdetest.

>	$simplify (\binom{{ans}_{2}}{} \| \binom{}{x = L}) assuming L :: real$

$u (L, t) = 0$

(24)

Summary: The system with periodic boundary conditions is

>	${sys}_{2} ≔ [{pde}_{2}, {bc}_{2}]$

${sys}_{2} ≔ [\frac{\partial}{\partial t} u (x, t) = κ (\frac{\partial^{2}}{\partial x^{2}} u (x, t)), u (0, t) = 0, u (L, t) = 0]$

(25)

The solution computed by pdsolve automatically by performing the steps summarized in the Step-by-step Solution section above:

>	$pdsolve ({sys}_{2})$

$u (x, t) = \sum_{n = 1}^{\infty} csgn (\frac{1}{L}) \sin (\frac{n π x}{L}) {&ExponentialE;}^{- \frac{κ π^{2} n^{2} t}{L^{2}}} f__1 (n)$

(26)

>	$pdetest (, {sys}_{2})$

$[0, 0, 0]$

(27)

Notes on this PDE and Initial Values / Boundary Conditions Problem

Given a problem with PDEs and some BCs, note the following:

•	Depending on how you write a general PDE solution, it becomes possible or nearly impossible to adjust it to match the BCs.

•	Certain particular PDE solutions are frequently easier to adjust than general solutions.

•	Some combinations, classified in the literature, of "certain types of PDEs" with "certain type of BCs" can be solved systematically by writing the PDE solution in a special form.

•	By passing PDEs alone to pdsolve, it is not possible to predict the form of the PDE solution. On the other hand, pdsolve accepts a HINT argument so that solutions of a "certain type" can be requested.

Three Textbook Examples

A bar loses heat across its lateral boundary at a rate proportional to the temperature $u (x, t)$ and its BCs state that the temperature at the two ends of the bar are equal to 1.

This problem is modeled by the following equation.

$restart$

>	${sys}_{3} ≔ [\frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) - a u (x, t), u (0, t) = 1, u (1, t) = 1]$

${sys}_{3} ≔ [\frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) - a u (x, t), u (0, t) = 1, u (1, t) = 1]$

(28)

>	$pdsolve ({sys}_{3})$

$u (x, t) = \frac{({&ExponentialE;}^{\frac{\sqrt{a}}{\sqrt{k}}} + 1) (\sum_{n = 1}^{\infty} f__1 (n) {&ExponentialE;}^{- t (π^{2} k n^{2} + a)} \sin (n π x)) + {&ExponentialE;}^{\frac{\sqrt{a} x}{\sqrt{k}}} + {&ExponentialE;}^{- \frac{\sqrt{a} (x - 1)}{\sqrt{k}}}}{{&ExponentialE;}^{\frac{\sqrt{a}}{\sqrt{k}}} + 1}$

(29)

>	$pdetest (, {sys}_{3})$

$[0, 0, 0]$

(30)

The following is a textbook example where the solution is computed by constructing an infinite series and then reversed using the boundary conditions to compute a closed formula for the coefficients of the series. The three boundary conditions specify the value of $u (x, t)$ at two points (values of $x$ ) and at $t = 0$ as a generic function $f (x)$ .

>	${sys}_{4} ≔ [\frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)), u (0, t) = 0, u (λ, t) = 0, u (x, 0) = f (x)]$

${sys}_{4} ≔ [\frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)), u (0, t) = 0, u (λ, t) = 0, u (x, 0) = f (x)]$

(31)

>	$pdsolve ({sys}_{4})$

$u (x, t) = 2 (\sum_{n = 1}^{\infty} \frac{\sin (\frac{n π x}{λ}) {&ExponentialE;}^{- \frac{π^{2} n^{2} k t}{λ^{2}}} (\int_{0}^{λ} f (x) \sin (\frac{n π x}{λ}) &DifferentialD; x)}{λ})$

(32)

The following is the wave equation with conditions at $t = 0$ for $u (x, t)$ and its time derivative $\frac{\partial}{\partial t} u (x, t)$ , as well as conditions at the boundaries x = 0 and x = 1:

>	${sys}_{5} ≔ [\frac{\partial^{2}}{\partial t^{2}} u (x, t) = \frac{1}{16} (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) - \frac{1}{5} (\frac{\partial}{\partial t} u (x, t)), u (0, t) = 0, u (1, t) = 0, u (x, 0) = x (1 - x), D_{2} (u) (x, 0) = x (1 - x)]$

${sys}_{5} ≔ [\frac{\partial^{2}}{\partial t^{2}} u (x, t) = \frac{\frac{\partial^{2}}{\partial x^{2}} u (x, t)}{16} - \frac{\frac{\partial}{\partial t} u (x, t)}{5}, u (0, t) = 0, u (1, t) = 0, u (x, 0) = x (1 - x), D_{2} (u) (x, 0) = x (1 - x)]$

(33)

>	$pdsolve ({sys}_{5})$

$u (x, t) = \sum_{n = 1}^{\infty} (- \frac{44 ({(−1)}^{n} - 1) ((I + \frac{\sqrt{25 π^{2} n^{2} - 4}}{22}) {&ExponentialE;}^{- \frac{(2 + I \sqrt{25 π^{2} n^{2} - 4}) t}{20}} - {&ExponentialE;}^{\frac{(- 2 + I \sqrt{25 π^{2} n^{2} - 4}) t}{20}} (I - \frac{\sqrt{25 π^{2} n^{2} - 4}}{22})) \sin (n π x)}{\sqrt{25 π^{2} n^{2} - 4} n^{3} π^{3}})$

(34)

>	$pdetest (, {sys}_{5})$

$[0, 0, 0, - \frac{4 (\sum_{n = 1}^{\infty} \frac{({(−1)}^{n} - 1) \sin (n π x)}{n^{3}})}{π^{3}} + x^{2} - x, - \frac{4 (\sum_{n = 1}^{\infty} \frac{({(−1)}^{n} - 1) \sin (n π x)}{n^{3}})}{π^{3}} + x^{2} - x]$

(35)

To verify the conditions at t = 0 which pdetest is unable to check, we use plots.

First, we plot together the solution at t = 0 (1000 terms) and the quadratic expression $x \cdot (1 - x)$ and see that they are identical:

>	$plot ([subs (infinity = 1000, t = 0, rhs ()), x (1 - x)], x = 0 .. 1)$

Then, we plot together the derivative of the solution at t = 0 (1000 terms) and the quadratic expression $x \cdot (1 - x)$ and see that they are identical:

>	$plot ([subs (infinity = 1000, t = 0, \frac{\partial}{\partial t} rhs ()), x (1 - x)], x = 0 .. 1)$

More Examples

$restart$

Set infolevel = 2 to receive information on the method used.

>	$infolevel [pdsolve] ≔ 2$

${infolevel}_{pdsolve} ≔ 2$

(36)

>	${pde}_{1} ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, t) - \frac{\frac{\partial^{2}}{\partial t^{2}} u (x, t)}{c^{2}} = 0 &semi;$ ${iv}_{1} ≔ u (x, 0) = f (x), D_{2} (u) (x, 0) = g (x) &semi;$ $pdsolve ([{pde}_{1}, {iv}_{1}])$

${pde}_{1} ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, t) - \frac{\frac{\partial^{2}}{\partial t^{2}} u (x, t)}{c^{2}} = 0$

${iv}_{1} ≔ u (x, 0) = f (x), D_{2} (u) (x, 0) = g (x)$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

<- submethod "LinearInXT" successful

<- method "SpecializeArbitraryFunctions" for 2nd order PDEs successful

$u (x, t) = \frac{\int_{- c t + x}^{c t + x} g (x1) &DifferentialD; x1}{2 c} + \frac{f (- c t + x)}{2} + \frac{f (c t + x)}{2}$

(37)

>	${pde}_{2} ≔ \frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) &semi;$ ${iv}_{2} ≔ u (x, 0) = x &semi;$ $pdsolve ([{pde}_{2}, {iv}_{2}])$

${pde}_{2} ≔ \frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

${iv}_{2} ≔ u (x, 0) = x$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Heat" for 2nd order PDEs

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Series" for 2nd order PDEs

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

-> trying "WithSourceTerm"

-> trying "ThreeVariables"

-> trying adding missing boundary conditions

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

* trying method "Laplace" for 2nd order PDEs

-> trying a Laplace transformation

* trying method "Fourier" for 2nd order PDEs

-> trying a fourier transformation

<- fourier transformation successful

<- method "Fourier" for 2nd order PDEs successful

$u (x, t) = x$

(38)

>	$with (inttrans, fourier, invfourier)$

$[fourier, invfourier]$

(39)

>	${iv}_{2.1} ≔ u (x, 0) = φ (x) &semi;$ ${ans}_{2.1} ≔ pdsolve ([{pde}_{2}, {iv}_{2.1}])$

${iv}_{2.1} ≔ u (x, 0) = φ (x)$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Heat" for 2nd order PDEs

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Series" for 2nd order PDEs

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

-> trying "WithSourceTerm"

-> trying "ThreeVariables"

-> trying adding missing boundary conditions

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

* trying method "Laplace" for 2nd order PDEs

-> trying a Laplace transformation

* trying method "Fourier" for 2nd order PDEs

-> trying a fourier transformation

<- fourier transformation successful

<- method "Fourier" for 2nd order PDEs successful

${ans}_{2.1} ≔ u (x, t) = ℱ^{- 1} (ℱ (φ (x), x, s) {&ExponentialE;}^{- k s^{2} t}, s, x)$

(40)

>	$\binom{{ans}_{2.1}}{} \| \binom{}{φ (x) = x^{7}}$

$u (x, t) = ℱ^{- 1} ((\binom{ℱ (φ (x), x, s)}{} | \binom{}{φ (x) = x^{7}}) {&ExponentialE;}^{- k s^{2} t}, s, x)$

(41)

>	$pdetest (, [{pde}_{2}, \binom{{iv}_{2.1}}{} \| \binom{}{φ (x) = x^{7}}])$

$[k (- 2 I ℱ^{- 1} (s \frac{\partial}{\partial x} (\binom{ℱ (φ (x), x, s)}{} | \binom{}{\{φ (x) = x^{7}\}}) {&ExponentialE;}^{- k s^{2} t}, s, x) - ℱ^{- 1} (\frac{\partial^{2}}{\partial x^{2}} (\binom{ℱ (φ (x), x, s)}{} | \binom{}{\{φ (x) = x^{7}\}}) {&ExponentialE;}^{- k s^{2} t}, s, x)), ℱ^{- 1} (\binom{ℱ (φ (x), x, s)}{} | \binom{}{φ (x) = x^{7}}, s, x) - x^{7}]$

(42)

>	$convert ({ans}_{2.1}, Int)$

$u (x, t) = \frac{\int_{- \infty}^{\infty} (\int_{- \infty}^{\infty} φ (x) {&ExponentialE;}^{−I x s} &DifferentialD; x) {&ExponentialE;}^{- k s^{2} t + I s x} &DifferentialD; s}{2 π}$

(43)

>	${pde}_{3} ≔ \frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) &semi;$ ${iv}_{3} ≔ u (x, 0) = μ, u (0, t) = λ &semi;$ $pdsolve ([{pde}_{3}, {iv}_{3}])$

${pde}_{3} ≔ \frac{\partial}{\partial t} u (x, t) = k (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

${iv}_{3} ≔ u (x, 0) = μ, u (0, t) = λ$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Heat" for 2nd order PDEs

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Series" for 2nd order PDEs

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

-> trying "WithSourceTerm"

-> trying "NonhomogeneousBC"

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Heat" for 2nd order PDEs

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

* trying method "Series" for 2nd order PDEs

-> trying "TwoBC"

-> trying "ThreeBCsincos"

-> trying "FourBC"

-> trying "ThreeBC"

-> trying "ThreeBCPeriodic"

-> trying "WithSourceTerm"

-> trying "ThreeVariables"

* trying method "Laplace" for 2nd order PDEs

-> trying a Laplace transformation

<- Laplace transformation successful

<- method "Laplace" for 2nd order PDEs successful

<- submethod "NonhomogeneousBC" successful

<- submethod "WithSourceTerm" successful

<- method "Series" for 2nd order PDEs successful

$u (x, t) = (λ - μ) ℒ^{- 1} (\frac{1}{{&ExponentialE;}^{\frac{\sqrt{k s} x}{k}} s}, s, t) + μ$

(44)

>	${pde}_{4} ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, t) - \frac{\frac{\partial^{2}}{\partial t^{2}} u (x, t)}{c^{2}} = 0 &semi;$ ${iv}_{4} ≔ u (x, 0) = f (x), D_{2} (u) (x, 0) = g (x), u (0, t) = 0 &semi;$ $pdsolve ([{pde}_{4}, {iv}_{4}]) assuming 0 < x, 0 < t$

${pde}_{4} ≔ \frac{\partial^{2}}{\partial x^{2}} u (x, t) - \frac{\frac{\partial^{2}}{\partial t^{2}} u (x, t)}{c^{2}} = 0$

${iv}_{4} ≔ u (x, 0) = f (x), D_{2} (u) (x, 0) = g (x), u (0, t) = 0$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

<- submethod "SemiInfiniteDomain" successful

<- method "Wave" for 2nd order PDEs successful

$u (x, t) = \frac{(\{\begin{array}{c} f (c t + x) - f (c t - x) + \frac{\int_{c t - x}^{c t + x} g (ζ) &DifferentialD; ζ}{c} & x < c t \\ f (c t + x) + f (- c t + x) + \frac{\int_{- c t + x}^{c t + x} g (ζ) &DifferentialD; ζ}{c} & c t < x \end{array})}{2}$

(45)

>	${pde}_{5} ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) - c^{2} (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) = f (x, t) &semi;$ ${iv}_{5} ≔ u (0, t) = 0, D_{1} (u) (0, t) = 0 &semi;$ $pdsolve ([{pde}_{5}, {iv}_{5}])$

${pde}_{5} ≔ \frac{\partial^{2}}{\partial t^{2}} u (x, t) - (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) c^{2} = f (x, t)$

${iv}_{5} ≔ u (0, t) = 0, D_{1} (u) (0, t) = 0$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs

-> trying "Cauchy"

-> trying "SemiInfiniteDomain"

-> trying "WithSourceTerm"

<- submethod "WithSourceTerm" successful

<- method "Wave" for 2nd order PDEs successful

$u (x, t) = \int_{0}^{x} (\int_{t - \frac{x - τ}{c}}^{t + \frac{x - τ}{c}} - \frac{f (τ, ζ)}{2 c} &DifferentialD; ζ) &DifferentialD; τ$

(46)

>	${pde}_{6} ≔ \frac{\partial}{\partial t} u (x, t) = u (x, t) (\frac{\partial^{2}}{\partial x^{2}} u (x, t)) &semi;$ ${iv}_{6} ≔ u (0, t) = 0, u (l, t) = 0 &semi;$ $pdsolve ([{pde}_{6}, {iv}_{6}])$

${pde}_{6} ≔ \frac{\partial}{\partial t} u (x, t) = u (x, t) (\frac{\partial^{2}}{\partial x^{2}} u (x, t))$

${iv}_{6} ≔ u (0, t) = 0, u (l, t) = 0$

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

-> trying "LinearInXT"

* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

-> trying SpecializeArbitraryConstants

<- trying SpecializeArbitraryConstants successful

<- method "SpecializeArbitraryConstants" for 2nd order PDEs successful

$u (x, t) = \frac{{_c}_{1} x (- x + l)}{2 {_c}_{1} t - 2 c__3}$

(47)

>	$pdetest (, [{pde}_{6}, {iv}_{6}])$

$[0, 0, 0]$

(48)

	See Also
	pdetest, pdsolve

Return to Index of Example Worksheets

Download Help Document

Maple

Maple Add-Ons

MapleSim

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim

Maple

Powerful math software that is easy to use

Maple Add-Ons

MapleSim

Advanced System Level Modeling

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim