Group Theory - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : System : Information : Updates : Maple 2019 : Group Theory

Group Theory Updates in 2019

Description

Computing Dessins D'enfants and Belyi maps

New GroupTheory Package Commands

New and Updated Group Databases

Performance Improvements

Description

•	The GroupTheory package in 2019 contains more than sixty new or updated commands, new and enhanced databases of groups, and significant performance improvements.

>	with( GroupTheory ):

Computing Dessins D'enfants and Belyi maps

•

The new FindDessins command computes all dessins d'enfants corresponding to a specified branching pattern. A dessin also represents a Belyi map, and the DecomposeDessin command finds all decompositions of the corresponding Belyi map. These are both parametrized by certain triples of permutations, called 3-constellations, with cycle structure equal to the specified branching pattern.

•	Consider an example of degree $24$ with branching pattern [3$8], [2$12], [6$4].

>	infolevel[ 'FindDessins' ] := 2:

>	S := FindDessins( [ 3 $ 8 ], [ 2 $ 12 ], [ 6 $ 4 ] );

FindDessins:   Genus 1
FindDessins:       1 pairs before discarding conjugates
FindDessins:      1 dessins of degree 1/24 after .2e-2 seconds
FindDessins:       1 pairs before discarding conjugates
FindDessins:      1 dessins of degree 2/24 after .2e-2 seconds
FindDessins:       2 pairs before discarding conjugates
FindDessins:      1 dessins of degree 3/24 after .2e-2 seconds
FindDessins:     1 pairs before discarding conjugates
FindDessins:      1 dessins of degree 5/24 after .2e-2 seconds
FindDessins:       1 pairs before discarding conjugates
FindDessins:      1 dessins of degree 6/24 after .3e-2 seconds
FindDessins:   2 pairs before discarding conjugates
FindDessins:     3 pairs before discarding conjugates
FindDessins:     12 pairs before discarding conjugates
FindDessins:      3 pairs before discarding conjugates
FindDessins:      3 dessins of degree 12/24 after .10e-1 seconds
FindDessins:     4 pairs before discarding conjugates
FindDessins:     31 pairs before discarding conjugates
FindDessins:      2 pairs before discarding conjugates
FindDessins:      4 dessins of degree 18/24 after .32e-1 seconds
FindDessins:     4 pairs before discarding conjugates
FindDessins:      3 pairs before discarding conjugates
FindDessins:      3 dessins of degree 24/24 after .148 seconds

$S ≔ \{[(1, 2, 3) (4, 5, 6) (7, 8, 9) (10, 11, 12) (13, 14, 15) (16, 17, 18) (19, 20, 21) (22, 23, 24), (1, 4) (2, 7) (3, 10) (5, 13) (6, 16) (8, 19) (9, 15) (11, 20) (12, 18) (14, 22) (17, 23) (21, 24)], [(1, 2, 3) (4, 5, 6) (7, 8, 9) (10, 11, 12) (13, 14, 15) (16, 17, 18) (19, 20, 21) (22, 23, 24), (1, 4) (2, 7) (3, 8) (5, 10) (6, 11) (9, 13) (12, 16) (14, 19) (15, 20) (17, 22) (18, 23) (21, 24)], [(1, 2, 3) (4, 5, 6) (7, 8, 9) (10, 11, 12) (13, 14, 15) (16, 17, 18) (19, 20, 21) (22, 23, 24), (1, 4) (2, 7) (3, 10) (5, 13) (6, 16) (8, 19) (9, 15) (11, 17) (12, 21) (14, 22) (18, 24) (20, 23)]\}$

(1)

•	In this case, FindDessins finds $3$ dessins.

>	nops( S );

$3$

(2)

>	d := S[ 2 ];

$d ≔ [(1, 2, 3) (4, 5, 6) (7, 8, 9) (10, 11, 12) (13, 14, 15) (16, 17, 18) (19, 20, 21) (22, 23, 24), (1, 4) (2, 7) (3, 8) (5, 10) (6, 11) (9, 13) (12, 16) (14, 19) (15, 20) (17, 22) (18, 23) (21, 24)]$

(3)

>	map( PermCycleType, d );

$[[3, 3, 3, 3, 3, 3, 3, 3], [2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2, 2]]$

(4)

>	DecomposeDessin( d, 'L', 'gr' );

$F = F1(deg 2) = F2(deg 2) = F3(deg 2) = F4(deg 2) = F5(deg 2) = F6(deg 4) = F7(deg 4) = F8(deg 4) = F9(deg 8) = F10(deg 12)$

(5)

L[1];

$[F1: EllipticCurve-->P1, F1 = F6(deg 2) = F7(deg 2) = F8(deg 2), Degree = 12, BranchPattern = ([3$4], [2$6], [6$2]), Dessin = [(1, 2, 3) (4, 5, 6) (7, 8, 9) (10, 11, 12), (1, 4) (2, 7) (3, 8) (5, 10) (6, 11) (9, 12)]]$

(6)

gr;

•	By iterating over all possible cycle types of a given degree (in the example below, the degree is $N = 6$ ), we can count all dessins d'enfants or, equivalently, Belyi maps up to equivalence.

>	infolevel[ 'FindDessins' ] := 0:

N := 6:

>	P := combinat:-partition( N ):

>	nops( P );

$11$

(7)

>	add( add( add( nops( FindDessins( i, j, k ) ), k = P ), j = P ), i = P );

$624$

(8)

New GroupTheory Package Commands

•

Many new commands have been added to the GroupTheory package in 2019. These include commands for recognizing groups with many interesting properties, new commands for constructing groups of various kinds, new commands to compute subgroups and subgroup series, as well as a suite of commands for recognizing numbers for which every group of a given order has one of a number of group-theoretic properties.

Frobenius Groups

•	Maple is now able to recognize finite Frobenius groups, either as abstract groups, or as permutation groups, and to compute Frobenius kernels and complements. Consult the linked help pages for more details. See also the section on the new database of small Frobenius groups below.

•	The IsFrobeniusGroup command determines whether a finite permutation group G is a Frobenius group, as an abstract group.

>	IsFrobeniusGroup( Symm( 3 ) ); # the smallest Frobenius group

$true$

(9)

>	IsFrobeniusGroup( DihedralGroup( 5 ) );

$true$

(10)

>	IsFrobeniusGroup( QuaternionGroup() );

$false$

(11)

•	The IsFrobeniusPermGroup command returns true if the permutation group G is Frobenius in its natural action.

>	G := Group( [ Perm([[1,2],[3,6],[4,5]]), Perm([[1,3,4],[2,5,6]]) ] );

$G ≔ ⟨(1, 2) (3, 6) (4, 5), (1, 3, 4) (2, 5, 6)⟩$

(12)

>	IsFrobeniusPermGroup( G );

$false$

(13)

>	IsFrobeniusGroup( G );

$true$

(14)

•	If G is a Frobenius group, then the FrobeniusKernel( G ) command returns its Frobenius kernel. Likewise, the FrobeniusComplement( G ) command returns a representative Frobenius complement.

>	FrobeniusKernel( DihedralGroup( 5 ) );

$⟨(1, 3, 5, 2, 4)⟩$

(15)

>	FrobeniusComplement( DihedralGroup( 5 ) );

$⟨(1, 4) (2, 3)⟩$

(16)

•	If a Frobenius group is not represented as a permutation group with Frobenius action, you can use the FrobeniusPermRep( G ) command to obtain a permutation group isomorphic to G for which the action is Frobenius.

>	P := FrobeniusPermRep( SmallGroup( 6, 1 ) );

$P ≔ ⟨(1, 2), (1, 3, 2)⟩$

(17)

>	IsFrobeniusPermGroup( P );

$true$

(18)

Hamiltonian Groups

•	Several new commands that allow you to work with finite Hamiltonian groups have been introduced in 2019.

•	Use the IsHamiltonian command to check whether a permutation group is Hamiltonian (that is, a non-Abelian group with every subgroup normal). The IsDedekind command allows you to determine whether a permutation group is a Dedekind group (either Abelian or Hamiltonian).

>	IsHamiltonian( QuaternionGroup() );

$true$

(19)

>	IsDedekind( DihedralGroup( 4 ) );

$false$

(20)

>	IsDedekind( ElementaryGroup( 3, 3 ) );

$true$

(21)

•

There are new constructors for Hamiltonian groups in this release. The HamiltonianGroup( n, k ) command returns the $k$ -th Hamiltonian group of order $n$ , where $n$ is a multiple of eight. (All Hamiltonian groups have order equal to a multiple of eight.) The NumHamiltonianGroups command returns the number of Hamiltonian groups of a given positive integral order.

>	NumHamiltonianGroups( 100 );

$0$

(22)

>	NumHamiltonianGroups( 200 );

$2$

(23)

>	G := HamiltonianGroup( 200, 2 ):

>	IsHamiltonian( G );

$true$

(24)

•	The AllHamiltonianGroups command returns an expression sequence of all the Hamiltonian groups of a given order.

>	AllHamiltonianGroups( 200 );

$⟨(1, 2, 3, 4) (5, 6, 8, 7), (1, 5, 3, 8) (2, 7, 4, 6), (9, 10, 11, 12, 13), (14, 15, 16, 17, 18)⟩, ⟨(1, 2, 3, 4) (5, 6, 8, 7), (1, 5, 3, 8) (2, 7, 4, 6), (9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33)⟩$

(25)

•	In addition, Hamiltonian groups in the database of small groups have been identified, allowing you to use the search term hamiltonian in the SearchSmallGroups command.

Subgroup Series

•	Every finite group has a composition series, a subnormal series with simple factors, and the CompositionSeries command returns a composition series for a finite permutation group.

G := Group( [Perm([[1, 2, 3]]), Perm([[2, 3, 4]]), Perm([[6, 8], [7, 9], [11, 19], [12, 18], [14, 17], [16, 20]]), Perm([[6, 10, 11], [7, 15, 16], [8, 18, 9], [12, 13, 17], [14, 19, 20]]), Perm([[5, 6], [7, 12], [8, 13], [9, 14], [10, 11], [15, 19], [16, 18], [17, 20]]), Perm([[5, 7], [6, 12], [8, 17], [9, 10], [11, 14], [13, 20], [15, 16], [18, 19]]), Perm([[5, 8], [6, 13], [7, 17], [9, 18], [10, 19], [11, 15], [ 12, 20], [14, 16]]), Perm([[5, 9], [6, 14], [7, 10], [8, 18], [11, 12], [13, 16], [15, 20], [17, 19]]), Perm([[21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84, 85, 86, 87, 88, 89, 90, 91, 92, 93, 94, 95, 96, 97, 98, 99, 100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110]])] );

$G ≔ ⟨(1, 2, 3), (2, 3, 4), (6, 8) (7, 9) (11, 19) (12, 18) (14, 17) (16, 20), (6, 10, 11) (7, 15, 16) (8, 18, 9) (12, 13, 17) (14, 19, 20), (5, 6) (7, 12) (8, 13) (9, 14) (10, 11) (15, 19) (16, 18) (17, 20), (5, 7) (6, 12) (8, 17) (9, 10) (11, 14) (13, 20) (15, 16) (18, 19), (5, 8) (6, 13) (7, 17) (9, 18) (10, 19) (11, 15) (12, 20) (14, 16), (5, 9) (6, 14) (7, 10) (8, 18) (11, 12) (13, 16) (15, 20) (17, 19), (21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84, 85, 86, 87, 88, 89, 90, 91, 92, 93, 94, 95, 96, 97, 98, 99, 100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110)⟩$

(26)

>	cs := CompositionSeries( G );

$cs ≔ ⟨(1, 2, 3), (2, 3, 4), (6, 8) (7, 9) (11, 19) (12, 18) (14, 17) (16, 20), (6, 10, 11) (7, 15, 16) (8, 18, 9) (12, 13, 17) (14, 19, 20), (5, 6) (7, 12) (8, 13) (9, 14) (10, 11) (15, 19) (16, 18) (17, 20), (5, 7) (6, 12) (8, 17) (9, 10) (11, 14) (13, 20) (15, 16) (18, 19), (5, 8) (6, 13) (7, 17) (9, 18) (10, 19) (11, 15) (12, 20) (14, 16), (5, 9) (6, 14) (7, 10) (8, 18) (11, 12) (13, 16) (15, 20) (17, 19), (21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76, 77, 78, 79, 80, 81, 82, 83, 84, 85, 86, 87, 88, 89, 90, 91, 92, 93, 94, 95, 96, 97, 98, 99, 100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110)⟩ ▹ ⟨(6, 15, 8, 20, 16) (7, 13, 9, 14, 17) (10, 18, 19, 11, 12), (5, 13, 18, 19, 17) (7, 16, 10, 11, 15) (8, 9, 12, 14, 20), (8, 13) (9, 10) (11, 14) (15, 18) (16, 19) (17, 20), (1, 4) (2, 3), (1, 3) (2, 4), (2, 4, 3), (21, 66) (22, 67) (23, 68) (24, 69) (25, 70) (26, 71) (27, 72) (28, 73) (29, 74) (30, 75) (31, 76) (32, 77) (33, 78) (34, 79) (35, 80) (36, 81) (37, 82) (38, 83) (39, 84) (40, 85) (41, 86) (42, 87) (43, 88) (44, 89) (45, 90) (46, 91) (47, 92) (48, 93) (49, 94) (50, 95) (51, 96) (52, 97) (53, 98) (54, 99) (55, 100) (56, 101) (57, 102) (58, 103) (59, 104) (60, 105) (61, 106) (62, 107) (63, 108) (64, 109) (65, 110), (21, 51, 81) (22, 52, 82) (23, 53, 83) (24, 54, 84) (25, 55, 85) (26, 56, 86) (27, 57, 87) (28, 58, 88) (29, 59, 89) (30, 60, 90) (31, 61, 91) (32, 62, 92) (33, 63, 93) (34, 64, 94) (35, 65, 95) (36, 66, 96) (37, 67, 97) (38, 68, 98) (39, 69, 99) (40, 70, 100) (41, 71, 101) (42, 72, 102) (43, 73, 103) (44, 74, 104) (45, 75, 105) (46, 76, 106) (47, 77, 107) (48, 78, 108) (49, 79, 109) (50, 80, 110), (21, 31, 41, 51, 61, 71, 81, 91, 101) (22, 32, 42, 52, 62, 72, 82, 92, 102) (23, 33, 43, 53, 63, 73, 83, 93, 103) (24, 34, 44, 54, 64, 74, 84, 94, 104) (25, 35, 45, 55, 65, 75, 85, 95, 105) (26, 36, 46, 56, 66, 76, 86, 96, 106) (27, 37, 47, 57, 67, 77, 87, 97, 107) (28, 38, 48, 58, 68, 78, 88, 98, 108) (29, 39, 49, 59, 69, 79, 89, 99, 109) (30, 40, 50, 60, 70, 80, 90, 100, 110)⟩ ▹ \dots ▹ ⟨(5, 13) (6, 8) (7, 20) (9, 16) (10, 15) (11, 19) (12, 17) (14, 18)⟩ ▹ ⟨⟩$

(27)

•	Composition series are of type SubnormalSeries, but not (in general) of type NormalSeries.

>	type( cs, 'SubnormalSeries' );

$true$

(28)

>	type( cs, 'NormalSeries' );

$false$

(29)

>	[seq]( GroupOrder( H ), H = cs );

$[1036800, 207360, 69120, 23040, 11520, 3840, 1920, 960, 16, 8, 4, 2, 1]$

(30)

•	The CompositionLength command returns the number of composition factors.

>	CompositionLength( DihedralGroup( 10 ) );

$3$

(31)

•	For a prime number $p$ , the lower $p$ -central series of a finite group G can be computed by using the new LowerPCentralSeries( p, G ) command.

>	ser := LowerPCentralSeries( 2, DihedralGroup( 8 ) );

$ser ≔ D_{8} ▹ ⟨(1, 7, 5, 3) (2, 8, 6, 4)⟩ ▹ ⟨(1, 5) (2, 6) (3, 7) (4, 8)⟩ ▹ ⟨⟩$

(32)

>	seq( GroupOrder( H ), H = ser );

$16, 4, 2, 1$

(33)

•	To compute the lower Fitting series of a group use the LowerFittingSeries command. The FittingLength( G ) command returns the Fitting length of the soluble permutation group G.

>	ser := LowerFittingSeries( DihedralGroup( 10 ) );

$ser ≔ D_{10} ▹ [D_{10}, D_{10}] ▹ ⟨⟩$

(34)

>	seq( GroupOrder( H ), H = ser );

$20, 5, 1$

(35)

>	FittingLength( DihedralGroup( 10 ) );

$2$

(36)

>	FittingLength( DihedralGroup( 8 ) );

$1$

(37)

•	Use the new FrattiniSeries( G ) command to compute the Frattini series of a permutation group G.

>	fs := FrattiniSeries( Alt( 4 ) );

$fs ≔ A_{4} ◃ Φ (A_{4})$

(38)

>	type( fs, 'NormalSeries' );

$true$

(39)

•	The FrattiniLength command computes the Frattini length of a permutation group; that is, the length of its Frattini series.

>	FrattiniLength( GL( 2, 3 ) );

$2$

(40)

•	A Sylow tower of a finite group $G$ is a normal series

$1 = G_{0} ◃ G_{1} ◃ \dots ◃ G_{r} = G$

for which the series quotients $\frac{G_{k}}{G_{k + 1}}$ are isomorphic to the Sylow subgroups of $G$ , exactly one for each prime divisor of the order of $G$ . A sequence $γ = p_{1}, p_{2}, .., p_{r}$ of primes is called a complexion of the Sylow tower if it contains all of the primes dividing the order of $G$ and if the tower quotients corresponding to the prime divisors of the order of $G$ appear in the order in which they appear in $γ$ . A group may or may not have a Sylow tower, and may have a Sylow tower of one complexion, but not of another, but a group with a Sylow tower of any complexion is necessarily soluble.

•	The SylowTower( G ) command computes a Sylow tower (of some unspecified complexion) for a soluble permutation group G, if one exists.

>	st := SylowTower( Alt( 4 ) );

$st ≔ ⟨⟩ ◃ ⟨(1, 2) (3, 4), (1, 3) (2, 4)⟩ ◃ A_{4}$

(41)

>	type( st, 'NormalSeries' );

$true$

(42)

•	The complexion for the computed Sylow tower can be retrieved by using the Complexion method.

>	Complexion( st );

$[2, 3]$

(43)

•	The IsSylowTowerGroup( G ) command determines whether the group G has a Sylow tower.

>	IsSylowTowerGroup( Alt( 4 ) );

$true$

(44)

>	IsSylowTowerGroup( Symm( 4 ) );

$false$

(45)

•

A Sylow tower is called ordered if the primes corresponding to successive tower quotients occur in descending order of magnitude. The Sylow tower for the alternating group computed above is not ordered because the prime divisors $2$ and $3$ of the order $12$ of the group do not occur in descending order.

•	The OrderedSylowTower( G ) command computes an ordered Sylow tower for the soluble permutation group G if one exists.

•	In fact, the alternating group $A_{4}$ does not have an ordered Sylow tower.

>	OrderedSylowTower( Alt( 4 ) );

Error, group GroupTheory:-AlternatingGroup(4) has no ordered Sylow tower of complexion [3, 2]

•	However, every supersoluble group does have an ordered Sylow tower.

>	st := OrderedSylowTower( DihedralGroup( 15 ) );

$st ≔ ⟨⟩ ◃ ⟨(1, 4, 7, 10, 13) (2, 5, 8, 11, 14) (3, 6, 9, 12, 15)⟩ ◃ ⟨(1, 4, 7, 10, 13) (2, 5, 8, 11, 14) (3, 6, 9, 12, 15), (1, 11, 6) (2, 12, 7) (3, 13, 8) (4, 14, 9) (5, 15, 10)⟩ ◃ ⟨(1, 4, 7, 10, 13) (2, 5, 8, 11, 14) (3, 6, 9, 12, 15), (1, 11, 6) (2, 12, 7) (3, 13, 8) (4, 14, 9) (5, 15, 10), (2, 15) (3, 14) (4, 13) (5, 12) (6, 11) (7, 10) (8, 9)⟩$

(46)

•	Notice that the prime divisors in this example do occur in descending order.

>	Complexion( st );

$[5, 3, 2]$

(47)

•	Use the IsOrderedSylowTowerGroup( G ) command to determine whether the group G has an ordered Sylow tower.

>	IsOrderedSylowTowerGroup( Alt( 4 ) );

$false$

(48)

>	IsOrderedSylowTowerGroup( DihedralGroup( 15 ) );

$true$

(49)

•	More generally, the OrderedSylowTower command allows you to pre-specify any desired complexion, and computes a Sylow tower with the matching complexion, if possible.

>	st := OrderedSylowTower( DihedralGroup( 15 ), 'complexion' = [ 3, 5, 2 ] );

$st ≔ ⟨⟩ ◃ ⟨(1, 6, 11) (2, 7, 12) (3, 8, 13) (4, 9, 14) (5, 10, 15)⟩ ◃ ⟨(1, 6, 11) (2, 7, 12) (3, 8, 13) (4, 9, 14) (5, 10, 15), (1, 4, 7, 10, 13) (2, 5, 8, 11, 14) (3, 6, 9, 12, 15)⟩ ◃ ⟨(1, 6, 11) (2, 7, 12) (3, 8, 13) (4, 9, 14) (5, 10, 15), (1, 4, 7, 10, 13) (2, 5, 8, 11, 14) (3, 6, 9, 12, 15), (2, 15) (3, 14) (4, 13) (5, 12) (6, 11) (7, 10) (8, 9)⟩$

(50)

>	Complexion( st );

$[3, 5, 2]$

(51)

>	st := OrderedSylowTower( DihedralGroup( 15 ), 'complexion' = [ 3, 2, 5 ] );

Error, group GroupTheory:-DihedralGroup(15,form = "permgroup") has no ordered Sylow tower of complexion [3, 2, 5]

Remak Decompositions

•	The new DirectFactors command produces a Remak decomposition of a finite group. This is an expression sequence of directly indecomposable subgroups of the group such that the group is the direct product of the groups in the sequence.

>	df := DirectFactors( DihedralGroup( 10 ) );

$df ≔ ⟨(1, 6) (2, 7) (3, 8) (4, 9) (5, 10)⟩, ⟨(1, 7) (2, 6) (3, 5) (8, 10), (1, 9) (2, 8) (3, 7) (4, 6)⟩$

(52)

>	AreIsomorphic( DihedralGroup( 10 ), DirectProduct( df ) );

$true$

(53)

•	To determine whether a group is directly indecomposable, use the new IsDirectlyIndecomposable command.

>	IsDirectlyIndecomposable( QuaternionGroup() );

$true$

(54)

>	DirectFactors( QuaternionGroup() );

$Q$

(55)

>	IsDirectlyIndecomposable( SmallGroup( 4, 2 ) );

$false$

(56)

>	DirectFactors( SmallGroup( 4, 2 ) );

$⟨(1, 2) (3, 4)⟩, ⟨(1, 3) (2, 4)⟩$

(57)

New Commands for Finite Soluble Groups

•	A finite group is soluble if, and only if, it has a Sylow basis. The SylowBasis command computes a Sylow basis for a soluble permutation group.

>	G := DihedralGroup( 30 );

$G ≔ D_{30}$

(58)

>	ifactor( GroupOrder( G ) );

${(2)}^{2} (3) (5)$

(59)

>	B := SylowBasis( G );

$B ≔ [⟨(1, 25, 19, 13, 7) (2, 26, 20, 14, 8) (3, 27, 21, 15, 9) (4, 28, 22, 16, 10) (5, 29, 23, 17, 11) (6, 30, 24, 18, 12)⟩, ⟨(1, 11, 21) (2, 12, 22) (3, 13, 23) (4, 14, 24) (5, 15, 25) (6, 16, 26) (7, 17, 27) (8, 18, 28) (9, 19, 29) (10, 20, 30)⟩, ⟨(1, 30) (2, 29) (3, 28) (4, 27) (5, 26) (6, 25) (7, 24) (8, 23) (9, 22) (10, 21) (11, 20) (12, 19) (13, 18) (14, 17) (15, 16), (1, 15) (2, 14) (3, 13) (4, 12) (5, 11) (6, 10) (7, 9) (16, 30) (17, 29) (18, 28) (19, 27) (20, 26) (21, 25) (22, 24)⟩]$

(60)

>	map( GroupOrder, B );

$[5, 3, 4]$

(61)

>	andmap( type, map( GroupOrder, B ), 'primepower' );

$true$

(62)

>	evalb( FrobeniusProduct( B[ 1 ], B[ 2 ], G ) = FrobeniusProduct( B[ 2 ], B[ 1 ], G ) );

$true$

(63)

•	The HallSubgroup command computes a Hall subgroup corresponding to a set of prime divisors of the order of a soluble group.

>	H := HallSubgroup( { 2, 5 }, DihedralGroup( 30 ) );

$H ≔ ⟨(1, 7, 13, 19, 25) (2, 8, 14, 20, 26) (3, 9, 15, 21, 27) (4, 10, 16, 22, 28) (5, 11, 17, 23, 29) (6, 12, 18, 24, 30), (1, 10) (2, 9) (3, 8) (4, 7) (5, 6) (11, 30) (12, 29) (13, 28) (14, 27) (15, 26) (16, 25) (17, 24) (18, 23) (19, 22) (20, 21), (1, 16) (2, 17) (3, 18) (4, 19) (5, 20) (6, 21) (7, 22) (8, 23) (9, 24) (10, 25) (11, 26) (12, 27) (13, 28) (14, 29) (15, 30)⟩$

(64)

>	ifactor( GroupOrder( DihedralGroup( 30 ) ) );

${(2)}^{2} (3) (5)$

(65)

>	ifactor( GroupOrder( H ) );

${(2)}^{2} (5)$

(66)

Group Properties

•	A number of new commands have been introduced that allow you to test whether a finite group has various properties.

•	Some of these, such as the new commands IsHamiltonian, IsFrobeniusGroup and IsDirectlyIndecomposable, were described above.

•	Several more new commands are provided to test whether a finite group belongs to one of a number of other classes of soluble groups.

•	Use the IsMetacyclic command to determine whether a finite group is metacyclic, and the IsMetabelian command to decide whether a finite group is metabelian. For example, the alternating group of degree $4$ is metabelian, but is not metacyclic.

>	IsMetacyclic( Alt( 4 ) );

$false$

(67)

>	IsMetabelian( Alt( 4 ) );

$true$

(68)

•	The new IsCyclicSylowGroup command determines whether a finite group has the property that all of its Sylow subgroups are cyclic. (These are most commonly referred to as Z-groups.)

>	IsCyclicSylowGroup( DihedralGroup( 5 ) );

$true$

(69)

•	Finite groups whose Sylow subgroups are all Abelian (often called A-groups) can be recognized by the new IsAbelianSylowGroup command.

>	IsAbelianSylowGroup( Alt( 4 ) );

$true$

(70)

•	Use the new IsAlmostSimple command to determine whether a group is almost simple.

>	IsAlmostSimple( Symm( 6 ) );

$true$

(71)

•	The new commands IsCNGroup, IsCAGroup and IsCCGroup are used to recognize groups based on properties of their centralizers. These commands detect, respectively, whether the centralizer of each non-trivial element of a finite group is nilpotent, Abelian or cyclic.

•	For example, the symmetric group of degree $4$ is the smallest non-nilpotent (CN)-group that is not a (CA)-group.

>	IsCNGroup( Symm( 4 ) );

$true$

(72)

>	IsCAGroup( Symm( 4 ) );

$false$

(73)

•	The IsHallPaigeGroup command determines whether a finite group has a complete mapping in the sense of Hall and Paige. (The Hall-Paige conjecture was recently settled.)

>	IsHallPaigeGroup( DihedralGroup( 5 ) );

$false$

(74)

>	IsHallPaigeGroup( DihedralGroup( 10 ) );

$true$

(75)

>	IsHallPaigeGroup( TitsGroup() );

$true$

(76)

•	The IsDihedral command determines whether a permutation group is isomorphic to a dihedral group (not necessarily of the same degree).

>	IsDihedral( Group( Perm([[1,4],[2,11]]), Perm([[111,112],[207,333]]) ) );

$true$

(77)

>	IsDihedral( QuaternionGroup() );

$false$

(78)

•	Other group properties implemented for permutation groups in this release include IsSupersoluble, IsLagrangian, IsGCLTGroup and IsStemGroup.

•	The IsSupersoluble( G ) command determines whether the group G is supersoluble; that is, whether all of its chief factors are cyclic of prime order.

>	IsSupersoluble( Alt( 4 ) );

$false$

(79)

>	IsSupersoluble( DihedralGroup( 7 ) );

$true$

(80)

•	Use the IsLagrangian( G ) command to determine whether the group G satisfies the converse of Lagrange's Theorem; that is, whether it has a subgroup of order $d$ for each divisor $d$ of its order.

>	IsLagrangian( Symm( 4 ) );

$true$

(81)

>	IsLagrangian( Alt( 4 ) );

$false$

(82)

•	The IsGCLTGroup( G ) command checks whether the group G is a GCLT-group. (See IsGCLTGroup for a definition.)

>	IsGCLTGroup( Symm( 4 ) );

$false$

(83)

>	IsGCLTGroup( QuaternionGroup() );

$true$

(84)

•	To determine whether a group G is a stem group, use the new IsStemGroup( G ) command.

>	IsStemGroup( DihedralGroup( 4 ) );

$true$

(85)

>	IsStemGroup( CyclicGroup( 10 ) );

$false$

(86)

•	A finite group is said to have perfect order classes if the number of elements of each order is a divisor of the order of the group. The IsPerfectOrderClassesGroup command determines whether a group has perfect order classes.

>	IsPerfectOrderClassesGroup( Symm( 3 ) );

$true$

(87)

>	IsPerfectOrderClassesGroup( Symm( 4 ) );

$false$

(88)

New and Updated Group Constructors

•	The SmallGroup constructor can now construct groups of order $p^{k}$ , for arbitrary primes $p$ , and positive integers $k \leq 4$ .

>	G := SmallGroup( 5^4, 3 ):

>	GroupOrder( G );

$625$

(89)

>	G := SmallGroup( 11^4, 11, 'form' = "fpgroup" );

$G ≔ ⟨_a1,_a2,_a3 ∣ {_a2}^{-1} {_a1}^{-1}_a2_a1, {_a3}^{-1} {_a1}^{-1}_a3_a1, {_a3}^{-1} {_a2}^{-1}_a3_a2, {_a1}^{11}, {_a2}^{11}, {_a3}^{121}⟩$

(90)

>	GroupOrder( G );

$14641$

(91)

•	Generalizing the DerivedSubgroup constructor, the new Commutator( A, B, G ) command computes the normal closure, in the group G, of the commutators $[a, b]$ , with $a$ in $A$ and $b$ in $B$ .

>	H := Commutator( SylowSubgroup( 2, Symm( 5 ) ), SylowSubgroup( 3, Symm( 5 ) ), Symm( 5 ) );

$H ≔ [⟨(1, 2), (3, 4), (1, 3) (2, 4)⟩, ⟨(1, 2, 3)⟩]$

(92)

>	GroupOrder( H );

$60$

(93)

>	AreIsomorphic( H, Alt( 5 ) );

$true$

(94)

•	The AllAbelianGroups command returns the complete set of Abelian groups of a given order.

>	AllAbelianGroups( 4 );

$⟨_a1,_a2 ∣ {_a1}^{2}, {_a2}^{2}, {_a2}^{-1} {_a1}^{-1}_a2_a1⟩, ⟨_a1 ∣ {_a1}^{4}⟩$

(95)

Number Theoretic Commands

•	A selection of number-theoretic commands have been added that allow you to determine whether every group of a given order has a specific property. See GroupTheory/Numbers for a complete description. Here are several examples.

•	The IsCyclicNumber( n ) command returns true if, and only if, every group of order n is cyclic. This, of course, includes the primes, but also includes composite numbers. In this case, there is only one group of order $n$ .

>	IsCyclicNumber( 11 );

$true$

(96)

>	IsCyclicNumber( 15 );

$true$

(97)

>	NumGroups( 15 );

$1$

(98)

>	IsCyclicNumber( 6 );

$false$

(99)

>	NumGroups( 6 );

$2$

(100)

•	Positive integers $n$ for which every group of order $n$ is Abelian are recognized by the IsAbelianNumber( n ) command.

>	IsAbelianNumber( 4 );

$true$

(101)

>	andmap( IsAbelian, AllSmallGroups( 4 ) );

$true$

(102)

>	IsAbelianNumber( 6 );

$false$

(103)

>	andmap( IsAbelian, AllSmallGroups( 6 ) );

$false$

(104)

•	To determine whether every group of order $n$ is a nilpotent group, use the new IsNilpotentNumber( n ) command.

>	IsNilpotentNumber( 24 );

$false$

(105)

>	IsNilpotentNumber( 459 );

$true$

(106)

>	NumGroups( 459 );

$5$

(107)

>	andmap( IsNilpotent, AllSmallGroups( 459 ) );

$true$

(108)

•	Similarly, the IsSolubleNumber( n ) command determines whether every group of order n is soluble.

>	andmap( IsSolubleNumber, [seq]( 1 .. 59 ) );

$true$

(109)

>	andmap( IsSolubleNumber, [seq]( 1 .. 60 ) );

$false$

(110)

>	Statistics:-VennDiagram( IsCyclicNumber, IsAbelianNumber, IsNilpotentNumber, IsLagrangianNumber, IsSolubleNumber, universe = {seq}(1..10000), legend = ["Cyclic", "Abelian", "Nilpotent", "Lagrangian", "Soluble" ] );

•	Since every supersoluble group has an ordered Sylow tower, every supersoluble number is an ordered Sylow tower number. Evidence for this is exhibited by this command:

>	andmap( IsSupersolubleNumber implies IsOrderedSylowTowerNumber, [seq]( 1 .. 10000 ) );

$true$

(111)

•	But, the non-Abelian group of order $75$ is not supersoluble, yet it has an ordered Sylow tower. Therefore, $75$ is an ordered Sylow tower number, but not a supersoluble number.

>	IsOrderedSylowTowerNumber( 75 );

$true$

(112)

>	IsSupersolubleNumber( 75 );

$false$

(113)

•	The following additional number-theoretic commands are new in this release: IsIntegrableNumber, IsMetacyclicNumber, IsMetabelianNumber, IsLagrangianNumber, IsGCLTNumber.

•	See GroupTheory/Numbers for more information on these, and the other new commands described above.

Other New Commands

•	A number of other commands in the GroupTheory package have been added, or updated, in 2019.

•	The NumGroups command can compute the number of groups of order $n$ for more positive integers $n$ .

>	NumGroups( 837627012169834259 ); # returned FAIL in Maple 2018

$24$

(114)

•	The ElementPower command computes integral powers of elements of a finite group.

>	G := CayleyTableGroup( Symm( 3 ) );

$G ≔ < a Cayley table group with 6 elements >$

(115)

>	g := RandomElement( G ):

>	ElementPower( g, 208374237432343274923743847385, G );

$2$

(116)

•	The IsTrivial and TrivialSubgroup commands are utilities for testing for a trivial subgroup, and constructing the trivial subgroup of a given group.

•	For permutation groups, the RandomInvolution command returns a randomly chosen element of order $2$ in a group of even order.

>	g := RandomInvolution( Alt( 8 ) );

$g ≔ (1, 7) (3, 5)$

(117)

>	PermOrder( g );

$2$

(118)

•	The RandomPElement command selects an element of $p$ -power order from a permutation group at random, and the RandomPPrimeElement command chooses at random an element with order not divisible by a specified prime $p$ .

>	g := RandomPElement( 3, Alt( 11 ) );

$g ≔ (8, 9, 11)$

(119)

>	ifactor( PermOrder( g ) );

$(3)$

(120)

>	evalb( g in Alt( 11 ) );

$true$

(121)

>	g := RandomPPrimeElement( 3, Alt( 11 ) );

$g ≔ (1, 6, 11, 5, 2, 3, 8, 9, 7, 4, 10)$

(122)

>	ifactor( PermOrder( g ) );

$(11)$

(123)

>	evalb( g in Alt( 11 ) );

$true$

(124)

•

The new OrderClassProfile command computes the number of elements of each order in a finite group. A sorted list of element orders is returned by default, but you can request that the output be produced in the form of a MultiSet, or a list of pairs of the form [ order, multiplicity ] by using the appropriate option, as illustrated in the examples below.

>	OrderClassProfile( Alt( 4 ) );

$[[1, 1], [2, 3], [3, 8]]$

(125)

>	OrderClassProfile( Alt( 4 ), 'output' = "list" );

$[1, 2, 2, 2, 3, 3, 3, 3, 3, 3, 3, 3]$

(126)

>	OrderClassProfile( Alt( 4 ), 'output' = "multiset" );

$\{[1, 1], [2, 3], [3, 8]\}$

(127)

•	The OrderClassPolynomial command provides an encoding of the order class data in the form of a polynomial expression in an indeterminate x, in which the coefficient of the term x^k is equal to the number of elements of order k.

>	OrderClassPolynomial( Alt( 4 ), 'x' );

$8 x^{3} + 3 x^{2} + x$

(128)

New and Updated Group Databases

•	2019 includes a new database of Frobenius groups, as well as updates to the databases of small groups, transitive groups and perfect groups.

New Database of Frobenius Groups

•	2019 also introduces a new database of Frobenius groups.

•	To determine the number of Frobenius groups of a given order $n$ , use the command NumFrobeniusGroups( n ).

>	NumFrobeniusGroups( 6 );

$1$

(129)

>	NumFrobeniusGroups( 60 );

$0$

(130)

>	NumFrobeniusGroups( 100 );

$3$

(131)

•	To access a Frobenius group in the database, similar to the other group databases in Maple, use the command FrobeniusGroup( n, k ) to access the $k$ -th Frobenius group of order $n$ .

>	G := FrobeniusGroup( 100, 3 );

$G ≔ ⟨(2, 7, 11, 4) (3, 6, 15, 10) (5, 17, 25, 18) (8, 9, 24, 23) (12, 20, 22, 14) (13, 19, 21, 16), (2, 11) (3, 15) (4, 7) (5, 25) (6, 10) (8, 24) (9, 23) (12, 22) (13, 21) (14, 20) (16, 19) (17, 18), (1, 2, 4, 7, 11) (3, 5, 8, 12, 16) (6, 9, 13, 17, 20) (10, 14, 18, 21, 23) (15, 19, 22, 24, 25), (1, 3, 6, 10, 15) (2, 5, 9, 14, 19) (4, 8, 13, 18, 22) (7, 12, 17, 21, 24) (11, 16, 20, 23, 25)⟩$

(132)

>	GroupOrder( FrobeniusKernel( G ) );

$25$

(133)

>	GroupOrder( FrobeniusComplement( G ) );

$4$

(134)

•	The AllFrobeniusGroups( n ) command returns a list of all the Frobenius groups of a given order $n$ .

>	L := AllFrobeniusGroups( 18 );

$L ≔ [⟨(2, 9) (3, 6) (4, 8) (5, 7), (1, 2, 4, 3, 5, 7, 6, 8, 9), (1, 3, 6) (2, 5, 8) (4, 7, 9)⟩, ⟨(2, 4) (3, 6) (5, 9) (7, 8), (1, 2, 4) (3, 5, 7) (6, 8, 9), (1, 3, 6) (2, 5, 8) (4, 7, 9)⟩]$

(135)

>	evalb( nops( L ) = NumFrobeniusGroups( 18 ) );

$true$

(136)

•	The IdentifyFrobeniusGroup command returns the ID of a Frobenius group that is present in the Frobenius groups database.

>	IdentifyFrobeniusGroup( Symm( 3 ) );

$6, 1$

(137)

>	IdentifyFrobeniusGroup( Alt( 4 ) );

$12, 1$

(138)

>	AreIsomorphic( Alt( 4 ), FrobeniusGroup( 12, 1 ) );

$true$

(139)

•

The Frobenius groups database is searchable by using the SearchFrobeniusGroups command. This is similar to SearchSmallGroups and SearchTransitiveGroups. Consult the help page SearchFrobeniusGroups for a complete list and description of the pre-computed properties that can be queried using this command.

>	SearchFrobeniusGroups( order < 50, 'cyclickernel', 'cycliccomplement' );

$[6, 1], [10, 1], [14, 1], [18, 1], [20, 1], [21, 1], [22, 1], [26, 1], [30, 1], [34, 1], [38, 1], [39, 1], [42, 1], [42, 2], [46, 1]$

(140)

>	G := FrobeniusGroup( 42, 1 );

$G ≔ ⟨(2, 7) (3, 6) (4, 5), (2, 3, 5) (4, 7, 6), (1, 2, 3, 4, 5, 6, 7)⟩$

(141)

>	IsCyclic( FrobeniusKernel( G ) );

$true$

(142)

>	IsCyclic( FrobeniusComplement( G ) );

$true$

(143)

•	Let us construct one of the maximal subgroups of the exceptional group $Sz (8)$ , as follows.

>	a, b := op( Generators( ExceptionalGroup( "Sz(8)" ) ) ):

>	G := Group( [ (a.b)^2 . (b.a)^2 .b, (a.b^2)^(-1) . b.a.b^2 ] ):

•	This subgroup is a Frobenius group.

>	IsFrobeniusGroup( G );

$true$

(144)

•	To compute the Frobenius kernel and complement and determine their orders, proceed as follows.

>	K := FrobeniusKernel( G );

$K ≔ Fitt (⟨(1, 20) (2, 34) (3, 31) (4, 49) (5, 21) (6, 12) (7, 54) (8, 13) (9, 58) (10, 64) (11, 46) (14, 40) (15, 51) (16, 26) (17, 47) (18, 60) (19, 32) (22, 35) (23, 61) (24, 45) (25, 62) (27, 57) (28, 39) (29, 48) (30, 36) (33, 41) (37, 65) (38, 59) (42, 50) (43, 53) (44, 55) (56, 63), (1, 29, 40, 19) (2, 10, 16, 24) (3, 41, 53, 14) (4, 44, 56, 47) (6, 52, 11, 38) (7, 59, 21, 46) (8, 17, 26, 31) (9, 28, 37, 49) (12, 25, 62, 54) (13, 48, 61, 58) (15, 30, 23, 18) (20, 45, 63, 60) (22, 27, 51, 55) (32, 50, 57, 34) (33, 64, 35, 65) (36, 42, 43, 39)⟩)$

(145)

>	GroupOrder( K );

$13$

(146)

>	C := FrobeniusComplement( G );

$C ≔ ⟨(1, 47, 41, 27) (2, 43, 8, 18) (3, 4, 36, 20) (5, 12, 7, 54) (6, 62, 59, 11) (9, 40, 64, 63) (10, 49, 60, 42) (13, 24, 15, 65) (14, 45, 35, 30) (16, 48, 50, 37) (17, 22, 53, 23) (19, 51, 58, 33) (21, 46, 25, 52) (26, 32, 61, 55) (28, 57, 56, 29) (31, 39, 44, 34)⟩$

(147)

>	GroupOrder( C );

$4$

(148)

>	IsMalnormal( C, G );

$true$

(149)

•	Subgroups of Frobenius complements whose order is the product of two primes are necessarily cyclic.

>	IsCyclic( C );

$true$

(150)

>	IdentifySmallGroup( C );

$4, 1$

(151)

•	However, the natural action of this group is not Frobenius.

>	IsFrobeniusPermGroup( G );

$false$

(152)

•	To get an isomorphic Frobenius permutation group (via the action of $G$ on the cosets of the Frobenius complement), use the FrobeniusPermRep command.

>	P := FrobeniusPermRep( G );

$P ≔ ⟨(1, 2) (3, 8) (4, 13) (5, 10) (6, 7) (11, 12), (1, 6, 5, 2) (3, 7, 4, 12) (8, 13, 10, 9)⟩$

(153)

>	IsFrobeniusPermGroup( P );

$true$

(154)

•	Of course, the Frobenius kernel and complement of $P$ are isomorphic to those of $G$ .

>	IdentifySmallGroup( FrobeniusComplement( P ) );

$4, 1$

(155)

>	AreIsomorphic( FrobeniusKernel( P ), K );

$true$

(156)

•	To locate this group in the database of Frobenius groups, use the IdentifyFrobeniusGroup command.

>	IdentifyFrobeniusGroup( G );

$52, 1$

(157)

•	Or, equivalently:

>	IdentifyFrobeniusGroup( P );

$52, 1$

(158)

•	Finally, as discussed below, the Frobenius (permutation) groups in the database of transitive groups have been identified, and can be used as a search term there. As well, the Frobenius (abstract) groups in the Small Groups database have been identified.

Updated Database of Perfect Groups

•

The new SearchPerfectGroups command allows you to search the database of perfect group for groups satisfying various combinations of properties, including the order, center, socle, Fitting subgroup, class number and others. Consult the help page SearchPerfectGroups for a complete list of the supported properties.

•	Find the perfect groups with non-trivial center, whose order is less than $1000$ .

>	L := [SearchPerfectGroups]( order < 1000, center > 1, 'form' = "fpgroup" );

$L ≔ [⟨c, e, f ∣ f^{2}, c^{2} f^{-1}, e^{3}, f^{-1} e^{-1} f e, c e c e c e c e c e⟩, ⟨c, e, f ∣ f^{2}, c^{2} f^{-1}, e^{3}, f^{-1} e^{-1} f e, c e c e c e c e c e c e c e, c^{-1} e^{-1} c e c^{-1} e^{-1} c e c^{-1} e^{-1} c e c^{-1} e^{-1} c e f^{-1}⟩, ⟨c, e, f, h ∣ h^{2}, c^{2} h^{-1}, e^{3}, f^{3}, h^{-1} e^{-1} h e, h^{-1} f^{-1} h f, e f e f e f e f h^{-1}, c^{-1} e^{-1} f e f e^{-1} f e f^{-1}, e f^{-1} e f^{-1} e f^{-1} e f^{-1} e f^{-1}⟩]$

(159)

>	map( GroupOrder, L );

$[120, 336, 720]$

(160)

>	map( IsPerfect, L );

$[true, true, true]$

(161)

>	map( GroupOrder @ Center @ PermutationGroup, L );

$[2, 2, 2]$

(162)

•	Find those perfect groups of order less than $10000$ with center isomorphic to SmallGroup( 4, 2 ).

>	SearchPerfectGroups( order < 10000, center = [ 4, 2 ] ); # SmallGroup ID for center!

$[3840, 3], [3840, 4], [3840, 5], [3840, 7], [5376, 1]$

(163)

•	It is important to understand that the IDs returned by SearchPerfectGroups are the IDs of groups in the database of perfect groups, while the IDs used in queries such as the one above are IDs for the small groups database.

Updated Databases of Small Groups and Transitive Groups

•	Many new properties have been added to the databases of small groups and transitive groups. See the help pages for SearchSmallGroups and SearchTransitiveGroups for a complete list of the supported, searchable properties.

>	SearchSmallGroups( order <= 32, compositionlength = 5, abelian );

$[32, 1], [32, 3], [32, 16], [32, 21], [32, 36], [32, 45], [32, 51]$

(164)

>	SearchSmallGroups( hamiltonian, order = 100 .. 120 );

$[104, 11], [112, 39], [120, 33]$

(165)

>	SearchSmallGroups( almostsimple );

$[60, 5], [120, 34], [168, 42], [336, 208], [360, 118], [504, 156]$

(166)

•	The TransitiveGroups database now includes some abstract group-theoretic properties.

•	Which soluble, but non-Abelian transitive groups have degree less than $5$ ?

>	SearchTransitiveGroups( degree < 5, soluble, abelian = false );

$[3, 2], [4, 3], [4, 4], [4, 5]$

(167)

•	The following visualization gives an indication of the relative prevalence of soluble transitive groups in the database.

>	Statistics:-PieChart( [ "Soluble" = SearchTransitiveGroups( 'soluble', 'form' = "count" ), "Insoluble" = SearchTransitiveGroups( 'soluble' = false, 'form' = "count" ) ] );

•	How many transitive groups in the database are perfect, but not simple?

>	SearchTransitiveGroups( simple = false, perfect, form = "count" );

$386$

(168)

•	Importantly, the Frobenius groups in the transitive groups database have been identified.

>	SearchTransitiveGroups( frobenius, form = count );

$82$

(169)

•	We know that there are two Frobenius groups of order $18$ .

>	NumFrobeniusGroups( 18 );

$2$

(170)

•	Let's see if both also appear in the TransitiveGroups database.

>	SearchTransitiveGroups( frobenius, order = 18 );

$[9, 3], [9, 5]$

(171)

>	IsFrobeniusPermGroup( TransitiveGroup( 9, 3 ) );

$true$

(172)

>	IsFrobeniusPermGroup( TransitiveGroup( 9, 5 ) );

$true$

(173)

•	Use IdentifyFrobeniusGroup to distinguish which transitive group corresponds to which Frobenius group from their respective databases.

>	IdentifyFrobeniusGroup( TransitiveGroup( 9, 3 ) );

$18, 1$

(174)

>	IdentifyFrobeniusGroup( TransitiveGroup( 9, 5 ) );

$18, 2$

(175)

>	AreIsomorphic( TransitiveGroup( 9, 3 ), FrobeniusGroup( 18, 1 ) );

$true$

(176)

>	AreIsomorphic( TransitiveGroup( 9, 5 ), FrobeniusGroup( 18, 2 ) );

$true$

(177)

Performance Improvements

•	Arithmetic and other low-level operations for permutations have been completely re-written in compiled kernel code. In addition, the memory overhead of permutations has been considerably reduced.

•	For example, the following call to PermOrder took about 200 times longer in Maple 2018.

>	p := Perm( combinat:-randperm( 10^5 ) ):

>	PermOrder( p );

$2071130635650776700$

(178)

•	Timing details will of course vary from one machine to another, and depend also upon the random state of the Maple session. But, reproduced here are some representative calculations run in a fresh Maple 2018 session, on a particular 64-bit Linux workstation.

>	L := CodeTools:-Usage( [seq]( Perm( combinat:-randperm( 10^4 ) ), i = 1 .. 1000 ) ):

memory used=307.01MiB, alloc change=283.42MiB, cpu time=6.62s, real time=6.62s, gc time=108.00ma

>	CodeTools:-Usage( PermProduct( op( L ) ) ):

memory used=307.57MiB, alloc change=288.00MiB, cpu time=9.78s, real time=8.36s, gc time=1.75s

>	CodeTools:-Usage( map( PermOrder, L ) ):

memory used=2.54GiB, alloc change=96.00MiB, cpu time=52.62s, real time=40.96s, gc time=13.75s

>	CodeTools:-Usage( map( PermInverse, L ) ):

memory used=0.74GiB, alloc change=320.00MiB, cpu time=19.56s, real time=14.66s, gc time=5.71s

>	CodeTools:-Usage( map( PermCycleType, L ) ):

memory used=0.84MiB, alloc change=0 bytes, cpu time=152.00ms, real time=149.00ms, gc time=0ns

>	CodeTools:-Usage( map( PermPower, L, 3333 ) ):

memory used=4.53GiB, alloc change=2.22GiB, cpu time=3.78m, real time=2.17m, gc time=113.08s

•	And here are the same calculations run in a fresh 2019 session on the same machine. It is apparent that both time used and memory consumption have been considerably reduced.

>	L := CodeTools:-Usage( [seq]( Perm( combinat:-randperm( 10^4 ) ), i = 1 .. 1000 ) ):

memory used=77.16MiB, alloc change=59.42MiB, cpu time=1.10s, real time=1.10s, gc time=8.00ms

>	CodeTools:-Usage( PermProduct( op( L ) ) ):

memory used=77.85MiB, alloc change=0 bytes, cpu time=592.00ms, real time=587.00ms, gc time=24.00ms

>	CodeTools:-Usage( map( PermOrder, L ) ):

memory used=8.08MiB, alloc change=3.01MiB, cpu time=204.00ms, real time=203.00ms, gc time=0ns

>	CodeTools:-Usage( map( PermInverse, L ) ):

memory used=77.30MiB, alloc change=-1.00MiB, cpu time=568.00ms, real time=560.00ms, gc time=16.00ms

>	CodeTools:-Usage( map( PermCycleType, L ) ):

memory used=214.05KiB, alloc change=0 bytes, cpu time=124.00ms, real time=125.00ms, gc time=0ns

>	CodeTools:-Usage( map( PermPower, L, 3333 ) ):

memory used=77.81MiB, alloc change=0 bytes, cpu time=764.00ms, real time=752.00ms, gc time=36.00ms

Maple

Maple Add-Ons

MapleSim

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim

Maple

Powerful math software that is easy to use

Maple Add-Ons

MapleSim

Advanced System Level Modeling

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim