DGsetup - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : Mathematics : DifferentialGeometry : DGsetup

DifferentialGeometry

DGsetup

set up a coordinate system, a frame, a Lie algebra, define a set of abstract forms

	Calling Sequence
	DGsetup(varlist1, framename, options) DGsetup(varlist1, varlist2, framename, options) DGsetup(varlist1, varlist2, framename, jetorder, options) DGsetup(framedata, options) DGsetup(Liealgebradata, options) DGsetup(alg, rho, V) DGsetup(abstractforms, streqn, framename)

Parameters

varlist1	-	a list of unassigned Maple names
varlist2	-	a list of unassigned Maple names
framename	-	an unassigned Maple name or a string
jetorder	-	a positive integer
framedata	-	the structure equations for an anholonomic frame, as calculated by the procedure FrameData
Liealgebradata	-	the structure equations for a Lie algebra, as calculated by the procedure LieAlgebraData
abstractforms	-	a list specifying a set of abstract forms, without reference to any underlying set of coordinates
streqn	-	a list of structure equations for the exterior derivatives and interior products of an abstract form
options	-	a list of frame labels, a list of co-frame labels, the keyword 'quiet' or 'verbose'

Description

•

All computational sessions with the DifferentialGeometry package begin with a call to the DGsetup command. This command fixes the coordinate names for the manifold being defined; specifies the vectors and 1-forms to be used as local frames and co-frames on the manifold; and stores all the computational rules needed to work with the given frame or co-frame. It is also used by the JetCalculus package to initialize a jet space to any given order and by the LieAlgebras package to prepare for computations with Lie algebras.

•	The following table summarizes the different calling sequences for DGsetup.

Ex 1.	Create a two-dimensional manifold $M$ with local coordinates $(x, y)$ .
	> DGsetup([x, y], M)
Ex 2.	Create a fiber bundle $E$ with fiber coordinates $(u, v)$ over a three-dimensional base space with coordinates $(x, y, z)$ .
	> DGsetup([x, y, z], [u,v], M);
Ex 3.	Create the 3rd order jet space $J$ for 2 independent variables $(x, y)$ and 1 dependent variable $(u)$ .
	> DGsetup([x, y], [u], J, 3);
Ex 4a.	Perform calculations on a three-dimensional manifold $N$ in terms of an anholonomic frame $F$ . The command FrameData is used to calculate the structure equations for the frame and this is passed to DGsetup.
	> DGsetup([x, y, z], M);
	> F := evalDG([D_x, x*D_x + D_y, y D_x + D_z]);
	> FD := FrameData(F, N);
	> DGsetup(FD);
Ex 4b.	Perform calculations on a three-dimensional manifold $N$ in terms of an anholonomic frame $F$ . Label the frame vectors $[X, Y, Z]$ and the co-frame 1-forms $[α, β, σ]$ .
	> DGsetup(FD, [X, Y, Z], [alpha, beta, sigma]);
Ex 5.	Perform calculations on a three-dimensional manifold $N$ in terms of an anholonomic co-frame $Ω$ . The command FrameData is used to calculate the structure equations for the frame and this is passed to DGsetup.
	> DGsetup([x, y, z], M);
	> Omega := evalDG([dx, xdx + dy, ydx + dz]);
	> FD := FrameData(Omega, N);
	> DGsetup(FD);
Ex 6a.	Initialize a Lie algebra alg1 defined by a set of 3 matrices $A = [M_{1}, M_{2}, M_{3}]$ . Use LieAlgebraData to calculate the structure equations for the Lie algebra and pass this result to DGsetup.
	> A := [Matrix([[1, 0], [0, 0]]), Matrix([[0, 1], [0, 0]]), Matrix([[0, 0],[0, 1]])];
	> LD := LieAlgebraData(A, alg1);
	> DGsetup(LD);
Ex 6b.	Initialize a Lie algebra alg1 defined by a set of 3 matrices. Label the basis elements for the Lie algebra as $[f_{1}, f_{2}, f_{3}]$ and the dual 1-forms by $[ξ_{1}, ξ_{2}, ξ_{3}]$
	> DGsetup(LD, [f], [xi]):
Ex 7.	Initialize a Lie algebra alg1 defined by a set of 3 vector fields $Γ = [X_{1}, X_{2}, X_{3}]$ . Use LieAlgebraData to calculate the structure equations for the Lie algebra and passed this result to DGsetup.
	> DGsetup([x, y], M);
	> Gamma : = evalDG([D_x, D_y, yD_x - xD_y]);
	> LD := LieAlgebraData(A, alg1):
	> DGsetup(LD);
Ex 8.	Initialize a Lie algebra alg1 from a set of structure equations. For other ways to initialize a Lie algebra, see LieAlgebraData.
	> B := [x, y, h];
	> S := [[h, x] = 2x, [h, y] = -2y, [x, y] = h];
	> LD := LieAlgebraData( S, B, alg);
	> DGsetup(LD);
Ex 9.	Initialize a classical simple Lie algebra, say $sl (3)$ , the Lie algebra of trace-free matrices. See SimpleLieAlgebraData.
	> LD := SimpleLieAlgebraData(sl(3), alg);
	> DGsetup(LD);
Ex 10.	Initialize a Lie algebra with coefficients in a representation.
	> LD := LieAlgebraData( [h,x] = 2x, [h,y] = -2y, [x,y] =h], [x, y, h], alg);
	> DGsetup(LD);
	> DGsetup([x1, x2, x3], V);
	> A := Adjoint();
	> rho := Representation(alg, V, Adjoint());
	> DGsetup(alg, rho, R):
Ex 11.	Initialize a set of abstract differential forms with a given set of structure equations.
	> DGsetup([f = dgform(0), alpha = dgform(1), beta = dgfom(2)], [d(beta) = alpha &w beta], M)
Ex 12.	Initialize an abstract co-frame and set of abstract differential forms with a given set of structure equations.
	> DGsetup([[alpha, beta], f = dgform(0), sigma = dgform(2)], [d(alpha) = f sigma, hook(D_alpha, sigma) = beta], M):

Examples

>	$with (DifferentialGeometry) &colon;$ $with (LieAlgebras) &colon;$

Example 1. Use the first calling sequence to set up a coordinate system on a manifold.

In this first example, we create a two-dimensional manifold M with coordinates [x, y].

>	$DGsetup ([x, y], M, verbose)$

$The following coordinates have been protected:$

$[x, y]$

$The following vector fields have been defined and protected:$

$[D_x, D_y]$

$The following differential 1-forms have been defined and protected:$

$[dx, dy]$

$frame name: M$

(1)

The coordinates are now protected names which cannot be assigned values.

The standard coordinate vectors D_x, D_y and dual 1 forms dx, dy have been defined and protected. We display the internal representation of these vectors just to show that they have been assigned values. (Knowledge of this internal representation of various objects used in the DifferentialGeometry package is not required of the user).

>	$lprint (D_x) &colon;$

_DG([["vector", M, []], [[[1], 1]]])

>	$lprint (dx)$

_DG([["form", M, 1], [[[1], 1]]])

Without the option 'verbose', the information concerning the definition and protection of variable is suppressed. This behavior of the DGsetup command can be controlled globally with the Preferences command.

>	$DGsetup ([u, v], N)$

$frame name: N$

(2)

Example 2. Use the second calling sequence to set up coordinates on a vector or fiber bundle.

In many situations in differential geometry, one deals with vector bundles or fiber bundles pi: E -> M. For these applications, use the second calling sequence to DGsetup. The

first argument varlist1 should be coordinates for the basis manifold M and the second argument should be the list of coordinates for the fiber of the bundle E. Here is the command

for creating a rank-2 bundle over a three-dimensional space. The base coordinates are [x, y, z] and the fiber coordinates are [u, v].

>	$DGsetup ([x, y, z], [u, v], P, verbose)$

$The following coordinates have been protected:$

$[x, y, z, u, v]$

$The following vector fields have been defined and protected:$

$[D_x, D_y, D_z, D_u, D_v]$

$The following differential 1-forms have been defined and protected:$

$[dx, dy, dz, du, dv]$

$frame name: P$

(3)

This particular use of DGsetup could be used, for example, to study a three-dimensional manifold imbedded in a five-dimensional Riemannian manifold, where the vectors D_u and D_v define a local basis for the normal bundle.

Example 3. Use the third calling sequence to set up coordinates on a jet bundle.

The JetCalculus subpackage of the DifferentialGeometry package contains an extensive set of commands for symbolic computations on jet spaces. These spaces provide the natural mathematical setting for the geometric approach to the calculus of variations and to differential equations. The third calling sequence for the DGsetup command will create a jet space over a bundle pi: E -> M with prescribed lists of independent variables (coordinates on M) and dependent variables (fiber coordinates on E). In addition to the coordinate vectors and coordinate differential forms on jet space, DGsetup also defines and protects the contact forms on jet space. See the JetCalculus overview page for additional information regarding these differential forms. The user may specify which of two notational conventions are to be used to denote the jet coordinates. See the Preferences command for details.

First we initialize the 3rd order jet space for 1 independent and 2 dependent variables.

>	$DGsetup ([t], [x, y], J12, 3, verbose)$

$The following coordinates have been protected:$

$[t, x [], y [], x_{1}, y_{1}, x_{1, 1}, y_{1, 1}, x_{1, 1, 1}, y_{1, 1, 1}]$

$The following vector fields have been defined and protected:$

$[D_t, D_x [], D_y [], {D_x}_{1}, {D_y}_{1}, {D_x}_{1, 1}, {D_y}_{1, 1}, {D_x}_{1, 1, 1}, {D_y}_{1, 1, 1}]$

$The following differential 1-forms have been defined and protected:$

$[dt, dx [], dy [], {dx}_{1}, {dy}_{1}, {dx}_{1, 1}, {dy}_{1, 1}, {dx}_{1, 1, 1}, {dy}_{1, 1, 1}]$

$The following type [1,0] biforms have been defined and protected::$

$[Dt]$

$The following type [0,1] biforms (contact 1-forms) have been defined and protected::$

$[Cx [], Cy [], {Cx}_{1}, {Cy}_{1}, {Cx}_{1, 1}, {Cy}_{1, 1}, {Cx}_{1, 1, 1}, {Cy}_{1, 1, 1}]$

$frame name: J12$

(4)

Here is the initialization of the 3rd order jet space for 2 independent and 1 dependent variable.

>	$DGsetup ([x, y], [U], J21, 3, verbose)$

$The following coordinates have been protected:$

$[x, y, U [], U_{1}, U_{2}, U_{1, 1}, U_{1, 2}, U_{2, 2}, U_{1, 1, 1}, U_{1, 1, 2}, U_{1, 2, 2}, U_{2, 2, 2}]$

$The following vector fields have been defined and protected:$

$[D_x, D_y, D_U [], {D_U}_{1}, {D_U}_{2}, {D_U}_{1, 1}, {D_U}_{1, 2}, {D_U}_{2, 2}, {D_U}_{1, 1, 1}, {D_U}_{1, 1, 2}, {D_U}_{1, 2, 2}, {D_U}_{2, 2, 2}]$

$The following differential 1-forms have been defined and protected:$

$[dx, dy, dU [], {dU}_{1}, {dU}_{2}, {dU}_{1, 1}, {dU}_{1, 2}, {dU}_{2, 2}, {dU}_{1, 1, 1}, {dU}_{1, 1, 2}, {dU}_{1, 2, 2}, {dU}_{2, 2, 2}]$

$The following type [1,0] biforms have been defined and protected::$

$[Dx, Dy]$

$The following type [0,1] biforms (contact 1-forms) have been defined and protected::$

$[CU [], {CU}_{1}, {CU}_{2}, {CU}_{1, 1}, {CU}_{1, 2}, {CU}_{2, 2}, {CU}_{1, 1, 1}, {CU}_{1, 1, 2}, {CU}_{1, 2, 2}, {CU}_{2, 2, 2}]$

$frame name: J21$

(5)

Example 4. Use the fourth calling sequence to set up an anholonomic frame on a manifold.

It is extremely important, for many calculations in DifferentialGeometry, to work with frames and co-frames other than the coordinate frame (e.g. D_x, D_y, ...) and the coordinate co-frame (e.g. dx, dy ...). For example, curvature tensor calculations are often greatly simplified by working in an orthonormal frame. To set up a frame for subsequent computations with the DifferentialGeometry package, first use the FrameData command to calculate the structure equations for the frame or co-frame. Then pass the output of the FrameData command to DGsetup.

>	$DGsetup ([x, y, z], M)$

$frame name: M$

(6)

The three vectors in the list F are the vectors that will be used as a frame.

>	$F ≔ evalDG ([D_x, D_y + x D_x, D_z + y D_x])$

$F ≔ [D_x, x D_x + D_y, y D_x + D_z]$

(7)

The command FrameData calculates the structure equations for this frame. These structure equations are displayed with the convention that the first element of the frame is E1, the second element is E2, and so on. The name of the manifold with coordinates [x, y, z] and anholonomic frame F is M1.

>	$StructureEquations ≔ FrameData (F, M1)$

$StructureEquations ≔ [[E1, E2] = E1, [E2, E3] = (1 - y) E1]$

(8)

Pass the output of FrameData to the command DGsetup. Now in place of the coordinate vectors D_x, D_y, D_z and coordinate form dx, dy, dz, we shall use the vectors F[1], F[2], F[3] and the dual 1 forms. The default labels for the frame elements are E1, E2, E3 and the default labels for the co-frame elements are Theta1, Theta2, Theta3.

>	$DGsetup (StructureEquations, verbose)$

$The following coordinates have been protected:$

$[x, y, z]$

$The following vector fields have been defined and protected:$

$[E1, E2, E3]$

$The following differential 1-forms have been defined and protected:$

$[Θ1, Θ2, Θ3]$

$frame name: M1$

(9)

As sample calculations on the manifold M1 we have:

>	$LieBracket (E2, E3)$

$- (- 1 + y) E1$

(10)

>	$ExteriorDerivative (Θ1)$

$- Θ1 ⋀ Θ2 + (- 1 + y) Θ2 ⋀ Θ3$

(11)

We can specify the labels for the frame and the co-frame as optional arguments to DGsetup. The second argument is a list of names for the frame elements and the third argument is a list of names for the co-frame elements. If a list with just one name is given, then that name is used as the kernel name for the list of frame or co-frame elements. For example:

>	$DGsetup (StructureEquations, [X, Y, Z], [ω], verbose)$

$The following coordinates have been protected:$

$[x, y, z]$

$The following vector fields have been defined and protected:$

$[X, Y, Z]$

$The following differential 1-forms have been defined and protected:$

$[ω1, ω2, ω3]$

$frame name: M1$

(12)

Example 5. Use the fourth calling sequence to set up an anholonomic co-frame on a manifold.

The same commands used in the previous example can be used to create an anholonomic co-frame on a manifold.

>	$DGsetup ([x, y, z], M)$

$frame name: M$

(13)

The three 1-forms in the list Omega are the 1-forms that will be used as a co-frame.

>	$Ω ≔ evalDG ([dx, x dx + dy, y dx + dz])$

$Ω ≔ [dx, x dx + dy, y dx + dz]$

(14)

The command FrameData calculates the structure equations for this co-frame. These structure equations are displayed with the convention that the first element of the frame is $Θ_{}$ 1, the second element is $Θ_{}$ 2, and so on. The name of the manifold with coordinates [x, y, z] and anholonomic frame Omega is M1.

>	$StructureEquations ≔ FrameData (Ω, M1)$

$StructureEquations ≔ [d Θ1 = 0, d Θ2 = 0, d Θ3 = - Θ1 ⋀ Θ2]$

(15)

Pass the output of FrameData to the command DGsetup. Now in place of the coordinate vectors D_x, D_y, D_z and coordinate form dx, dy, dz, we shall use the 1-forms Omega[1], Omega[2], Omega[3] and the dual vector fields. The default labels for the frame elements are E1, E2, E3 and the default labels for the co-frame elements are Theta1, Theta2, Theta3.

>	$DGsetup (StructureEquations, verbose)$

$The following coordinates have been protected:$

$[x, y, z]$

$The following vector fields have been defined and protected:$

$[E1, E2, E3]$

$The following differential 1-forms have been defined and protected:$

$[Θ1, Θ2, Θ3]$

$frame name: M1$

(16)

Example 6. Use the fifth calling sequence to initialize a Lie algebra, defined by a set of matrices

The DGsetup command can also be used to initialize a Lie algebra the same way that DGsetup is used to initialize an anholonomic frame on a manifold. Typically, one first obtains the structure equations for the Lie algebra using the LieAlgebraData command and then passes these structure equations to DGsetup. Structure equations for a large number of Lie algebras can also be retrieved from the database of Lie algebras found in the Library package.

>	$M ≔ [Matrix ([[1, 0], [0, 0]]), Matrix ([[0, 1], [0, 0]]), Matrix ([[0, 0], [0, 1]])]$

$M ≔ [[], [], []]$

(17)

Calculate the structure equations for the matrix Lie algebra defined by the matrices M. Here e1 refers to the first matrix in M, e2 the second matrix, ....

>	$StructureEquations ≔ LieAlgebraData (M, Alg1)$

$StructureEquations ≔ [[e1, e2] = e2, [e2, e3] = e2]$

(18)

The default names for the basis elements for the Lie algebra are e1, e2, e3.... The default names for the basis elements for the dual elements of the Lie algebra are theta1, theta2, ....

>	$DGsetup (StructureEquations, verbose)$

$The following vector fields have been defined and protected:$

$[e1, e2, e3]$

$The following differential 1-forms have been defined and protected:$

$[θ1, θ2, θ3]$

$Lie algebra: Alg1$

(19)

Again it is a simple matter to override this default labeling.

>	$DGsetup (StructureEquations, [f], [ξ], verbose)$

$The following vector fields have been defined and protected:$

$[f1, f2, f3]$

$The following differential 1-forms have been defined and protected:$

$[ξ1, ξ2, ξ3]$

$Lie algebra: Alg1$

(20)

Example 7. Use the fifth calling sequence to initialize a Lie algebra, defined by a set of vector fields

The same sequence of commands as illustrated in the previous example can be used to initialize a Lie algebra from a set of vector fields.

>	$DGsetup ([x, y], M7)$

$frame name: M7$

(21)

Here are the vector fields we shall use.

>	$Gamma ≔ evalDG ([D_x, D_y, y D_x - x D_y])$

$Γ ≔ [D_x, D_y, y D_x - x D_y]$

(22)

>	$LD ≔ LieAlgebraData (Gamma, alg7)$

$LD ≔ [[e1, e3] = - e2, [e2, e3] = e1]$

(23)

>	$DGsetup (LD, [Tx, Ty, R], [ω])$

$Lie algebra: alg7$

(24)

>	$MultiplicationTable (LieTable)$

$[]$

(25)

Example 8. Use the fifth calling sequence to initialize a simple Lie algebra, defined by structure equations

The LieAlgebraData command, in conjunction with DGsetup, can be used to initialize a Lie algebra from a set of structure equations. First specify the basis elements. These must be unassigned names.

>	$B ≔ [x, y, h]$

$B ≔ [x, y, h]$

(26)

Define a list of structure equations for a Lie algebra.

>	$S ≔ [[h, x] = 2 x, [h, y] = - 2 y, [x, y] = h]$

$S ≔ [[h, x] = 2 x, [h, y] = - 2 y, [x, y] = h]$

(27)

>	$LD ≔ LieAlgebraData (S, B, alg8)$

$LD ≔ [[e1, e2] = e3, [e1, e3] = - 2 e1, [e2, e3] = 2 e2]$

(28)

>	$DGsetup (LD)$

$Lie algebra: alg8$

(29)

Example 9. Use the fifth calling sequence to initialize a simple Lie algebra, constructed from the command "SimpleLieAlgebraData"

The LieAlgebra package contains tables of structures equations for the classical simple and semi-simple matrix algebras. These can be accessed with the command SimpleLieAlgebraData. In this example we initialize $sl (3)$ , the Lie algebra of $3 \times 3$ trace-free matrices.

>	$LD ≔ SimpleLieAlgebraData (sl(3), alg9)$

$LD ≔ [[e1, e3] = e3, [e1, e4] = 2 e4, [e1, e5] = - e5, [e1, e6] = e6, [e1, e7] = - 2 e7, [e1, e8] = - e8, [e2, e3] = - e3, [e2, e4] = e4, [e2, e5] = e5, [e2, e6] = 2 e6, [e2, e7] = - e7, [e2, e8] = - 2 e8, [e3, e5] = e1 - e2, [e3, e6] = e4, [e3, e7] = - e8, [e4, e5] = - e6, [e4, e7] = e1, [e4, e8] = e3, [e5, e8] = - e7, [e6, e7] = e5, [e6, e8] = e2]$

(30)

>	$DGsetup (LD)$

$Lie algebra: alg9$

(31)

Example 10. Use the sixth calling sequence to initialize a Lie algebra with coefficients in a representation

Exterior forms on Lie algebras can be generalized to allow for coefficients in a representation. In this example we use the three-dimensional Lie algebra defined in Example 7 and its adjoint representation. First, define a three-dimensional space to serve as the representation space.

>	$DGsetup ([x1, x2, x3], V)$

$frame name: V$

(32)

Now use the Adjoint and Representation commands to create the adjoint representation for $alg7$ .

>	$A ≔ Adjoint (alg7)$

$A ≔ [[], [], []]$

(33)

>	$ρ ≔ Representation (alg7, V, A)$

$ρ ≔ [[Tx, []], [Ty, []], [R, []]]$

(34)

Invoke the sixth calling sequence for DGsetup.

>	$DGsetup (alg7, ρ, Rep1)$

$Lie algebra with coefficients: Rep1$

(35)

At this point one can calculate, for example, the exterior derivative of a 1-form on alg7 with coefficients in V.

>	$DGsetup (alg7, ρ, Rep1)$

$Lie algebra with coefficients: Rep1$

(36)

Example 11. Use the seventh calling sequence to initialize a list of abstract differential forms

In this example we use DGsetup to define a computational environment defined by a single scalar $f$ , a 1-form $α_{}$ and a 2-form $β_{}$ . The exterior derivative of $α_{}$ is specified as $d (α) = f β_{}$ .

>	$DGsetup ([f = dgform (0), α = dgform (1), β = dgform (2)], [d (α) = f β], M11)$

$frame name: M11$

(37)

>	$ExteriorDerivative (α)$

$β f$

(38)

>	$ExteriorDerivative ((α &w β) &w β)$

$- 2 α ⋀ β ⋀ d β + β f ⋀ β ⋀ β$

(39)

We use DGsetup to add forms or structure equations.

>	$DGsetup (M11, [σ = dgform (1)], [d (β) = σ &w β])$

$updated frame: M11$

(40)

>	$ExteriorDerivative (β)$

$β ⋀ σ$

(41)

Example 12. Use the seventh calling sequence to initialize a co-frame and a list of abstract differential forms

This is essentially the same as Example 11 except that the first list, used to specify the list of abstract forms, now contains a sublist defining a co-frame. In this example, we would like to label the co-frame as $[ω1, ω2, ω3]$ but these names were assigned to the 1-forms for the Lie algebra $alg7$ . Therefore, we should first remove this frame.

>	$RemoveFrame (alg7)$

$13$

(42)

>	$DGsetup ([[ω1, ω2, ω3], β1 = dgform (2)], [d (ω1) = ω2 &w ω3, d (ω2) = β1], M12)$

$frame name: M12$

(43)

>	$ExteriorDerivative (ω1)$

$ω2 ⋀ ω3$

(44)

In this setting interior products and Lie derivatives can be computed.

>	$Hook (D_omega2, β1)$

$ι_{2} β1$

(45)

>	$LieDerivative (D_omega2, β1)$

$ι_{2} d β1 + d ι_{2} β1$

(46)

For more information on abstract differential forms in DifferentialGeometry, see WorkingWithAbstractForms.

Maple

Maple Add-Ons

MapleSim

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim

Maple

Powerful math software that is easy to use

Maple Add-Ons

MapleSim

Advanced System Level Modeling

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim