int - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : Physics : Vectors : int

Physics[Vectors][int] - extend the int command to also compute path, surface, and volume integrals from the mathematical representation of the region, vectorial, parametric or as a set of expressions relating the coordinates to each other

Calling Sequence

int(F, r_ = A .. B, path = C)

int(F, r_, path = C, parameter = [t = a..b])

int(F, r_ = C, parameter = [t = a..b])

int(F, r_ = A .. B, path = C, kind = crossproduct)

int(F, S_, surface = C, parameters = [u = a..b, v = c..d])

int(F, S_ = C, parameters = [u = a..b, v = c..d])

int(F, S_, parameters = [u = a..b, v = c..d], kind = crossproduct)

int(F, V, volume = C, parameters = [u = a..b, v = c..d, w = c..d])

int(F, V = C, parameters = [u = a..b, v = c..d, w = c..d])

Parameters

F or F_	-	the integrand, can be an algebraic scalar expression F, or a vector function F_ (to represent vector functions see notation)
C	-	the mathematical formulation for the region of integration; it could be a vector function representation - of a curve, surface, or volume - or an algebraic equation relating the coordinates, or any region's representation as a set or list of such relations, solved or not for the coordinates in terms of parameters.
r_ = A..B	-	the global symbol r_ (not another symbol), representing the position vector, whose differential $d \vec{r}$ is the line element of the integration path. On the right-hand side A and B represent the initial and final points of the path C of integration and can be omitted when the parameter option is used and includes the parameter's range of integration.
r_ = C	-	in this case the right-hand side is itself the region of integration C and the argument path = C can be omitted.
S_	-	the global symbol S_ (not another symbol); $d \vec{S}$ represents the surface element of the surface of integration.
S_ = C	-	in this case the right-hand side is itself the region of integration C and the argument surface = C can be omitted.
V	-	the global symbol V (not another symbol); $dV$ represents the volume element of the volume of integration.
V = C	-	in this case the right-hand side is itself the region of integration C and the argument volume = C can be omitted.
path = C	-	synonym curve = C, together with using the symbol r_ as integration variable, it indicates that the integral is a 1-dimensional path integral
surface = C	-	together with using the symbol S_ as integration variable, indicates that the integral is a 2-dimensional surface integral
volume = C	-	together with using the symbol V as integration variable, indicates that the integral is a 3-dimensional volume integral
kind = crossproduct	-	indicates that the integrand is the cross product of the vector function F_ (the first argument to int) with the line or surface elements $d \vec{r}$ or $d \vec{S}$
parameters = ...	-	synonym parameter, optional for line integrals, mandatory for surface and volume integrals, the right-hand side is a list with the parameters and their ranges specifying the region of integration, e.g. in the case of surface integrals [u = a..b, v = c..d]. In the case of path integrals, the right-hand side can also be only the parameter, without its range, provide that the integration limits A and B are given.
inert	-	optional, when passed it makes int return the integral expressed in terms of the parameters but before performing the integration, as an inert Int function call

Description

•

The int command of the Vectors package extends the Maple int command to also compute vector integrals; these are path, surface, or volume integrals, where the integrand is a scalar or vector function, and starting from any region's description (algebraic, parametric, vectorial). In the context of the Physics Vectors package, vectors are names that end with the underscore _ and vector functions are functions where the name ends with the underscore _.

•	There are three kinds of line or path integrals:

${(\int_{\vec{A}}^{\vec{B}} F &DifferentialD; \vec{r})}_{path = C}$

${(\int_{\vec{A}}^{\vec{B}} \vec{F} \cdot &DifferentialD; \vec{r})}_{path = C}$

${(\int_{\vec{A}}^{\vec{B}} \vec{F} \times &DifferentialD; \vec{r})}_{path = C}$

where $\vec{A}$ and $\vec{B}$ are points in space, the limits of integration, that belong to the curve $C$ over which the integral is performed. In the first integral, $F$ is a scalar function and the result of the integration is thus a vector. In the second and third integrals the integrand $\vec{F}$ is a vector function, so that the dot product $\vec{F} \cdot d \vec{r}$ is a scalar and so is the integral, while in the third one $\vec{F} \times d \vec{r}$ is a vector and so is its integration over the region $C$ .

•	Likewise, there are three kinds of surface integrals

${(\int F &DifferentialD; \vec{S})}_{surface = C, parameters = [u = a .. b, v = c .. d]}$

${(\int \vec{F} \cdot &DifferentialD; \vec{S})}_{surface = C, parameters = [u = a .. b, v = c .. d]}$

${(\int \vec{F} \times &DifferentialD; \vec{S})}_{surface = C, parameters = [u = a .. b, v = c .. d]}$

and two types of volume integrals

${(\int F &DifferentialD; V)}_{volume = C, parameters = [u = a .. b, v = c .. d, w = f .. g]}$

${(\int \vec{F} &DifferentialD; V)}_{volume = C, parameters = [u = a .. b, v = c .. d, w = f .. g]}$

•	The conventions to represent these integrals are those of the standard int Maple command, extended to handle vector integrals as follows:

–

The first argument - the integrand - can be a scalar function, say $F$ , or a vector function $\vec{F}$ , in which case, for line and surface integrals, where the element of integration is also a vector, the integral is understood as the integral of their scalar product e.g. $\vec{F} \cdot d \vec{r}$ for line integrals. If the optional argument kind = crossproduct is passed, the integral is understood as the integral of the cross product e.g. $\vec{F} \times d \vec{S}$ for surface integrals.

–

The second argument, the integration variable, also indicates the kind of integration - line (path), surface, or volume - by respectively using the global names r_, S_, or V, so that $d \vec{r}$ is a line element, $d \vec{S}$ a surface element and $dV$ a volume element. In the case of path integrals, the second argument can include the range as in r_ = A_ .. B_ where A_ and B_ represent two points in space that belong to the integration curve $C$ .

–

The region of integration is indicated as region = ... where region is the keyword path or curve for line integrals, and surface and volume for surface and volume integrals. The right-hand side of region = ... specifies the region of integration as a vector function or as an equation relating the coordinates, or as a set or list of them. That specification is used by int to derive parametric equations representing the region using the ParametrizeCurve, ParametrizeSurface, and ParametrizeVolume commands. Alternative ways of specifying the region of integration are discussed in the Examples section.

–

The parameters and their ranges covering the region of integration, are required in the case of surface and volume integrals. Indicating the parameter, or its range, are both optional in the case of line integrals and, when the range is not passed, the integration limits are required expressed as two points $\vec{A}$ and $\vec{B}$ . When these two points are one and the same, it is understood to be a closed path of integration. The parameters can also be indicated as functionality of the coordinates, for example using $x (t)$ instead of just $x$ when indicating the integration region C.

–

The limits of integration $\vec{A}$ and $\vec{B}$ in path integrals must be points of the integration path and can be represented using the notation for algebraic vectors of the Vectors package, as a sum of terms where each one is the product of a unit vector times some coefficient, or as a list with the three components of the vector.

•

You can use a shortcut notation for all of path, surface, and volume integrals, consisting of passing the second argument as an equation having integration variable (r_, S_, or V) on the left-hand side, and the region of integration C on the right-hand side. In those cases, the argument region = C where region is one of path, surface, or volume becomes redundant and can be omitted.

•	The line element $d \vec{r}$ in path integrals is expressed in terms of a parameter $t$ as

$d \vec{r} = (\frac{&DifferentialD;}{&DifferentialD; t} \vec{r} (t)) dt$

Using indexed notation for derivatives ${\vec{r}}_{u} = \frac{\partial}{\partial u} \vec{r} (u, v)$ , the surface element $d \vec{S}$ in surface integrals is expressed in terms of parameters as

$d \vec{S} = {\vec{r}}_{u} \times {\vec{r}}_{v} du dv$

and the volume element $d V$ in volume integrals as

$dV = {\vec{r}}_{u} \cdot ({\vec{r}}_{v} \times {\vec{r}}_{w}) du dv dw$

Since both $d \vec{S}$ and $d V$ involve a cross product, there is a sign that depends on the ordering of the parameters $u, v, w$ . To have control over that sign, the parameters on the right-hand side of parameters = ... are expected as an ordered list.

•

The integrals in the three cases are computed by first expressing the integrand and the integration element in terms of the parameters using the parametric equations derived with ParametrizeCurve, ParametrizeSurface, and ParametrizeVolume, then performing the vector product operations, then the integration. Passing the optional argument inert, the last integration step is not performed and a result is returned using the inert function Int.

Examples

>	with(Physics:-Vectors);

$[&x, `+`, `.`, Assume, ChangeBasis, ChangeCoordinates, CompactDisplay, Component, Curl, DirectionalDiff, Divergence, Gradient, Identify, Laplacian, \nabla, Norm, ParametrizeCurve, ParametrizeSurface, ParametrizeVolume, Setup, Simplify, `^`, diff, int]$

(1)

>	Setup(mathematicalnotation = true);

$[mathematicalnotation = true]$

(2)

Path integrals

Consider the following scalar function $F$ , path $C$ and integration limits $\vec{A}$ and $\vec{B}$

F := x*y;

$F ≔ x y$

(3)

>	C := {y = x^2, z = 0};

$C ≔ \{y = x^{2}, z = 0\}$

(4)

>	A_ := [0, 0, 0];

$\vec{A} ≔ [0, 0, 0]$

(5)

>	B_ := [1, 1, 0];

$\vec{B} ≔ [1, 1, 0]$

(6)

The line or path integral, shown here in inert form on the left-hand side and active, computed to the end on the right-hand side, is

>	(Int = int)(F, r_ = A_ .. B_, path = C);

(7)

Note that the output on the right-hand side is a vector. Within int, to perform this integration the curve $C = \{y = x^{2}, z = 0\}$ is first parametrized using ParametrizeCurve

>	ParametrizeCurve(C);

$[x (t) = t, y (t) = t^{2}, z (t) = 0], t$

(8)

The output above is a sequence, first the parametric equations as an ordered list (order $[x, y, z]$ ) then the parameter, in this case $t$ . For the formulation of the integral to make sense, the limits of integration $\vec{A}$ and $\vec{B}$ must belong to this curve, i.e. satisfy the parametric equations for some value of the parameter, in this case $t = 0$ and $t = 1$

>	A_ = Eval((8)[1], t = 0);

$[0, 0, 0] = \binom{[x (t) = t, y (t) = t^{2}, z (t) = 0]}{} | \binom{}{t = 0}$

(9)

>	B_ = Eval((8)[1], t = 1);

$[1, 1, 0] = \binom{[x (t) = t, y (t) = t^{2}, z (t) = 0]}{} | \binom{}{t = 1}$

(10)

To see the integral after being parametrized and before performing the integration use the option inert

>	(Int = int)(F, r_ = A_ .. B_, path = C, inert);

(11)

Since there is a relation one-to-one between the integration limits $\vec{A}$ and $\vec{B}$ and the parameter's range, instead of indicating $\vec{A}$ and $\vec{B}$ you can also indicate the range of $t$ itself, getting the same result (7)

>	(Int = int)(F, r_, path = C, parameter = {t = 0..1});

(12)

When the parameter's range is passed, you can also use a shortcut notation, passing the second argument as an equation r_ = C, making more explicit that r_ is the vector representation of region of integration, so the line element $d \vec{r}$ is the differential of the parametric equations of C. In this case indicating path = C is redundant and can be omitted.

>	(Int = int)(F, r_ = C, parameter = {t = 0..1});

(13)

The integration path and the limits of integration can be expressed in vector notation as well

>	C_ := x_i + x^2_j;

$\vec{C} ≔ x^{2} \overset{\land}{j} + x \overset{\land}{i}$

(14)

A_ := 0;

$\vec{A} ≔ 0$

(15)

>	B_ := _i + _j;

$\vec{B} ≔ \overset{\land}{i} + \overset{\land}{j}$

(16)

>	(Int = int)(F, r_ = A_ .. B_, path = C_);

(17)

The following $C$ represents a circle of radius $a$ on the $(x, y)$ plane

>	C := {x^2 + y^2 = a^2, z = 0};

$C ≔ \{z = 0, x^{2} + y^{2} = a^{2}\}$

(18)

To perform a path integral over this curve, the curve is first parametrized as

>	ParametrizeCurve(C);

$[x (φ) = a \cos (φ), y (φ) = a \sin (φ), z (φ) = 0], φ$

(19)

Checking the form of the parametrization returned is useful when using the parameter = a..b option to understand what the values of a and b need to be. From the above we see that for $φ = 0 .. \frac{π}{2}$ , the limits of integration $\vec{A}$ and $\vec{B}$ are

>	eval((19)[1], phi = 0);

$[x (0) = a, y (0) = 0, z (0) = 0]$

(20)

>	A_ := a*_i;

$\vec{A} ≔ a \overset{\land}{i}$

(21)

>	eval((19)[1], phi = Pi/2);

$[x (\frac{π}{2}) = 0, y (\frac{π}{2}) = a, z (\frac{π}{2}) = 0]$

(22)

>	B_ := a*_j;

$\vec{B} ≔ a \overset{\land}{j}$

(23)

So for the following integrand, we have (in the context of int, the keywords curve and path are synonyms)

F := 1;

$F ≔ 1$

(24)

>	(Int = int)(F, r_ = A_ .. B_, curve = C);

(25)

An example having for integrand a vector function $\vec{F}$ , also expressing the path using vector notation

>	F_ := x^2_i + y_j + xyz*_k;

$\vec{F} ≔ x y z \overset{\land}{k} + x^{2} \overset{\land}{i} + y \overset{\land}{j}$

(26)

>	C_ := x*(_i + _j + _k);

$\vec{C} ≔ x (\overset{\land}{i} + \overset{\land}{j} + \overset{\land}{k})$

(27)

Integrate over this curve from the origin to the point $\overset{\land}{i} + \overset{\land}{j} + \overset{\land}{k}$ . To represent a point whose three coordinates are equal, you can use a list with three equal values or, as a shortcut notation, use the single value of the three coordinates. So instead of $[0, 0, 0]$ you can use $0$ and instead of $[1, 1, 1]$ you can use 1

>	A_, B_ := 0, 1;

$\vec{A}, \vec{B} ≔ 0, 1$

(28)

When the integrand is a vector function, int computes the integral of the dot product $\vec{F} \cdot d \vec{r}$ over the given curve, resulting in a scalar value

>	(Int = int)(F_, r_ = A_ .. B_, path = C_);

(29)

To compute the integral of the cross product $\vec{F} \times d \vec{r}$ use the option kind = crossproduct. In this example, we can see that the value of the parameter $t$ for which the points $\vec{A}$ and $\vec{B}$ satisfy the parametric equations are $t = 0$ and $t = 1$ . Knowing those values allows for passing this information directly and omit the integration limits $\vec{A}$ and $\vec{B}$

>	(Int = int)(F_, r_, path = C_, kind = crossproduct, parameters = {t = 0..1});

(30)

The case of a straight line that passes through two given points is special: in addition to handling any mathematical formulation of a line, ParametrizeCurve can also compute the parametric equations directly from the coordinates of those two points. For example

>	P__1 := 2_i - 3_j + 4*_k;

$P__1 ≔ 2 \overset{\land}{i} - 3 \overset{\land}{j} + 4 \overset{\land}{k}$

(31)

>	P__2 := -4_i + 2_j - _k;

$P__2 ≔ - 4 \overset{\land}{i} + 2 \overset{\land}{j} - \overset{\land}{k}$

(32)

we have (in the computational context of ParametrizeCurve, line and straightline are synonyms)

>	ParametrizeCurve(line(P__1, P__2));

$[x (t) = 2 - 6 t, y (t) = - 3 + 5 t, z (t) = - 5 t + 4], t$

(33)

Likewise, int can compute path integrals over a straight line that passes through two points in the same way. Take for instance as integration limits the points that satisfy this line for $t = 5$ and $t = −5$

>	A_ := (16_i)/5 - 4_j + 5*_k;

$\vec{A} ≔ \frac{16 \overset{\land}{i}}{5} - 4 \overset{\land}{j} + 5 \overset{\land}{k}$

(34)

>	B_ := -(44_i)/5 + 6_j - 5*_k;

$\vec{B} ≔ - \frac{44 \overset{\land}{i}}{5} + 6 \overset{\land}{j} - 5 \overset{\land}{k}$

(35)

>	(Int = int)(F_, r_ = A_ .. B_, path = line(P__1, P__2), kind = crossproduct);

(36)

Consider integrating over a path $C$ that consists of three line segments, say $C_{1}, C_{2}, C_{3}$ , connecting the origin with the point $[1, 1, 1]$ via $[0, 0, 0] \to [1, 0, 0] \to [1, 1, 0] \to [1, 1, 1]$ , so first a translation along the $x$ axis only, then one along the $y$ axis, then one along the $z$ axis.

One way of performing this computation is to make three calls to int, passing each of the three different paths $C_{1}, C_{2}, C_{3}$ then add the results. Another way, significantly simpler, is using the $path = linesegments (...)$ . First one path at a time: the vectorial representations of these paths and the three computations are as follows:

>	C__1_ := x*_i;

${\vec{C}}_{1} ≔ x \overset{\land}{i}$

(37)

>	A_, B_ := 0, _i;

$\vec{A}, \vec{B} ≔ 0, \overset{\land}{i}$

(38)

>	(Int = int)(F_, r_ = A_ .. B_, path = C__1_);

(39)

>	C__2_ := _i + y*_j;

${\vec{C}}_{2} ≔ y \overset{\land}{j} + \overset{\land}{i}$

(40)

>	A_, B_ := B_, B_ + _j;

$\vec{A}, \vec{B} ≔ \overset{\land}{i}, \overset{\land}{i} + \overset{\land}{j}$

(41)

>	(Int = int)(F_, r_ = A_ .. B_, path = C__2_);

(42)

>	C__3_ := _i + _j + z*_k;

${\vec{C}}_{3} ≔ z \overset{\land}{k} + \overset{\land}{i} + \overset{\land}{j}$

(43)

>	A_, B_ := B_, B_ + _k;

$\vec{A}, \vec{B} ≔ \overset{\land}{i} + \overset{\land}{j}, \overset{\land}{i} + \overset{\land}{j} + \overset{\land}{k}$

(44)

>	(Int = int)(F_, r_ = A_ .. B_, path = C__3_);

(45)

>	(39) + (42) + (45);

(46)

These three steps can be compacted into one using $path = linesegments (...)$

>	(Int = int)(F_, r_, path = linesegments(0, _i, _i + _j, _i + _j + _k));

(47)

Moreover, note that this integral from 0 to $[1, 1, 1] = \overset{\land}{i} + \overset{\land}{j} + \overset{\land}{k}$ depends on the path of integration. To see that, compute the same integral over the straight line that joins these two points:

>	(Int = int)(F_, r_, path = linesegment(0, _i + _j + _k));

(48)

So $\frac{13}{2}$ instead of $\frac{4}{3}$ . The reason for that: the curl of $\vec{F}$ is not zero

>	(%Curl = Curl)(F_);

$\nabla \times (x y z \overset{\land}{k} + x^{2} \overset{\land}{i} + y \overset{\land}{j}) = x z \overset{\land}{i} - y z \overset{\land}{j}$

(49)

therefore, the path integral from $\vec{A}$ to $\vec{B}$ depends on the path. Note as well that when there are only two points, the $path = linesegment (\vec{A}, \vec{B})$ notation is equivalent to $\vec{r} = \vec{A} .. \vec{B}, path = line (\vec{A}, \vec{B})$ so the integral above can also be expressed as

>	(Int = int)(F_, r_ = 0.. _i + _j + _k, path = line(0, _i + _j + _k));

(50)

Consider the same computation over two different paths in a case where the curl of $\vec{F}$ is equal to zero; take for instance $\vec{F}$ to be equal to the position vector itself

>	F_ := x * _i + y * _j + z * _k;

$\vec{F} ≔ x \overset{\land}{i} + y \overset{\land}{j} + z \overset{\land}{k}$

(51)

>	(%Curl = Curl)(F_);

$\nabla \times (x \overset{\land}{i} + y \overset{\land}{j} + z \overset{\land}{k}) = 0$

(52)

Now the integral does not depend on the path:

>	(Int = int)(F_, r_, path = linesegments(0, _i, _i + _j, _i + _j + _k));

(53)

>	(Int = int)(F_, r_, path = linesegment(0, _i + _j + _k));

(54)

You can indicate that the line integral is around a closed curve in two different ways: passing the initial and final points (integration limits) $\vec{A}$ and $\vec{B}$ such that $\vec{A} = \vec{B}$ , or entirely omitting the integration limits and passing a range for the parameter such that the curve is closed. The following represents a circle on the $(x, y)$ plane

>	C := {x^2 + y^2 = a^2, z = 0};

$C ≔ \{z = 0, x^{2} + y^{2} = a^{2}\}$

(55)

Integrate the vectorial line element $d \vec{r}$ around the whole circle using the two mentioned ways of representing a closed curve. From symmetry considerations, this integral should be equal to 0: we are adding infinitesimal vectorial line elements tangent to the circle around all of it: the contributions of the upper half cancel those of the lower half. Start and finish the integration at the point $[a, 0, 0]$

>	A_ := a*_i;

$\vec{A} ≔ a \overset{\land}{i}$

(56)

>	(Int = int)(1, r_ = A_ .. A_, path = C);

(57)

>	(Int = int)(1, r_, path = C, parameter = {phi = 0..2*Pi});

(58)

These are the contributions of the upper half only

>	(Int = int)(1, r_, path = C, parameter = {phi = 0..Pi});

(59)

Take now $\vec{F} = \vec{r}$ , the position vector, and integrate the cross product $\vec{F} \times d \vec{r}$ around the circle $C$ : this time, at each point of the circle, $\vec{F} \times d \vec{r}$ is perpendicular to the plane $(x, y)$ , in the $\overset{\land}{k}$ direction, so there are no cancellations, everything adds. Here again start and finish the integration at the point $[a, 0, 0]$

>	F_ := x * _i + y * _j + z * _k;

$\vec{F} ≔ x \overset{\land}{i} + y \overset{\land}{j} + z \overset{\land}{k}$

(60)

>	(Int = int)(F_, r_ = A_ .. A_, path = C, kind = crossproduct);

(61)

>	(Int = int)(F_, r_, path = C, parameter = {phi = 0..2*Pi}, kind = crossproduct);

(62)

Surface and Volume integrals

The case of surface and volume integrals is analogous to that of line (path) integrals, but for two things: instead of one, there are two or three parameters, and instead of indicating integration limits, it is required that you indicate the parameter's ranges.

The following $C$ represents the surface of a sphere of radius $a$ centered at the origin

>	with(Physics, Assume, CompactDisplay);

$[Assume, CompactDisplay]$

(63)

>	Assume(a > 0);

$\{a :: (0, \infty)\}$

(64)

>	C__2 := x^2 + y^2 + z^2 = a^2;

$C__2 ≔ x^{2} + y^{2} + z^{2} = a^{2}$

(65)

>	ParametrizeSurface(C__2);

$[x (θ, φ) = a \sin (θ) \cos (φ), y (θ, φ) = a \sin (θ) \sin (φ), z (θ, φ) = a \cos (θ)], [θ, φ]$

(66)

From the definition of the vectorial surface element as

$d \vec{S} = {\vec{r}}_{u} \times {\vec{r}}_{v} du dv$

$d \vec{S}$ is a vector perpendicular to the surface of the sphere. Hence, the vectorial surface integral of $d \vec{S}$ over the upper half of the sphere should be a vector perpendicular to the plane $(x, y)$ in the $\overset{\land}{k}$ direction. Also, checking the form of the parametrization returned by ParametrizeSurface is useful to understand what the ranges for parameters $θ$ and $φ$ need to be to represent the desired region.

>	(Int = int)(1, S_, surface = C__2, parameters = [theta = 0..Pi/2, phi = 0..2*Pi]);

(67)

From symmetry considerations, the integral of $d \vec{S}$ over the lower half of the sphere should have the same magnitude but opposite direction ( $- \overset{\land}{k}$ ), from where the integral over the whole sphere, so for $θ = 0 .. π$ , should be equal to 0

>	(Int = int)(1, S_, surface = C__2, parameters = [theta = 0..Pi, phi = 0..2*Pi]);

(68)

From this example we see that to get the area computing the integral of $d \vec{S}$ over the whole surface it is necessary to take as integrand the modulus of $d \vec{S}$ , that is its scalar product with a unit vector parallel to it. By definition of surface element (see the Description) that unit vector is given by

>	CompactDisplay(r_(theta, phi));

$\vec{r} (θ, φ) will now be displayed as \vec{r}$

(69)

>	n_ := diff(r_(theta, phi), theta) &x diff(r_(theta, phi), phi)/Norm(diff(r_(theta, phi), theta) &x diff(r_(theta, phi), phi));

$\vec{n} ≔ \frac{{\vec{r}}_{θ} \times {\vec{r}}_{φ}}{‖{\vec{r}}_{θ} \times {\vec{r}}_{φ}‖}$

(70)

where $\vec{r}$ is the vectorial form of the parametric equations of the surface. It is easy to see this vector is the radial unit vector $\overset{\land}{r}$ . For that purpose you can use the option output = vector of ParametrizeSurface to get the vectorial form of the parametric equations for $C_{2}$

>	ParametrizeSurface(C__2, output = vector);

$a \sin (θ) \cos (φ) \overset{\land}{i} + a \sin (θ) \sin (φ) \overset{\land}{j} + a \cos (θ) \overset{\land}{k}, [θ, φ]$

(71)

Introduce this value of $\vec{r}$ into the expression for $\vec{n}$ and change basis to spherical

>	n_ := eval(n_, r_(theta, phi) = (71)[1]);

$\vec{n} ≔ \frac{2 (a^{2} {\sin (θ)}^{2} \cos (φ) \overset{\land}{i} + a^{2} {\sin (θ)}^{2} \sin (φ) \overset{\land}{j} + \frac{\sin (2 θ) a^{2} \overset{\land}{k}}{2})}{\sqrt{4 a^{4} {\sin (θ)}^{4} {\cos (φ)}^{2} + 4 a^{4} {\sin (θ)}^{4} {\sin (φ)}^{2} + a^{4} {\sin (2 θ)}^{2}}}$

(72)

>	n_ := ChangeBasis(n_, spherical);

$\vec{n} ≔ \overset{\land}{r}$

(73)

Putting all together, the area of a sphere of radius $a$ is given by this closed surface integral

>	(Int = int)(n_, S_, surface = C__2, parameters = [theta = 0..Pi, phi = 0..2*Pi]);

(74)

You can also use a shortcut notation for surface integrals passing the second argument as an equation S_ = C, making more explicit that S_ is the vector representation of the surface. In this case indicating surface = C is redundant and can be omitted.

>	(Int = int)(n_, S_ = C__2, parameters = [theta = 0..Pi, phi = 0..2*Pi]);

(75)

In the case of the volume of a sphere, an algebraic representation of the region is

>	C__3 := x^2 + y^2 + z^2 = r^2;

$C__3 ≔ x^{2} + y^{2} + z^{2} = r^{2}$

(76)

from where the volume of a sphere of radius $a$ is equal to the integral of the corresponding $dV = {\vec{r}}_{u} \cdot ({\vec{r}}_{v} \times {\vec{r}}_{w}) du dv dw$ with parameters $r = 0 .. a$ , $θ = 0 .. π$ and $φ = 0 .. 2 π$

>	(Int = int)(1, V, volume = C__3, parameters = [r = 0..a, theta=0..Pi, phi = 0..2*Pi]);

(77)

Using ParametrizeVolume one can also see that the vectorial representation of this region is just the position vector $\vec{r}$ written in spherical coordinates and basis

>	ParametrizeVolume(C__3, basis = spherical, output = vector);

$r \overset{\land}{r}, [r, θ, φ]$

(78)

so one can use this simpler vectorial representation of the sphere as well

>	(Int = int)(1, V, volume = r_r, parameters = [r = 0..a, theta=0..Pi, phi = 0..2Pi]);

(79)

You can also use a shortcut notation for volume integrals passing the second argument as an equation V = C, making more explicit that V is the specified volume of integration C. In this case indicating volume = C is redundant and can be omitted.

>	(Int = int)(1, V = r_r, parameters = [r = 0..a, theta=0..Pi, phi = 0..2Pi]);

(80)

	See Also
	ChangeBasis, ChangeCoordinates, convert,VectorCalculus, Identify, int, notation, operations, ParametrizeCurve, ParametrizeSurface, ParametrizeVolume, Physics, Physics conventions, Physics examples, Physics Updates, Tensors - a complete guide, Mini-Course Computer Algebra for Physicists, Physics[Vectors], Setup, standard int, VectorCalculus:-int

Compatibility

•	The Physics[Vectors][int] command was introduced in Maple 2022.

•	For more information on Maple 2022 changes, see Updates in Maple 2022.

Download Help Document

Maple

Maple Add-Ons

MapleSim

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim

Maple

Powerful math software that is easy to use

Maple Add-Ons

MapleSim

Advanced System Level Modeling

MapleSim Add-Ons

Systems Engineering

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim