For 1st order ODEs, the simplest problem beyond reach of complete solving algorithms is known as Abel equations. These are equations of the form

where $y\equiv y\left(x\right)$ is the unknown and the $f_i\equiv f_i\left(x\right)$ and $g_j\equiv g_j\left(x\right)$ are arbitrary functions of $x$. The biggest subclass of Abel equations known to be solvable was discovered by our research team and is the AIR 4-parameter class. New in Maple 15, two additional 1-parameter classes of Abel equations, beyond the AIR class, are now also solvable.

Examples

PDEtools[declare](y(x), prime=x);

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

This equation, depending on one parameter $\mathrm{\alpha }$, is now solved in terms of Bessel functions

ode[1] := diff(y(x),x) = (y(x)-x-alpha)/((2*x+2*alpha)*y(x)+2*x);

${\mathrm{ode}}_1≔\mathrm{y\text{'}}=\frac{y-x-\mathrm{\alpha }}{\left(2x+2\mathrm{\alpha }\right)y+2x}$

sol[1] := dsolve(ode[1]);

${\mathrm{sol}}_1≔\mathrm{c\_\_1}+\frac{2\mathrm{BesselK}\left(\frac{\sqrt{4\mathrm{\alpha }+1}}{2}+1\,-\sqrt{y^2+x}\right)\sqrt{y^2+x}+\left(\sqrt{4\mathrm{\alpha }+1}+2y+1\right)\mathrm{BesselK}\left(\frac{\sqrt{4\mathrm{\alpha }+1}}{2}\,-\sqrt{y^2+x}\right)}{-2\mathrm{BesselI}\left(\frac{\sqrt{4\mathrm{\alpha }+1}}{2}+1\,-\sqrt{y^2+x}\right)\sqrt{y^2+x}+\left(\sqrt{4\mathrm{\alpha }+1}+2y+1\right)\mathrm{BesselI}\left(\frac{\sqrt{4\mathrm{\alpha }+1}}{2}\,-\sqrt{y^2+x}\right)}=0$

odetest(sol[1], ode[1]);

$0$

The related class of Abel equations that is now entirely solvable consists of the set of equations that can be obtained from (2.1.2) by changing variables

where $F\left(x\right)$ and the four $P_i\left(x\right),Q_j\left(x\right)$ are arbitrary rational functions of $x$; this is the most general transformation that preserves the form of Abel equations and thus generates Abel ODE classes.

Another Abel equation, also depending on one parameter, is now, surprisingly, solvable entirely in terms of powers, which will be integer whenever $\mathrm{\alpha }$ is integer

ode[2] := diff(y(x),x) = -1/2*(y(x)-2)*(((x-1)*alpha+x)*y(x)-2*alpha)/x/((-alpha+x)*y(x)+(x-1)*alpha-x);

${\mathrm{ode}}_2≔\mathrm{y\text{'}}=-\frac{\left(y-2\right)\left(\left(\left(x-1\right)\mathrm{\alpha }+x\right)y-2\mathrm{\alpha }\right)}{2x\left(\left(-\mathrm{\alpha }+x\right)y+\left(x-1\right)\mathrm{\alpha }-x\right)}$

sol[2] := dsolve(ode[2]);

${\mathrm{sol}}_2≔\mathrm{c\_\_1}+\frac{{\left(-\frac{\mathrm{\alpha }\left(2+\left(y^2-2y\right)x\right){\left(\left(1+\mathrm{\alpha }\right)x-3\mathrm{\alpha }\right)}^2}{x{\left(x\left(\mathrm{\alpha }+y-1\right)-\mathrm{\alpha }\left(y+1\right)\right)}^2}\right)}^{\mathrm{\alpha }-1}{\left(-\frac{\left({\left(y-2\right)}^2\left(\mathrm{\alpha }-1\right)x^2-y\mathrm{\alpha }\left(\mathrm{\alpha }-1\right)\left(y-2\right)x-2{\mathrm{\alpha }}^2\right){\left(\left(1+\mathrm{\alpha }\right)x-3\mathrm{\alpha }\right)}^2}{x^2{\left(x\left(\mathrm{\alpha }+y-1\right)-\mathrm{\alpha }\left(y+1\right)\right)}^2}\right)}^{-\mathrm{\alpha }}{\left(-\frac{\mathrm{\alpha }}{x}\right)}^{1+\mathrm{\alpha }}{\left(\left(x-3\right)\mathrm{\alpha }+x\right)}^2}{{\left(\left(x-y-1\right)\mathrm{\alpha }+\left(y-1\right)x\right)}^2}=0$

As in the case of equation (2.1.2), the entire set of equations obtained by changing variables in (2.1.5) using the transformation that generates Abel ODE classes are now also solvable.

By using new algorithms developed by our research team, the dsolve command can additionally solve 11 nonlinear 2nd order ODE families that have no point symmetries and admit no integrating factors depending only on two of $\left\{x\,y\,\mathrm{y\text{'}}\right\}$. Each of these families of equations is parametrized by arbitrary functions of the independent and dependent variables, and the equations are solved by dsolve in Maple 15 for any values of these parametrizing functions. For 3 of these 11 families of equations, a general solution is computable directly, skipping the reduction of order step. For the other 8 families of equations, the original 2nd order ODE is systematically reduced to one of 1st order and dsolve will return a general solution when the 1st order equation is solvable with the existing algorithms. In what follows, an illustration of some of these newly solvable families of equations is presented.

Examples

An ODE family parametrized by an arbitrary function $G\left(y\right)$

ode[3] := diff(diff(y(x),x),x) = (G(y(x)))/(-x + G(y(x)))/D(G)(y(x))/x + (x + G(y(x)) + x^2)/(x-G(y(x)))/x*diff(y(x),x) + ((-x + G(y(x)))*`@@`(D,2)(G)(y(x))-2*(1/2 + x)*D(G)(y(x))^2)/(x-G(y(x)))/D(G)(y(x))*diff(y(x),x)^2 + D(G)(y(x))^2*x/(x-G(y(x)))*diff(y(x),x)^3;

${\mathrm{ode}}_3≔\mathrm{y\text{'}\text{'}}=\frac{G\left(y\right)}{\left(-x+G\left(y\right)\right)\mathrm{D}\left(G\right)\left(y\right)x}+\frac{\left(x+G\left(y\right)+x^2\right)\mathrm{y\text{'}}}{\left(x-G\left(y\right)\right)x}+\frac{\left(\left(-x+G\left(y\right)\right){\mathrm{D}}^{\left(2\right)}\left(G\right)\left(y\right)-2\left(\frac{1}{2}+x\right){\mathrm{D}\left(G\right)\left(y\right)}^2\right){\mathrm{y\text{'}}}^2}{\left(x-G\left(y\right)\right)\mathrm{D}\left(G\right)\left(y\right)}+\frac{{\mathrm{D}\left(G\right)\left(y\right)}^{2}x{\mathrm{y\text{'}}}^3}{x-G\left(y\right)}$

This ODE has no point symmetries, the determining PDE for them only admits both infinitesimals equal to zero:

PDEtools[DeterminingPDE](ode[3]);

$\left\{{\mathrm{\_\η}}_y\left(x\,y\right)=0\,{\mathrm{\_\ξ}}_x\left(x\,y\right)=0\right\}$

A solution for any of the members of this ODE family ${\mathrm{ode}}_3$, that is regardless of the form of the mapping $G$, can now be computed

sol[3] := dsolve(ode[3]);

${\mathrm{sol}}_3≔\mathrm{c\_\_2}+\frac{x\mathrm{KummerM}\left(-\mathrm{c\_\_1}\,1-\mathrm{c\_\_1}\,-x+G\left(y\right)\right)-\mathrm{c\_\_1}{\ⅇ}^{-x+G\left(y\right)}}{x\mathrm{KummerU}\left(-\mathrm{c\_\_1}\,1-\mathrm{c\_\_1}\,-x+G\left(y\right)\right)}=0$

Verify this result

odetest(sol[3], ode[3]);

$0$

Analogously, this other new ODE family can also be solved for arbitrary values of the parameter $\mathrm{\alpha }$ and the function parameter $G\left(y\right)$

ode[4] := diff(y(x), x, x) = (alpha*exp(1/x)*x + x^2*diff(G(x),x) + alpha*(ln(y(x)) + 2))/(exp(1/x)*x + ln(y(x)))/alpha/y(x)*diff(y(x),x)^2 + ((2*x^3*diff(G(x),x) + alpha*(-1 + x))*exp(1/x) + 2*x^2*diff(G(x),x)*ln(y(x)))/x/(exp(1/x)*x + ln(y(x)))/alpha*diff(y(x),x) + (x^2*exp(2/x) + 2*x*exp(1/x)*ln(y(x)) + ln(y(x))^2)*diff(G(x),x)/(exp(1/x)*x + ln(y(x)))/alpha*y(x);

${\mathrm{ode}}_4≔\mathrm{y\text{'}\text{'}}=\frac{\left(\mathrm{\alpha }{\ⅇ}^{\frac{1}{x}}x+x^2\mathrm{G\text{'}}+\mathrm{\alpha }\left(\ln \left(y\right)+2\right)\right){\mathrm{y\text{'}}}^2}{\left({\ⅇ}^{\frac{1}{x}}x+\ln \left(y\right)\right)\mathrm{\alpha }y}+\frac{\left(\left(2x^3\mathrm{G\text{'}}+\left(x-1\right)\mathrm{\alpha }\right){\ⅇ}^{\frac{1}{x}}+2x^2\mathrm{G\text{'}}\ln \left(y\right)\right)\mathrm{y\text{'}}}{x\left({\ⅇ}^{\frac{1}{x}}x+\ln \left(y\right)\right)\mathrm{\alpha }}+\frac{\left(x^2{\ⅇ}^{\frac{2}{x}}+2x{\ⅇ}^{\frac{1}{x}}\ln \left(y\right)+{\ln \left(y\right)}^2\right)\mathrm{G\text{'}}y}{\left({\ⅇ}^{\frac{1}{x}}x+\ln \left(y\right)\right)\mathrm{\alpha }}$

sol[4] := dsolve(ode[4], y(x));

${\mathrm{sol}}_4≔y={\ⅇ}^{\frac{\int -\frac{x{\ⅇ}^{\frac{1}{x}+\int \frac{\mathrm{c\_\_1}\mathrm{\alpha }-G\left(x\right)}{\mathrm{c\_\_1}\mathrm{\alpha }x-G\left(x\right)x+\mathrm{\alpha }}\ⅆx}\left(\mathrm{c\_\_1}\mathrm{\alpha }-G\left(x\right)\right)}{\mathrm{c\_\_1}\mathrm{\alpha }x-G\left(x\right)x+\mathrm{\alpha }}\ⅆx+\mathrm{c\_\_2}}{{\ⅇ}^{\int \frac{\mathrm{c\_\_1}\mathrm{\alpha }-G\left(x\right)}{\mathrm{c\_\_1}\mathrm{\alpha }x-G\left(x\right)x+\mathrm{\alpha }}\ⅆx}}}$

The following example shows a different kind of situation, where the nonlinear ODE problem is now reducible with new algorithms; the ODE family also does not admit point symmetries, and is parametrized by two functions $G\left(y\right),H\left(x\,y\right)$, that is, it can be reduced in order for any value or form of these functions

ode[5] := diff(diff(y(x),x),x) = 1/H(x,y(x))/D[2](H)(x,y(x))*D[1](H)(x,y(x))^2-1/x/D[2](H)(x,y(x))*D[1](H)(x,y(x))-D[1,1](H)(x,y(x))/D[2](H)(x,y(x)) + (-2*D[1,2](H)(x,y(x))/D[2](H)(x,y(x))-1/x + 2*D[1](H)(x,y(x))/H(x,y(x)) + 1/H(x,y(x))/D[2](H)(x,y(x))*D[1](H)(x,y(x))^2*x*D(G)(y(x)))*diff(y(x),x) + (1/H(x,y(x))*D[2](H)(x,y(x))-D[2,2](H)(x,y(x))/D[2](H)(x,y(x)) + 2*x*D[1](H)(x,y(x))/H(x,y(x))*D(G)(y(x)))*diff(y(x),x)^2 + 1/H(x,y(x))*x*D[2](H)(x,y(x))*D(G)(y(x))*diff(y(x),x)^3;

${\mathrm{ode}}_5≔\mathrm{y\text{'}\text{'}}=\frac{{{\mathrm{D}}_1\left(H\right)\left(x\,y\right)}^2}{H\left(x\,y\right){\mathrm{D}}_2\left(H\right)\left(x\,y\right)}-\frac{{\mathrm{D}}_1\left(H\right)\left(x\,y\right)}{x{\mathrm{D}}_2\left(H\right)\left(x\,y\right)}-\frac{{\mathrm{D}}_{1,1}\left(H\right)\left(x\,y\right)}{{\mathrm{D}}_2\left(H\right)\left(x\,y\right)}+\left(-\frac{2{\mathrm{D}}_{1,2}\left(H\right)\left(x\,y\right)}{{\mathrm{D}}_2\left(H\right)\left(x\,y\right)}-\frac{1}{x}+\frac{2{\mathrm{D}}_1\left(H\right)\left(x\,y\right)}{H\left(x\,y\right)}+\frac{{{\mathrm{D}}_1\left(H\right)\left(x\,y\right)}^{2}x\mathrm{D}\left(G\right)\left(y\right)}{H\left(x\,y\right){\mathrm{D}}_2\left(H\right)\left(x\,y\right)}\right)\mathrm{y\text{'}}+\left(\frac{{\mathrm{D}}_2\left(H\right)\left(x\,y\right)}{H\left(x\,y\right)}-\frac{{\mathrm{D}}_{2,2}\left(H\right)\left(x\,y\right)}{{\mathrm{D}}_2\left(H\right)\left(x\,y\right)}+\frac{2x{\mathrm{D}}_1\left(H\right)\left(x\,y\right)\mathrm{D}\left(G\right)\left(y\right)}{H\left(x\,y\right)}\right){\mathrm{y\text{'}}}^2+\frac{x{\mathrm{D}}_2\left(H\right)\left(x\,y\right)\mathrm{D}\left(G\right)\left(y\right){\mathrm{y\text{'}}}^3}{H\left(x\,y\right)}$

dsolve(ode[5]);

$y=\mathrm{\_b}\left(\mathrm{\_a}\right)\mathbf{where}\left[\left\{{\mathrm{\_b}}_{\mathrm{\_a}}=-\frac{G\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right){\mathrm{D}}_1\left(H\right)\left(\mathrm{\_a}\,\mathrm{\_b}\left(\mathrm{\_a}\right)\right)\mathrm{\_a}+{\mathrm{D}}_1\left(H\right)\left(\mathrm{\_a}\,\mathrm{\_b}\left(\mathrm{\_a}\right)\right)\mathrm{\_a}\mathrm{c\_\_1}+H\left(\mathrm{\_a}\,\mathrm{\_b}\left(\mathrm{\_a}\right)\right)}{{\mathrm{D}}_2\left(H\right)\left(\mathrm{\_a}\,\mathrm{\_b}\left(\mathrm{\_a}\right)\right)\mathrm{\_a}\left(G\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)+\mathrm{c\_\_1}\right)}\right\}\,\left\{\mathrm{\_a}=x\,\mathrm{\_b}\left(\mathrm{\_a}\right)=y\right\}\,\left\{x=\mathrm{\_a}\,y=\mathrm{\_b}\left(\mathrm{\_a}\right)\right\}\right]$

As usual, for different sets of particular values of $G\left(y\right)$ and $H\left(x\,y\right)$ the 1st order ODE shown in the result above is solvable. For example, consider the following 2nd order ODE that results from specializing $G$ and $H$

ode[5.1] := eval(ode[5], {G = (y -> 1/y), H = ((x,y) -> (1+x*y))});

${\mathrm{ode}}_{5.1}≔\mathrm{y\text{'}\text{'}}=\frac{y^2}{\left(1+yx\right)x}-\frac{y}{x^2}+\left(-\frac{3}{x}+\frac{2y}{1+yx}-\frac{1}{1+yx}\right)\mathrm{y\text{'}}+\left(\frac{x}{1+yx}-\frac{2x}{y\left(1+yx\right)}\right){\mathrm{y\text{'}}}^2-\frac{x^2{\mathrm{y\text{'}}}^3}{\left(1+yx\right)y^2}$

The corresponding reduced ODE is of Abel type with nonconstant invariants and solvable

sol[5.1] := dsolve(ode[5.1]);

${\mathrm{sol}}_{5.1}≔\mathrm{c\_\_2}-\frac{\left(-x+2\mathrm{c\_\_1}\right){\left({\ⅇ}^{\mathrm{c\_\_1}\mathrm{arctanh}\left(-\frac{yx+2}{xy}\right)}\right)}^2}{2x\mathrm{c\_\_1}}-\left({\int }_{\phantom{\mathrm{`\; `}}}^{-\frac{yx+2}{2x\mathrm{c\_\_1}y}}\frac{\mathrm{\_f}{\ⅇ}^{2\mathrm{c\_\_1}\mathrm{arctanh}\left(2\mathrm{c\_\_1}\mathrm{\_f}\right)}}{{\mathrm{\_f}}^2-\frac{1}{4{\mathrm{c\_\_1}}^2}}\ⅆ\mathrm{\_f}\right)=0$

Verify this result

odetest(sol[5.1], ode[5.1]);

$0$

Another kind of 2nd order nonlinear problem, reducible to first order with the new algorithms is the following ODE family depending on two arbitrary functions $F\left(y\right),G\left(y\right)$

ode[6] := diff(y(x), x,x) = 1/2*((-2*ln(x)-3)*D(G)(y(x))-2*F(y(x)))/x/(F(y(x)) + D(G)(y(x))*ln(x))*diff(y(x),x) + (-D(F)(y(x))-`@@`(D,2)(G)(y(x))*ln(x))/(F(y(x)) + D(G)(y(x))*ln(x))*diff(y(x),x)^2 + 1/2*x*(F(y(x)) + D(G)(y(x))*ln(x))*D(G)(y(x))*diff(y(x),x)^3;

${\mathrm{ode}}_6≔\mathrm{y\text{'}\text{'}}=\frac{\left(\left(-2\ln \left(x\right)-3\right)\mathrm{D}\left(G\right)\left(y\right)-2F\left(y\right)\right)\mathrm{y\text{'}}}{2x\left(F\left(y\right)+\mathrm{D}\left(G\right)\left(y\right)\ln \left(x\right)\right)}+\frac{\left(-\mathrm{D}\left(F\right)\left(y\right)-{\mathrm{D}}^{\left(2\right)}\left(G\right)\left(y\right)\ln \left(x\right)\right){\mathrm{y\text{'}}}^2}{F\left(y\right)+\mathrm{D}\left(G\right)\left(y\right)\ln \left(x\right)}+\frac{x\left(F\left(y\right)+\mathrm{D}\left(G\right)\left(y\right)\ln \left(x\right)\right)\mathrm{D}\left(G\right)\left(y\right){\mathrm{y\text{'}}}^3}{2}$

Consider for instance the simpler case where $G=\left(y\mapsto y\right),F=\left(y\mapsto \frac{1}{y}\right)$, so that our equation becomes

ode[6.1] := eval(ode[6], {G = (y -> y),F = (y -> 1/y)});

${\mathrm{ode}}_{6.1}≔\mathrm{y\text{'}\text{'}}=\frac{\left(-2\ln \left(x\right)-3-\frac{2}{y}\right)\mathrm{y\text{'}}}{2x\left(\frac{1}{y}+\ln \left(x\right)\right)}+\frac{{\mathrm{y\text{'}}}^2}{y^2\left(\frac{1}{y}+\ln \left(x\right)\right)}+\frac{x\left(\frac{1}{y}+\ln \left(x\right)\right){\mathrm{y\text{'}}}^3}{2}$

sol[6.1] := dsolve(ode[6.1]);

${\mathrm{sol}}_{6.1}≔\mathrm{c\_\_2}+{\mathrm{Ei}}_1\left(-y\right)-4{\mathrm{c\_\_1}}^2{\mathrm{Ei}}_1\left(y\right)-\frac{\ln \left(x\right){\left({\ⅇ}^y+2\mathrm{c\_\_1}\right)}^2}{{\ⅇ}^y}=0$

In the same line, consider this other nonlinear ODE family, not admitting point symmetries and depending on four arbitrary functions $F\left(y\right),G\left(y\right),H\left(x\right),J\left(x\right)$ for which the new routines in Maple 15 can systematically obtain a reduction of order

ode[7] := diff(y(x), x,x) = diff(y(x),x)*J(x)*(1 + H(x)*diff(y(x),x))^2/H(x)*D(F)(y(x)) + (-diff(J(x),x)-diff(y(x),x)*diff(J(x),x)*H(x)-diff(y(x),x)*J(x)*diff(H(x),x))/J(x)/H(x) + diff(y(x),x)*(1 + H(x)*diff(y(x),x))/H(x)*`@@`(D,2)(G)(y(x))/D(G)(y(x))-diff(y(x),x)*(1 + H(x)*diff(y(x),x))/H(x)*`@@`(D,2)(F)(y(x))/D(F)(y(x));

${\mathrm{ode}}_7≔\mathrm{y\text{'}\text{'}}=\frac{\mathrm{y\text{'}}J\left(x\right){\left(1+H\left(x\right)\mathrm{y\text{'}}\right)}^2\mathrm{D}\left(F\right)\left(y\right)}{H\left(x\right)}+\frac{-\mathrm{J\text{'}}-\mathrm{y\text{'}}\mathrm{J\text{'}}H\left(x\right)-\mathrm{y\text{'}}J\left(x\right)\mathrm{H\text{'}}}{J\left(x\right)H\left(x\right)}+\frac{\mathrm{y\text{'}}\left(1+H\left(x\right)\mathrm{y\text{'}}\right){\mathrm{D}}^{\left(2\right)}\left(G\right)\left(y\right)}{H\left(x\right)\mathrm{D}\left(G\right)\left(y\right)}-\frac{\mathrm{y\text{'}}\left(1+H\left(x\right)\mathrm{y\text{'}}\right){\mathrm{D}}^{\left(2\right)}\left(F\right)\left(y\right)}{H\left(x\right)\mathrm{D}\left(F\right)\left(y\right)}$

Without specializing the values of the four functions parametrizing the ODE family, only a reduction of order to the most general form of a 1st order equation is possible

sol[7] := dsolve(ode[7], y(x));

${\mathrm{sol}}_7≔y=\mathrm{\_b}\left(\mathrm{\_a}\right)\mathbf{where}\left[\left\{{\mathrm{\_b}}_{\mathrm{\_a}}=-\frac{\mathrm{D}\left(F\right)\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)J\left(\mathrm{\_a}\right)G\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)+\mathrm{D}\left(F\right)\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)J\left(\mathrm{\_a}\right)\mathrm{c\_\_1}+\mathrm{D}\left(G\right)\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)}{H\left(\mathrm{\_a}\right)\mathrm{D}\left(F\right)\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)J\left(\mathrm{\_a}\right)\left(G\left(\mathrm{\_b}\left(\mathrm{\_a}\right)\right)+\mathrm{c\_\_1}\right)}\right\}\,\left\{\mathrm{\_a}=x\,\mathrm{\_b}\left(\mathrm{\_a}\right)=y\right\}\,\left\{x=\mathrm{\_a}\,y=\mathrm{\_b}\left(\mathrm{\_a}\right)\right\}\right]$

Verify this result

odetest(sol[7], ode[7]);

$0$

As in the other cases, in the typical situation where these functions $F\left(y\right),G\left(y\right),H\left(x\right),J\left(x\right)$ appear specialized in some way, the 1st order equation obtained systematically by reducing the order will not be the most general one and so frequently automatically solved when the 2nd order equation is passed to dsolve.

Three new commands were added to PDEtools.

FunctionFieldSolutions is a new command that involves an innovative approach to computing exact solutions to DE systems involving mathematical functions, possibly inequations, ODEs and also non-differential equations. In these cases, due to the presence of nonpolynomial objects, the original Maple approach by decoupling the system using differential polynomial extensions, although powerful, sometimes fails in solving the problem. The new approach in FunctionFieldSolutions skips entirely that step and instead searches for solutions that can be written as a power series (with some upper bound degree $n$) in the mathematical functions and its derivatives (up to some upper bound differential order $m$), having for coefficients multivariable polynomials (with some upper bound degree $r$). In turn these polynomials have undetermined coefficients that get adjusted, resulting in the solution. To compute the key values of $n,m,r$ to construct these function field solutions, the new command maps the problem into one that can be tackled with the existing PDEtools:-Library:-UpperBounds (see PDEtools[Library]).

SymmetryCommutator is a new command to compute the commutator between two symmetries, given either as lists of infinitesimals or as infinitesimal generator procedures. This command is useful when studying the properties of a group of symmetries or when deriving the group constants or relations to make the group complete.

SymmetryGauge is a new command to gauge PDE symmetries. It is well known that an ODE symmetry can be rewritten in different ways (see Xgauge). It is not so well known, but the same happens with PDE symmetries. The ability to rewrite a symmetry is relevant for a number of purposes. First, that permits identifying that two apparently different symmetries are actually the same by rewriting them in evolutionary form (gauge $\mathrm{\xi }=0$). Second, symmetries that appear as dynamical ones can frequently be rewritten as pointlike, transforming the usability of the symmetry from perhaps very difficult into straightforward. Finally, depending on the form of the symmetry, by rewriting them it is frequently possible to simplify its form considerably so that invariants or canonical coordinates become computable and so the symmetry can be used to reduce the number of independent variables of PDE systems.

Examples 

with(PDEtools):

For FunctionFieldSolutions, consider the following nonlinear coupled system in $F\left(x\,y\right),G\left(x\,y\right)$ that involves the exponential function $\exp$

declare((F, G)(x, y));

$F\left(x\,y\right)\mathrm{will\; now\; be\; displayed\; as}F$

$G\left(x\,y\right)\mathrm{will\; now\; be\; displayed\; as}G$

sys[1] := {-F(x,y)*diff(F(x,y),y)+diff(F(x,y),x) = -F(x,y)*(exp(x)-1/y)+exp(x)*y+1/x, -F(x,y)*diff(G(x,y),y)+diff(G(x,y),x) = -F(x,y)*(exp(x)+1/y)+exp(x)*y+1/x};

${\mathrm{sys}}_1≔\left\{-F{F}_y+F_x=-F\left({\ⅇ}^x-\frac{1}{y}\right)+{\ⅇ}^{x}y+\frac{1}{x}\,-F{G}_y+G_x=-F\left({\ⅇ}^x+\frac{1}{y}\right)+{\ⅇ}^{x}y+\frac{1}{x}\right\}$

Typically, systems of this type do not admit polynomial solutions

PolynomialSolutions(sys[1]);   # returns NULL

On the other hand, these systems frequently admit function field solutions:

sol[1] := FunctionFieldSolutions(sys[1]);

${\mathrm{sol}}_1≔\left\{F={\ⅇ}^{x}y+\ln \left(x\right)-\ln \left(y\right)+\mathrm{c\_\_1}\,G={\ⅇ}^{x}y+\ln \left(x\right)+\ln \left(y\right)+\mathrm{c\_\_2}\right\}$

Verify this solution

pdetest(sol[1], sys[1]);

$\left\{0\right\}$

The following nonlinear system is also not solvable by pdsolve

sys[2] := {-F(x,y)*diff(F(x,y),y)+diff(F(x,y),x) = -F(x,y)*(exp(x)-1/y*exp(x/y))+exp(x)*y+exp(x/y)/x, -F(x,y)*diff(G(x,y),y)+diff(G(x,y),x) = -F(x,y)*(exp(x)+cos(x*y)/y)+exp(x)*y+cos(x*y)/x};

${\mathrm{sys}}_2≔\left\{-F{F}_y+F_x=-F\left({\ⅇ}^x-\frac{{\ⅇ}^{\frac{x}{y}}}{y}\right)+{\ⅇ}^{x}y+\frac{{\ⅇ}^{\frac{x}{y}}}{x}\,-F{G}_y+G_x=-F\left({\ⅇ}^x+\frac{\cos \left(yx\right)}{y}\right)+{\ⅇ}^{x}y+\frac{\cos \left(yx\right)}{x}\right\}$

Its solution via FunctionFieldSolutions takes time to be computed; in cases like this, the use of optional arguments to restrict the degrees in which the solution would depend on mathematical functions, can diminish the computational time

sol[2] := FunctionFieldSolutions(sys[2], mathfunctiondegree = 1);

${\mathrm{sol}}_2≔\left\{F=\mathrm{Ei}\left(\frac{x}{y}\right)-\mathrm{c\_\_4}\mathrm{Si}\left(yx\right)+\mathrm{c\_\_4}\mathrm{Ssi}\left(yx\right)+{\ⅇ}^{x}y+\mathrm{c\_\_2}\,G=\mathrm{Ci}\left(yx\right)+\mathrm{c\_\_3}\mathrm{Si}\left(yx\right)-\mathrm{c\_\_3}\mathrm{Ssi}\left(yx\right)+{\ⅇ}^{x}y+\mathrm{c\_\_1}\right\}$

pdetest(sol[2], sys[2]);

$\left\{0\right\}$

Examples

For SymmetryCommutator, consider two list of infinitesimals corresponding to a symmetry transformation where there are two independent ($x,t$) and one dependent variable, $u\left(x\,t\right)$

S[1], S[2] := [_xi[x] = x, _xi[t] = 1, _eta[u] = t], [_xi[x] = 1, _xi[t] = 1/t, _eta[u] = x^2];

$S_1,S_2≔\left[{\mathrm{\_\ξ}}_x=x\,{\mathrm{\_\ξ}}_t=1\,{\mathrm{\_\η}}_u=t\right],\left[{\mathrm{\_\ξ}}_x=1\,{\mathrm{\_\ξ}}_t=\frac{1}{t}\,{\mathrm{\_\η}}_u=x^2\right]$

For illustration purposes compute also the corresponding infinitesimal generators as differential operators

G[1] := InfinitesimalGenerator(S[1], u(x,t), expanded);

$G_1≔f\→x\left(\frac{\partial }{\partial x}f\right)\+\frac{\partial }{\partial t}f\+t\left(\frac{\partial }{\partial u}f\right)$

G[2] := InfinitesimalGenerator(S[2], u(x,t), expanded);

$G_2≔f\→\frac{\partial }{\partial x}f\+\frac{\frac{\partial }{\partial t}f}{t}\+x^2\left(\frac{\partial }{\partial u}f\right)$

The symmetry commutator is $\left[S_1\,S_2\right]=S_1@S_2-S_2@S_1$; when the first symmetry ($S_1$) is a differential operator procedure, the output is also a differential operator

SymmetryCommutator(G[1], G[2], u(x,t));

$f\→-\left(\frac{\partial }{\partial x}f\right)-\frac{\frac{\partial }{\partial t}f}{t^2}\+\frac{\left(2t{x}^2-1\right)\left(\frac{\partial }{\partial u}f\right)}{t}$

The output can be requested as a list or a procedure and the input can also be of mixed types, here we pass $G_1$ and $S_2$

SymmetryCommutator(G[1], S[2], u(x,t), output = list);

$\left[{\mathrm{\_\ξ}}_x=\mathrm{-1}\,{\mathrm{\_\ξ}}_t=-\frac{1}{t^2}\,{\mathrm{\_\η}}_u=\frac{2t{x}^2-1}{t}\right]$

The prolongation order of the commutator is by default the one of the given infinitesimals, and the same happens with the output's jetnotation, but both can be requested to be different using the optional arguments prolongation = n, and notation = <any jet notation>

SymmetryCommutator(G[1], G[2], u(x,t), prolongation = 2);

$f\&rarr;-\left(\frac{\partial }{\partial x}f\right)-\frac{\frac{\partial }{\partial t}f}{t^2}\&plus;\frac{\left(2t{x}^2-1\right)\left(\frac{\partial }{\partial u}f\right)}{t}\&plus;4x\left(\frac{\partial }{\partial u_x}f\right)\&plus;\frac{\left(t-2u_t\right)\left(\frac{\partial }{\partial u_t}f\right)}{t^3}\&plus;4\left(\frac{\partial }{\partial u_{x\&comma;x}}f\right)-\frac{2u_{x\&comma;t}\left(\frac{\partial }{\partial u_{x\&comma;t}}f\right)}{t^3}-\frac{2\left(2t{u}_{t\&comma;t}\&plus;t-3u_t\right)\left(\frac{\partial }{\partial u_{t\&comma;t}}f\right)}{t^4}$

SymmetryCommutator(G[1], G[2], u(x,t), prolongation = 2, notation = jetnumbers);

$f\&rarr;-\left(\frac{\partial }{\partial x}f\right)-\frac{\frac{\partial }{\partial t}f}{t^2}\&plus;\frac{\left(2t{x}^2-1\right)\left(\frac{\partial }{\partial u_{\&lsqb;\&rsqb;}}f\right)}{t}\&plus;4x\left(\frac{\partial }{\partial u_1}f\right)\&plus;\frac{\left(t-2u_2\right)\left(\frac{\partial }{\partial u_2}f\right)}{t^3}\&plus;4\left(\frac{\partial }{\partial u_{1\&comma;1}}f\right)-\frac{2u_{1\&comma;2}\left(\frac{\partial }{\partial u_{1\&comma;2}}f\right)}{t^3}-\frac{2\left(2t{u}_{2\&comma;2}\&plus;t-3u_2\right)\left(\frac{\partial }{\partial u_{2\&comma;2}}f\right)}{t^4}$

Examples

For SymmetryGauge, consider the list of infinitesimals corresponding to a symmetry transformation where there are two independent and one dependent variables, $u\left(x\&comma;t\right)$

S := [_xi[x] = 1, _xi[t] = t, _eta[u] = u];

$S≔\left[{\mathrm{\_\&xi;}}_x=1\&comma;{\mathrm{\_\&xi;}}_t=t\&comma;{\mathrm{\_\&eta;}}_u=u\right]$

For illustration purposes let's construct also the general form of a 2nd order PDE admitting this symmetry; for that we use the InvariantEquation command

PDE := InvariantEquation(S, u(x,t), order = 2, name = Lambda);

$\mathrm{*\; Partial\; match\; of\; \text{'}name\text{'}\; against\; keyword\; \text{'}arbitraryfunctionname\text{'}}$

$\mathrm{PDE}≔\mathrm{\Lambda }\left(u_t\&comma;t{\&ExponentialE;}^{-x}\&comma;u\left(x\&comma;t\right){\&ExponentialE;}^{-x}\&comma;u_{t,x}\&comma;u_x{\&ExponentialE;}^{-x}\&comma;u_{t,t}{\&ExponentialE;}^x\&comma;u_{x,x}{\&ExponentialE;}^{-x}\right)$

This general form can be particularized in different ways, for instance

pde := isolate(op(-1, PDE) = subsop(-1 = NULL, PDE), diff(u(x,t), x,x));

$\mathrm{pde}≔u_{x,x}=\frac{\mathrm{\Lambda }\left(u_t\&comma;t{\&ExponentialE;}^{-x}\&comma;u\left(x\&comma;t\right){\&ExponentialE;}^{-x}\&comma;u_{t,x}\&comma;u_x{\&ExponentialE;}^{-x}\&comma;u_{t,t}{\&ExponentialE;}^x\right)}{{\&ExponentialE;}^{-x}}$

Now: the general form of the symmetry S admitted by $\mathrm{pde}$ is not $S$ but

S1 := SymmetryGauge(S, u(x,t));

$\mathrm{S1}≔\left[{\mathrm{\_\&xi;}}_x=\mathrm{f\_\_1}\left(x\&comma;t\&comma;u\right)+1\&comma;{\mathrm{\_\&xi;}}_t=\mathrm{f\_\_2}\left(x\&comma;t\&comma;u\right)+t\&comma;{\mathrm{\_\&eta;}}_u=\mathrm{f\_\_1}\left(x\&comma;t\&comma;u\right)u_x+\mathrm{f\_\_2}\left(x\&comma;t\&comma;u\right)u_t+u\right]$

Verify that S1 is a symmetry of $\mathrm{pde}$

SymmetryTest(S1, pde);

$\left\{0\right\}$

Note the presence of arbitrary functions in $\mathrm{S1}$; there are as many as the number of independent variables. The input of SymmetryGauge can also be the infinitesimal generator procedure corresponding to $S$, in which case the output of SymmetryGauge will also be a procedure; the option expanded of SymmetryGauge is the same one of InfinitesimalGenerator

G := InfinitesimalGenerator(S, u(x,t), jetnotation = jetvariables);

$G≔f\&rarr;\frac{\partial }{\partial x}f\&plus;t\left(\frac{\partial }{\partial t}f\right)\&plus;u\left(\frac{\partial }{\partial u}f\right)$

SymmetryGauge(G, u(x,t), expanded);

$f\&rarr;\left(\mathrm{\_F1}\left(x\&comma;t\&comma;u\right)\&plus;1\right)\left(\frac{\partial }{\partial x}f\right)\&plus;\left(\mathrm{\_F2}\left(x\&comma;t\&comma;u\right)\&plus;t\right)\left(\frac{\partial }{\partial t}f\right)\&plus;\left(\mathrm{\_F1}\left(x\&comma;t\&comma;u\right)u_x\&plus;\mathrm{\_F2}\left(x\&comma;t\&comma;u\right)u_t\&plus;u\right)\left(\frac{\partial }{\partial u}f\right)$

The prolongation order of the symmetry returned is by default the one of the given symmetry, but can also be requested to be different using the optional argument prolongation = n, where n is a positive integer. To rewrite the symmetry in evolutionary form use the _xi = 0 optional argument

S0_xi := SymmetryGauge(S, u(x,t), xi = 0);

$\mathrm{S0\_xi}≔\left[{\mathrm{\_\&xi;}}_x=0\&comma;{\mathrm{\_\&xi;}}_t=0\&comma;{\mathrm{\_\&eta;}}_u=-t{u}_t+u-u_x\right]$

Verify that S0_xi is a symmetry of pde

SymmetryTest(S0_xi, pde);

$\left\{0\right\}$

Compare with the gauge where _eta = 0

S0_eta := SymmetryGauge(S, u(x,t), eta = 0);

$\mathrm{S0\_eta}≔\left[{\mathrm{\_\&xi;}}_x=-\frac{\mathrm{f\_\_2}\left(x\&comma;t\&comma;u\right)u_t+u-u_x}{u_x}\&comma;{\mathrm{\_\&xi;}}_t=\mathrm{f\_\_2}\left(x\&comma;t\&comma;u\right)+t\&comma;{\mathrm{\_\&eta;}}_u=0\right]$

SymmetryTest(S0_eta, pde);

$\left\{0\right\}$

You can also indicate the value of each of the infinitesimals appearing in the output, see SymmetryGauge

The following commands were significantly enhanced in their functionality: ConservedCurrents, D_Dx, DeterminingPDE, Eta_k, InfinitesimalGenerator, Infinitesimals, IntegratingFactors, InvariantEquation and Solve.

Apart from that, in Maple 15, the entire set of symmetry commands of PDEtools:

automatically use textbook mathematical jet notation on input and output;

handle list of infinitesimals or the corresponding symmetry generator operators in equal footing;

understand different jet notations as representing the same mathematical objects;

return list of infinitesimals with infinitesimal labels in mathematical notation, unless your input contains infinitesimals without labels;

return results in the jet notation of the input you pass to them;

optionally return in any jet notation you request.

Examples 

Consider a problem with one dependent variable $u\left(x\&comma;t\right)$ and the infinitesimal generator of a symmetry transformation

G := f -> x*diff(f, x) + diff(f, t) + u*diff(f, u);

$G≔f\&rarr;x\left(\frac{\partial }{\partial x}f\right)\&plus;\frac{\partial }{\partial t}f\&plus;u\left(\frac{\partial }{\partial u}f\right)$

To compute, for instance, the transformation that maps this operator into its canonical form, that is the canonical coordinates associated to this symmetry, you no longer need to construct the list of infinitesimals corresponding to $G$; you can now pass $G$ itself

CanonicalCoordinates(G, u(x,t), v(r,s));

$\left\{r=-\ln \left(x\right)+t\&comma;s=\frac{u\left(x\&comma;t\right)}{x}\&comma;v\left(r\&comma;s\right)=\ln \left(x\right)\right\}$

Solving now for the new variables $v\left(r\&comma;s\right)$, to achieve the canonical form of $G$ you change variables in the symmetry, and now you can pass to ChangeSymmetry the operator $G$ itself; also new: the output is automatically an operator because the input is so, or you can optionally request this output to be a list of infinitesimals

solve((50), {x,t, u(x,t)});

$\left\{t=r+v\left(r\&comma;s\right)\&comma;x={\&ExponentialE;}^{v\left(r\&comma;s\right)}\&comma;u\left(x\&comma;t\right)=s{\&ExponentialE;}^{v\left(r\&comma;s\right)}\right\}$

ChangeSymmetry((51), G);

$f\&rarr;\frac{\partial }{\partial v}f$

ChangeSymmetry((51), G, out = list);

$\mathrm{*\; Partial\; match\; of\; \text{'}out\text{'}\; against\; keyword\; \text{'}output\text{'}}$

$\left[{\mathrm{\_\&xi;}}_r=0\&comma;{\mathrm{\_\&xi;}}_s=0\&comma;{\mathrm{\_\&eta;}}_v=1\right]$

Note the (new) presence of infinitesimal labels in this output. The motivation behind all these changes is to have a computational experience with symmetry analysis using true mathematical notation, as close as possible as the one you use when computing with paper and pencil.

Apart from the ability to compute conserved currents and integrating factors of general types, ConservedCurrents and IntegratingFactors can now specifically compute conserved currents and integrating factors of polynomial or functionfield types.

Example 

declare(u(x, t));

$u\left(x\&comma;t\right)\mathrm{will\; now\; be\; displayed\; as}u$

pde := diff(u(x, t), t, x)+diff(u(x, t), x, x, x)+(diff(u(x, t), x))*u(x, t) = 0;

$\mathrm{pde}≔u_{t,x}+u_{x,x,x}+u_{x}u=0$

A conserved current of order 1 (so involving up to 1st order derivatives), depending on arbitrary functions

ConservedCurrents(pde, order = 1);

$\left[{\mathrm{\_J}}_x\left(x\&comma;t\&comma;u\&comma;u_x\&comma;u_t\right)={\mathrm{D}}_3\left(\mathrm{f\_\_1}\right)\left(x\&comma;t\&comma;u\right)u_t+{\mathrm{D}}_2\left(\mathrm{f\_\_1}\right)\left(x\&comma;t\&comma;u\right)+{\mathrm{f\_\_3}}_t\&comma;{\mathrm{\_J}}_t\left(x\&comma;t\&comma;u\&comma;u_x\&comma;u_t\right)=-{\mathrm{D}}_3\left(\mathrm{f\_\_1}\right)\left(x\&comma;t\&comma;u\right)u_x-{\mathrm{D}}_1\left(\mathrm{f\_\_1}\right)\left(x\&comma;t\&comma;u\right)-{\mathrm{f\_\_3}}_x+\mathrm{f\_\_4}\left(x\right)\right]$