In 2004, it was shown that basically all known solvable Abel equations belong to the Abel AIR class and that all their solutions can be expressed in terms of hypergeometric functions (see dsolve/references). There are six different cases. All of them can be solved using Maple 10.

Examples

PDEtools[declare](y(x), prime=x);

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

The 6th subclass, which is the simplest, admits solutions in terms of 0F1 (0-parameter) hypergeometric functions, Airy type; an example of this class is:

diff(y(x),x) = (a[1]*a[4]-a[3]*a[2])*(a[7]*y(x)+a[8])^3/((a[2]^2*a[7]+2*x*a[7]*a[2]*a[1]+x^2*a[7]*a[1]^2+a[5]*(a[3]*x+a[4])^2)*y(x)+a[8]*(x*a[1]+a[2])^2)/a[5]/a[8];

dsolve((2));

An example of the 4th subclass, hence admitting 0F1 (1-parameter) hypergeometric solutions of Bessel type:

diff(y(x),x) = -(c*b-a*d)*y(x)^2*r/(r*((-a+c^2)*x+c*d-b)*(x*a+b)*y(x)-s*(x*c+d)^2);

dsolve((4));

The 5th and 3rd AIR subclasses, respectively depending on 1 and 2 parameters, admit solutions in terms of 1F1 hypergeometric confluent functions. N-parameter (N > 1) Abel classes could not be solved by the Maple dsolve command in previous releases except for some particular cases. The 3rd AIR 2-parameter subclass is as general as the 1F1, second order linear equation, class. An example:

diff(y(x),x) = (-b*c+a*d)*y(x)/((x*c+d)*(x*a+b)*y(x)+((a-b*c)*x+b-d*b)*((a-c^2)*x+b-d*c));

dsolve((6));

The 2nd and 1st Abel AIR subclasses, respectively depending on 2 and 3 parameters, are rather difficult computational problems, and admit solutions in terms of 2F1 hypergeometric functions, which in the general case are complicated. Using new identities these solutions can be expressed in simpler forms in terms of the (new in Maple 10) confluent Heun functions. An example of the 1st AIR subclass:

diff(y(x),x) = (a*d-b*c)*(y(x)-1)*y(x)/(a*(x*c+d)*(a*x+b)*y(x)+((a-b*c)*x+b-b*d)*((a-c^2)*x+b-c*d));

A solution in terms of HeunC confluent functions:

dsolve((8));

Verify the solution.

odetest((9), (8));

$0$

You can also use the new solving routines with the dsolve command: dsolve(ode, y(x), [Abel_AIR]).

These new Abel AIR routines positively impact the ability of Maple to solve differential equations of other types too. The symmetry reduction process for many second and higher order nonlinear equations maps the problem into an Abel equation which is now solvable. Large families of first order linear and inverse linear equations, formerly solved using RootOfs of uncomputed integrals, as well as formerly unsolvable first order nonlinear Riccati families, can now be solved in terms of special functions through the new AIR code. In addition, second order linear equations of the Heun type can be solved in Maple 10. Because most differential equations are solved by mapping them into first order linear, nonlinear Riccati, or second order linear equations, these developments in the Abel sector provide new solutions for differential equation families of all types. Some examples illustrating this situation are in the following sections.

When using special functions to represent ODE solutions, a difficult mathematical problem is to determine whether the special function admits a representation in terms of simpler functions. For example, you may prefer to see the solution in terms of 2F1 hypergeometric functions instead of HeunC, and prefer a solution in terms of exponentials or sin instead of Kummer or Bessel functions.

To address this problem, the new Abel AIR routines have two mechanisms.

When the solution can be written in terms of simpler Liouvillian or hypergeometric functions, the routines automatically detect that, before computing any solution, and return the simpler representation.

By assigning the environment variable _Env_dsolve_Abel_AIR_use_simpler_functions to false or true, you can request to never or always (try to) compute a solution in terms of simpler functions.

The reason for providing the environment variable mechanism is twofold. Through it, you can make the routines return a simpler solution, when it exists, but its existence is difficult to determine a priori, or you can make them return the special function solution form, even when a solution in terms of simpler functions is known to the routines. This is useful for investigating the special cases of the more advanced functions entering alternative forms of the solution.

Examples

This is an example of the 1st Abel AIR subclass, where a 2F1 (3 parameter) representation of the solution is simpler than the one involving HeunC functions.

ode := diff(y(x),x) = -y(x)*(-1+y(x))/(((-1+b-a)*x+(a+1)^2-a*(1+c)-1)*y(x)-(a-x)*(-x+1+a-c));

$\mathrm{ode}≔\mathrm{y\text{'}}=-\frac{y\left(y-1\right)}{\left(\left(-1+b-a\right)x+{\left(a+1\right)}^2-a\left(c+1\right)-1\right)y-\left(a-x\right)\left(-x+1+a-c\right)}$

sol := dsolve(ode);

$\mathrm{sol}≔\mathrm{c\_\_1}+\frac{y^{-c+1}\left(-\left(\left(a-c+1\right)y-a+c+x-1\right)\left(-2+c\right)\mathrm{hypergeom}\left(\left[b-c+1\,a-c+1\right]\,\left[2-c\right]\,y\right)+\mathrm{hypergeom}\left(\left[b-c+2\,a-c+2\right]\,\left[3-c\right]\,y\right)y\left(y-1\right)\left(b-c+1\right)\left(a-c+1\right)\right)}{aby\left(y-1\right)\mathrm{hypergeom}\left(\left[b+1\,a+1\right]\,\left[c+1\right]\,y\right)+\mathrm{hypergeom}\left(\left[a\,b\right]\,\left[c\right]\,y\right)\left(a\left(y-1\right)+x\right)c}=0$

To see the representation of this solution in terms of HeunC functions, assign the environment variable _Env_dsolve_Abel_AIR_use_simpler_functions := false. To see a HeunG representation, use (new in Maple 10) convert(sol, HeunG).

The next example admits a solution that can be expressed in terms of elementary functions, entirely dispensing with the use of special functions.

ode := diff(y(x),x) = y(x)^2/(-2*x*y(x)+(x-1)*(x+1));

$\mathrm{ode}≔\mathrm{y\text{'}}=\frac{y^2}{-2yx+\left(x-1\right)\left(x+1\right)}$

dsolve(ode);

$y=-\frac{2}{\mathrm{RootOf}\left({\ⅇ}^{\mathrm{\_Z}}\mathrm{\_Z}x+\mathrm{c\_\_1}\mathrm{\_Z}x+{\ⅇ}^{\mathrm{\_Z}}\mathrm{\_Z}-2{\ⅇ}^{\mathrm{\_Z}}x-\mathrm{c\_\_1}\mathrm{\_Z}+2\mathrm{c\_\_1}x\right)}$

To see a 1F1, Kummer special function representation of the solution, assign false to the environment variable.

_Env_dsolve_Abel_AIR_use_simpler_functions := false;

$\mathrm{\_Env\_dsolve\_Abel\_AIR\_use\_simpler\_functions}≔\mathrm{false}$

dsolve(ode);

$\mathrm{c\_\_1}+\frac{\left(-\frac{\left(x+1\right)\mathrm{KummerM}\left(1\,3\,\frac{2}{y}\right)}{x-1}+\mathrm{KummerM}\left(2\,3\,\frac{2}{y}\right)\right)\left(1-x\right)}{\left(x+1\right)\mathrm{KummerU}\left(1\,3\,\frac{2}{y}\right)+\mathrm{KummerU}\left(2\,3\,\frac{2}{y}\right)\left(x-1\right)}=0$

Reset the environment variable.

_Env_dsolve_Abel_AIR_use_simpler_functions := '_Env_dsolve_Abel_AIR_use_simpler_functions':

New routines for mapping some relevant nonlinear first order families into Abel equations were added. These routines automatically take advantage of the old and new Abel ODE solving libraries. These mappings and the transformations used to perform them are also visible using the new Maple 10 convert/ODEs routines.

Example

PDEtools[declare](g(x), quiet):

diff(y(x),x) = 2*y(x)*((1/2*diff(g(x),x)*g(x)+(x+1)*g(x)+x^2-mu)*y(x)^(2*nu-1)+y(x)^nu*(1/2*diff(g(x),x)+1+x))/(nu-1)/(y(x)+g(x)*y(x)^nu);

$\mathrm{y\text{'}}=\frac{2y\left(\left(\frac{\mathrm{g\text{'}}g}{2}+\left(x+1\right)g+x^2-\mathrm{\mu }\right)y^{2\mathrm{\nu }-1}+y^{\mathrm{\nu }}\left(\frac{\mathrm{g\text{'}}}{2}+1+x\right)\right)}{\left(\mathrm{\nu }-1\right)\left(y+g{y}^{\mathrm{\nu }}\right)}$

dsolve((17), y(x));

Verify the solution.

odetest((18), (17), y(x));

$0$

You can also use this solving approach with the dsolve command: dsolve(ode, y(x), [equivalent_to_Abel]).

Similar to the Abel AIR problem, families of Riccati equations admit solutions in terms of hypergeometric functions; for these families, the new algorithms also provide solutions by mapping the equation into one of the six canonical solvable forms, depending on 0 (0F1 type), 1 (0F1 and 1F1 types), 2 (1F1 and 2F1 types), or 3 (2F1 type) parameters.

Examples

A Riccati equation of the 6th class, admitting Airy type solutions:

diff(y(x),x) = (a^2+x*c^2)/(a*d-c*b)*y(x)^2+2*(a*b+d*c*x)/(a*d-c*b)*y(x)+(b^2+x*d^2)/(a*d-c*b);

dsolve((20));

$y=\frac{\mathrm{AiryAi}\left(1\,-x\right)\mathrm{c\_\_1}d+\mathrm{AiryBi}\left(1\,-x\right)d-b\left(\mathrm{AiryAi}\left(-x\right)\mathrm{c\_\_1}+\mathrm{AiryBi}\left(-x\right)\right)}{\left(\mathrm{AiryAi}\left(-x\right)\mathrm{c\_\_1}+\mathrm{AiryBi}\left(-x\right)\right)a-\mathrm{AiryAi}\left(1\,-x\right)\mathrm{c\_\_1}c-\mathrm{AiryBi}\left(1\,-x\right)c}$

An example of the 3rd class, admitting 1F1 (2-parameter) solutions, expressible using Kummer functions:

diff(y(x),x) = (a^2-c*(s+r-x)*a+r*c^2*s)/(a*d-c*b)/x*y(x)^2+((2*b+(-s-r+x)*d)*a+2*c*((1/2*x-1/2*r-1/2*s)*b+r*s*d))/(a*d-c*b)/x*y(x)+(b^2-(s+r-x)*d*b+r*d^2*s)/(a*d-c*b)/x;

dsolve((22), y(x));

$y=\frac{\mathrm{KummerM}\left(-r+1\,1+s-r\,x\right)dr-\mathrm{KummerU}\left(-r+1\,1+s-r\,x\right)\mathrm{c\_\_1}drs-b\left(\mathrm{KummerU}\left(-r\,1+s-r\,x\right)\mathrm{c\_\_1}+\mathrm{KummerM}\left(-r\,1+s-r\,x\right)\right)}{\left(\mathrm{KummerU}\left(-r\,1+s-r\,x\right)\mathrm{c\_\_1}+\mathrm{KummerM}\left(-r\,1+s-r\,x\right)\right)a+\mathrm{KummerU}\left(-r+1\,1+s-r\,x\right)\mathrm{c\_\_1}crs-\mathrm{KummerM}\left(-r+1\,1+s-r\,x\right)cr}$

An example of the 2nd class, admitting 2F1 (2-parameter) solutions, expressible in simpler terms using HeunC confluent functions new in Maple 10:

diff(y(x),x) = (a^2+r*x*c^2-a*s*c)/(a*d-c*b)/(x-1)/x*y(x)^2+(2*r*x*c*d+(2*b-s*d)*a-b*s*c)/(a*d-c*b)/(x-1)/x*y(x)+(-b*s*d+r*x*d^2+b^2)/(a*d-c*b)/(x-1)/x;

dsolve((24), y(x));

In Maple 10, the five Heun functions were introduced. The solutions to the corresponding five second order linear differential equations cannot be expressed with previously existing functions of the mathematical language. The Heun functions include, among others, the Lame, Spheroidal wave, Mathieu, hypergeometric 2F1, 1F1, and 0F1 functions as particular cases, and are also connected to elliptic functions. As a benchmark, basically all the second order linear equations of Kamke's book have their solution expressible in terms of Heun functions.

Taking this into account, new routines for solving the five Heun equations were implemented in dsolve, as well as for solving the whole classes of equations one can derive from these five by changing variables

where $\left\{a\,b\,c\,d\,k\right\}$ are any constants and $P$ can be any function of $x$. Due to the generality and rich structure of Heun functions, their use for solving second order linear equations made a large number of formerly unsolvable equations solvable, making this pioneering Maple step one of the relevant milestones in the developments in this area.

Examples

Lame's equation in one of its algebraic forms: this is the first time its solution can be expressed in a computer algebra system.

diff(y(x),x,x) + 1/2*(1/x+1/(x-1)+1/(x-a))*diff(y(x),x) + 1/4*(a*h-nu*(nu+1)*x)/x/(x-1)/(x-a)*y(x) = 0;

$\mathrm{y\text{'}\text{'}}+\frac{\left(\frac{1}{x}+\frac{1}{x-1}+\frac{1}{x-a}\right)\mathrm{y\text{'}}}{2}+\frac{\left(ah-\mathrm{\nu }\left(\mathrm{\nu }+1\right)x\right)y}{4x\left(x-1\right)\left(x-a\right)}=0$

dsolve((26));

$y=\mathrm{c\_\_1}\mathrm{HeunG}\left(a\,-\frac{ah}{4}\,-\frac{\mathrm{\nu }}{2}\,\frac{\mathrm{\nu }}{2}+\frac{1}{2}\,\frac{1}{2}\,\frac{1}{2}\,x\right)+\mathrm{c\_\_2}\sqrt{x}\mathrm{HeunG}\left(a\,\frac{1}{4}+\frac{\left(-h+1\right)a}{4}\,1+\frac{\mathrm{\nu }}{2}\,-\frac{\mathrm{\nu }}{2}+\frac{1}{2}\,\frac{3}{2}\,\frac{1}{2}\,x\right)$

The spheroidal wave function equation: the solution is expressible in terms of HeunC.

diff(y(x),x,x) = 2*(b+1)*x/(1-x^2)*diff(y(x),x) + (4*q*x^2-c)/(1-x^2)*y(x);

dsolve((28));

$y=\mathrm{c\_\_1}\mathrm{HeunC}\left(0\,-\frac{1}{2}\,b\,q\,\frac{1}{4}-\frac{b}{4}-\frac{c}{4}\,x^2\right)+\mathrm{c\_\_2}x\mathrm{HeunC}\left(0\,\frac{1}{2}\,b\,q\,\frac{1}{4}-\frac{b}{4}-\frac{c}{4}\,x^2\right)$

The Mathieu equation is a particular case of Heun's equations - this is a rational form of it and the standard Mathieu function solution.

ode := diff(y(x),x,x) = x/(1-x^2)*diff(y(x),x)+((4*x^2-2)*q-a)/(1-x^2)*y(x);

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}=\frac{x\mathrm{y\text{'}}}{-x^2+1}+\frac{\left(\left(4x^2-2\right)q-a\right)y}{-x^2+1}$

dsolve(ode);

$y=\mathrm{c\_\_1}\mathrm{MathieuC}\left(a\,q\,\arccos \left(x\right)\right)+\mathrm{c\_\_2}\mathrm{MathieuS}\left(a\,q\,\arccos \left(x\right)\right)$

This equation is also solvable in terms of Heun functions.

dsolve(ode,[Heun]);

$y=\mathrm{c\_\_1}\mathrm{HeunC}\left(0\,-\frac{1}{2}\,-\frac{1}{2}\,q\,\frac{3}{8}-\frac{a}{4}-\frac{q}{2}\,x^2\right)+\mathrm{c\_\_2}\mathrm{HeunC}\left(0\,\frac{1}{2}\,-\frac{1}{2}\,q\,\frac{3}{8}-\frac{a}{4}-\frac{q}{2}\,x^2\right)x$

The Gauss 2F1 hypergeometric equation and its standard hypergeom 2F1 solution:

ode := diff(y(x),x,x) + (c/x + (a+1+b-c)/(x-1))*diff(y(x),x) - (b*a/x-b*a/(x-1))*y(x);

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}+\left(\frac{c}{x}+\frac{1+a+b-c}{x-1}\right)\mathrm{y\text{'}}-\left(\frac{ba}{x}-\frac{ba}{x-1}\right)y$

dsolve(ode);

$y=\mathrm{c\_\_1}\mathrm{hypergeom}\left(\left[a\,b\right]\,\left[c\right]\,x\right)+\mathrm{c\_\_2}{x}^{-c+1}\mathrm{hypergeom}\left(\left[b-c+1\,a-c+1\right]\,\left[2-c\right]\,x\right)$

The hypergeom 2F1 function is a particular case of HeunG and also of HeunC so the solution to Gauss' equation can also be expressed as:

dsolve(ode,[HeunG]);

$y=\mathrm{c\_\_1}\mathrm{HeunG}\left(1\,ab\,a\,b\,c\,0\,x\right)+\mathrm{c\_\_2}{x}^{-c+1}\mathrm{HeunG}\left(1\,\left(b-c+1\right)\left(a-c+1\right)\,b-c+1\,a-c+1\,2-c\,0\,x\right)$

dsolve(ode,[HeunC]);

$y=\mathrm{c\_\_1}{\left(x-1\right)}^{-a}\mathrm{HeunC}\left(0\,a-b\,c-1\,0\,\frac{\left(a+b-1\right)c}{2}-ab+\frac{1}{2}\,-\frac{1}{x-1}\right)+\mathrm{c\_\_2}{\left(x-1\right)}^{-b}\mathrm{HeunC}\left(0\,-a+b\,c-1\,0\,\frac{\left(a+b-1\right)c}{2}-ab+\frac{1}{2}\,-\frac{1}{x-1}\right)$

A large number of relationships between mathematical functions are visible through their connection with Heun functions; this is important for the representation of solutions in applied mathematics problems.

The Heun solution routines are also sensitive to assumptions and explore automorphisms of the Heun equations to rewrite the solution free of integrals when possible.

You can use the new algorithms for Heun function solutions with the dsolve command: dsolve(ode, y(x), [Heun]) (optionally HeunG, HeunC, HeunB, HeunD, or HeunT instead of Heun).

Enhancements were made for computing solutions for linear equations in the presence of periodic functions, typically those of elliptic type like JacobiSN or WeierstrassP. These improvements also combine with the new ability to compute Heun function solutions to obtain a representation for the solution of important classic ODE problems.

Examples

This is Kamke's second order linear example 2.27, the Jacobi form of Lame's equation.

diff(y(x),x,x)-(n*(n+1)*k^2*JacobiSN(x,k)^2+B)*y(x) = 0;

$\mathrm{y\text{'}\text{'}}-\left(n\left(n+1\right)k^2{\mathrm{JacobiSN}\left(x\,k\right)}^2+B\right)y=0$

The new routines for the computation of elliptic function solutions combine with those for computing Heun function solutions to obtain:

dsolve((37));

An equation of third order involving WeierstrassP functions

diff(y(x),x,x,x)-(8*WeierstrassP(x,g2,g3)+a)*diff(y(x),x)-4*WeierstrassPPrime(x,g2,g3)*y(x) = 0;

$\mathrm{y\text{'}\text{'}\text{'}}-\left(8\mathrm{WeierstrassP}\left(x\,\mathrm{g2}\,\mathrm{g3}\right)+a\right)\mathrm{y\text{'}}-4\mathrm{WeierstrassPPrime}\left(x\,\mathrm{g2}\,\mathrm{g3}\right)y=0$

Do not compute the integrals. In the uncomputed form, you can see the structure of the solution.

dsolve((39), useInt);

You can also use the algorithms for solving linear equations in the presence of periodic functions in the coefficients with the dsolve command: dsolve(ode, y(x), [with_periodic_functions]). See also DEtools[dperiodic_sols].

Kovacic's algorithm includes a complete prescription for computing Liouvillian solutions for second order linear ODEs with rational coefficients. The extension of that algorithm for third order linear equations was developed by Singer and Ulmer years ago, but an efficient computational implementation of it is still difficult at present. In this release, a step towards implementing this algorithm has been given, with the development of routines handling the imprimitive case.

Example

diff(y(x),x,x,x) + 1/6*(26*x-9)/x/(x-1)*diff(y(x),x,x) + 1/27*1/x*(76*x-55)/(x-1)^2*diff(y(x),x) + 28/729*1/x/(x-1)^2*y(x) = 0;

$\mathrm{y\text{'}\text{'}\text{'}}+\frac{\left(26x-9\right)\mathrm{y\text{'}\text{'}}}{6x\left(x-1\right)}+\frac{\left(76x-55\right)\mathrm{y\text{'}}}{27x{\left(x-1\right)}^2}+\frac{28y}{729x{\left(x-1\right)}^2}=0$

dsolve((41));

$y=\mathrm{c\_\_1}{\ⅇ}^{\int \mathrm{RootOf}\left(4+\left(2916x^3-5832x^2+2916x\right){\mathrm{\_Z}}^3+\left(972x^2-972x\right){\mathrm{\_Z}}^2+\left(108x-27\right)\mathrm{\_Z}\,\mathrm{index}=1\right)\ⅆx}+\mathrm{c\_\_2}{\ⅇ}^{\int \mathrm{RootOf}\left(4+\left(2916x^3-5832x^2+2916x\right){\mathrm{\_Z}}^3+\left(972x^2-972x\right){\mathrm{\_Z}}^2+\left(108x-27\right)\mathrm{\_Z}\,\mathrm{index}=2\right)\ⅆx}+\mathrm{c\_\_3}{\ⅇ}^{\int \mathrm{RootOf}\left(4+\left(2916x^3-5832x^2+2916x\right){\mathrm{\_Z}}^3+\left(972x^2-972x\right){\mathrm{\_Z}}^2+\left(108x-27\right)\mathrm{\_Z}\,\mathrm{index}=3\right)\ⅆx}$

To compute these integrals, use value; to directly obtain the solution with the integrals computed, use the useint option of dsolve.

The routines for mapping ODE problems into other ones are a sort of powertoys for differential equations, written by our research group while developing new algorithms and made available to Maple users as convert/ODEs routines. The package, growing with each release, has been reorganized in a modular way, now uniformingly providing functionality through new optional arguments. Frequently used mappings were added; these are:

MobiusX and MobiusY, to respectively perform Mobius transformations of the independent and dependent variables in arbitrary ODEs;

MobiusR, to perform, on second order linear ODEs, the composition of three transformations: To Riccati -> MobiusY -> to second order linear, resulting in a single non-local transformation with valuable properties;

Abel, to map certain families of first order nonlinear equations into Abel type equations.

Examples

MobiusX transformations on a second order linear ODE with constant coefficients:

ode := diff(y(x),x,x) = c[1]*diff(y(x),x)+c[0]*y(x);

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}=c_1\mathrm{y\text{'}}+c_{0}y$

Use $u\left(t\right)$ as a new dependent variable.

convert(ode, MobiusX, [a[0],a[1],b[0],b[1]], u(t));

In this output, you see the resulting ODE in $u\left(t\right)$ and the Mobius transformation used. The arguments after MobiusX are all optional - see convert/ODEs.

Among useful optional new functionality, there is an option to specify a simplifier to be used instead of the default one. For example, this specifies a MobiusX transformation of the form $x=\frac{t-1}{t+1}$ and requests the output be in partial fraction decomposition form.

convert(ode, MobiusX, [1,-1,1,1], u(t), parfrac);

$u_{t,t}=\left(\frac{2c_1}{{\left(t+1\right)}^2}-\frac{2}{t+1}\right)u_t+\frac{4c_{0}u\left(t\right)}{{\left(t+1\right)}^4},\left\{x=\frac{t-1}{t+1}\,y=u\left(t\right)\right\}$

When you know the output cannot be simplified or want to get it faster with no simplification, you can use the optional argument simplifier=NONE.

MobiusY transformations of the dependent variable - in this example $y$ - transform a second order linear equation into a nonlinear equation, while keeping the corresponding first order Riccati equation in the same class. This is the Riccati equation associated with ode.

Keep $y$ as a dependent variable and take $\mathrm{\_F1}\left(x\right)=1$.

eval(convert(ode, Riccati, keep), _F1(x)=1);

$\mathrm{y\text{'}}=y^2+c_{1}y-c_0,\left\{\mathrm{\_a}\left(x\right)={\ⅇ}^{-\left(\int y\ⅆx\right)}\mathrm{c\_\_1}\right\}$

This is a MobiusY transformation, $y=\frac{\left(fu+g\right)}{\left(ru+s\right)}$, where all of $\left\{f\,g\,r\,s\,u\,y\right\}$ are functions of $x$, resulting in another Riccati equation.

PDEtools[declare]( (f,g,r,s,u)(x), quiet);

convert((46)[1], MobiusY, [f,g,r,s](x), u(x));

$\mathrm{u\text{'}}=\frac{\left(fr{c}_1-r^2{c}_0-\mathrm{f\; \text{'}}r+\mathrm{r\text{'}}f+f^2\right)u^2}{fs-rg}+\frac{\left(-\mathrm{f\; \text{'}}s-\mathrm{g\text{'}}r+\mathrm{r\text{'}}g+\mathrm{s\text{'}}f+\left(c_{1}s+2g\right)f-2sr{c}_0+rg{c}_1\right)u}{fs-rg}+\frac{-s^2{c}_0+sg{c}_1-\mathrm{g\text{'}}s+\mathrm{s\text{'}}g+g^2}{fs-rg},\left\{y=\frac{fu+g}{ru+s}\right\}$

DEtools[odeadvisor]((47)[1], u(x), [Riccati]);

$\left[\mathrm{\_Riccati}\right]$

In fact, MobiusY transformations define the Riccati class of equations, so through these transformations any Riccati equation can be obtained from any other one.

MobiusR transformations are non-local transformations (contain an integral with derivatives of the dependent variable in the integrand), have the ability of generating the whole second order linear ODE from any given one, and, for particular cases of the transformation parameters, result in equations with remarkable properties. Consider an arbitrary second order linear ODE:

ode := diff(y(x),x,x)= c[1](x)*diff(y(x),x)+c[0](x)*y(x);

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}=c_1\left(x\right)\mathrm{y\text{'}}+c_0\left(x\right)y$

Applying the particular case of MobiusR where the four functions $\left[f\,g\,r\,s\right]$ entering the intermediate MobiusY are equal to $\left[0\,1\,1\,0\right]$, you obtain the following, using $u$ as the new variable.

ode_u := convert(ode, MobiusR, [0,1,1,0], y(x),u(x));

$\mathrm{ode\_u}≔\mathrm{u\text{'}\text{'}}=\frac{\left(-c_1\left(x\right)c_0\left(x\right)+c_0^{\text{'}}\right)\mathrm{u\text{'}}}{c_0\left(x\right)}+u{c}_0\left(x\right),\left\{y={\ⅇ}^{\int \frac{u{c}_0\left(x\right)}{\mathrm{u\text{'}}}\ⅆx}\right\}$

Applying to this result the same MobiusR, you reobtain the original equation.

convert(ode_u[1], MobiusR, [0,1,1,0], u(x),y(x));

$\mathrm{y\text{'}\text{'}}=c_1\left(x\right)\mathrm{y\text{'}}+c_0\left(x\right)y,\left\{u={\ⅇ}^{\int \frac{c_0\left(x\right)y}{\mathrm{y\text{'}}}\ⅆx}\right\}$

In other words, this particular case of MobiusR transformations has itself for an inverse. Another important property: Depending on the equation, this transformation adds a so-called false singularity (the singularity actually exists, the exponents differ by an integer, but the power series solution does not require a logarithmic term); for details, see convert/ODEs.

Keeping with the developments of DE testing tools, in this release, odetest is able to test ODE series solutions.

Examples

ode := [diff(y(x),x,x)+diff(y(x),x)^2=0, y(a)=0, D(y)(a)=1];

$\mathrm{ode}≔\left[\mathrm{y\text{'}\text{'}}+{\mathrm{y\text{'}}}^2=0\,y\left(a\right)=0\,\mathrm{D}\left(y\right)\left(a\right)=1\right]$

sol := dsolve( ode, y(x), type='series');

$\mathrm{sol}≔y=\left(x-a\right)-\frac{1}{2}{\left(x-a\right)}^2+\frac{1}{3}{\left(x-a\right)}^3-\frac{1}{4}{\left(x-a\right)}^4+\frac{1}{5}{\left(x-a\right)}^5+O\left({\left(x-a\right)}^6\right)$

'series' specifies the type of test.

odetest(sol, ode, series);

$\left[0\,0\,0\right]$

Leading the implementation of Traveling Wave Solutions (TWS) in computer algebra systems for Maple 9.5, for this release these libraries were extended to compute:

TWS expanding the solutions in powers of different functions (your choice of function, possibly the identity)

TWS as compositions of functions exploring differential polynomial extensions

Only the system of ordinary differential equations  equivalent to the given autonomous PDE system

Examples

Korteweg-deVries PDE:

with(PDEtools, TWSolutions);

$\left[\mathrm{TWSolutions}\right]$

KdV := U[t] = U[x,x,x] - 6*U[]*U[x];

$\mathrm{KdV}≔u_t=-6u{u}_x+u_{x,x,x}$

Introduce tau as the usual linear combination of $x,t$, but convert the PDE problem into an ODE not using any particular function transformation, just the identity, then return this resulting ODE and the transformation used to obtain it.

TWSolutions(KdV, function = identity, output = ODE);

$\left[\left\{-{\mathrm{\_C1}}^3{u}_{\mathrm{\tau },\mathrm{\tau },\mathrm{\tau }}+\left(6u\left(\mathrm{\tau }\right)\mathrm{\_C1}+\mathrm{\_C2}\right)u_{\mathrm{\tau }}\right\}\,\left\{\mathrm{\tau }=\mathrm{\_C1}x+\mathrm{\_C2}t+\mathrm{c\_\_3}\,u\left(\mathrm{\tau }\right)=u\right\}\right]$

This type of manipulation is useful for performing further analysis. You can see that the ODE is a total derivative; integrating it, we obtain a type 1 Painleve equation, as the Ablowitz-Ramani-Segur (ARS) conjecture suggests.

op([1,1],(64));

$-{\mathrm{\_C1}}^3{u}_{\mathrm{\tau },\mathrm{\tau },\mathrm{\tau }}+\left(6u\left(\mathrm{\tau }\right)\mathrm{\_C1}+\mathrm{\_C2}\right)u_{\mathrm{\tau }}$

This is an exact equation (see DEtools[firint]). A first integral is:

DEtools[firint]( (65) );

$-\frac{3\mathrm{\_C1}{u\left(\mathrm{\tau }\right)}^2+\mathrm{\_C2}u\left(\mathrm{\tau }\right)}{{\mathrm{\_C1}}^3}+u_{\mathrm{\tau },\mathrm{\tau }}+\mathrm{c\_\_3}=0$

This is the Painleve type 1 equation according to the ARS conjecture.

isolate((66), diff(u(tau),tau,tau));

$u_{\mathrm{\tau },\mathrm{\tau }}=\frac{3\mathrm{\_C1}{u\left(\mathrm{\tau }\right)}^2+\mathrm{\_C2}u\left(\mathrm{\tau }\right)}{{\mathrm{\_C1}}^3}-\mathrm{c\_\_3}$

The efficiency of the Traveling Wave Solutions libraries was also enhanced.

The following is a nonlinear PDE system example in five unknowns, containing four PDEs, extracted from Landau and Lifshitz's "Fluid Mechanics" book. To obtain enhanced display and simplify the input:

PDEtools[declare]((u,w,Tau)(x,z,t),p(x,z),Ts(z));

$u\left(x\,z\,t\right)\mathrm{will\; now\; be\; displayed\; as}u$

$w\left(x\,z\,t\right)\mathrm{will\; now\; be\; displayed\; as}w$

$\mathrm{{\rm T}}\left(x\,z\,t\right)\mathrm{will\; now\; be\; displayed\; as}\mathrm{{\rm T}}$

$p\left(x\,z\right)\mathrm{will\; now\; be\; displayed\; as}p$

$\mathrm{Ts}\left(z\right)\mathrm{will\; now\; be\; displayed\; as}\mathrm{Ts}$

with(DEtools,diff_table);

$\left[\mathrm{diff\_table}\right]$

U := diff_table(u(x,z,t)):  W := diff_table(w(x,z,t)):

P := diff_table(p(x,z)):  T := diff_table(Tau(x,z,t)):

The PDE system is:

e1 := U[x]+W[z] = 0;

$\mathrm{e1}≔u_x+w_z=0$

e2 := U[t] + U[]*U[x] + W[]*U[z] = -P[x] + sigma*(U[x,x]+U[z,z]);

$\mathrm{e2}≔u{u}_x+u_{z}w+u_t=-p_x+\mathrm{\sigma }\left(u_{x,x}+u_{z,z}\right)$

e3 := W[t]+U[]*W[x]+W[]*W[z] = -P[z]+sigma*(W[x,x]+W[z,z])+sigma*rho*(T[]-Ts(z));

$\mathrm{e3}≔u{w}_x+w{w}_z+w_t=-p_z+\mathrm{\sigma }\left(w_{x,x}+w_{z,z}\right)+\mathrm{\sigma }\mathrm{\rho }\left(\mathrm{{\rm T}}-\mathrm{Ts}\right)$

e4 := T[t]+U[]*T[x]+W[]*T[z] = T[x,x]+T[z,z];

$\mathrm{e4}≔{\mathrm{{\rm T}}}_{x}u+{\mathrm{{\rm T}}}_{z}w+{\mathrm{{\rm T}}}_t={\mathrm{{\rm T}}}_{x,x}+{\mathrm{{\rm T}}}_{z,z}$

sys := [e1,e2,e3,e4]:

This system represents a 2-D (coordinates $x,z$) fluid layer, open to air, subjected to a vertical temperature gradient (Nabla of $T\left(x\,z\,t\right)$) and embedded in a gravitational field. The constants sigma and rho are related to the viscosity, thermal diffusivity, the gravitational constant, and the coefficient of thermal expansion. A set of traveling wave solutions can be computed for this system in 2 seconds (typical PC 2 GigaHertz, 2004). The nonsingular case after removing redundant constant solutions:

TWSolutions( sys, singsol = false, remove_redundant );

For p = constant, this system also admits solutions in terms of the WeierstrassP elliptic function - to see this solution add the optional argument function = WeierstrassP to the calling sequence above.

In previous releases, Maple started exploring a computationally powerful idea: that of using Differential Polynomial Forms (DPFs) for representing non-polynomial mathematical objects, like mathematical functions, their composition, and more. For this release, the existing DPF representations were polished, allowing you, when possible, the choice of lower order (nonlinear) or higher order (linear) DPFs; many new DPFs were implemented, including those for the new special functions; some cases of indefinite integrals which can be represented in DPF were added; and a new library for computing DPFs for compositions constructed with the @ or @@ operators, so including inverse functions of any order, has been added.

Examples

New functions are handled: