New objects representing dates, times, and clocks were introduced in Maple 2018.

The Now method for a clock creates a Time object representing the current time according to the indicated clock.  (For more information about other available clock objects, see Clock.)

now := Now( SystemUTCClock );

$\mathrm{now}≔\mathrm{<Time:\; 1970-01-01T00:00:00\; +\; 1519826460130\; ms>}$

From a given Time object, you can create a corresponding Date object, as follows.

today := Date( now );

$\mathrm{today}≔\mathrm{<Date:\; 2018-02-28T14:01:0.130\; UTC>}$

Or, more simply, use the Date constructor without arguments.

today := Date();

$\mathrm{today}≔\mathrm{<Date:\; 2018-02-28T14:01:0.693\; UTC>}$

Various fields of the Date object are accessible.

Year( today );

$2018$

DayOfMonth( today );

$28$

Minute( today );

$1$

Arithmetic with Date and Time objects is builtin.

To compute the amount of time between two dates represented as Date objects, just subtract them.

d1 := Date( 2017, 12, 25 );

$\mathrm{d1}≔\mathrm{<Date:\; 2017-12-25T12:00:00\; Canada/Eastern>}$

d2 := Date( 2000, 12, 25 );

$\mathrm{d2}≔\mathrm{<Date:\; 2000-12-25T12:00:00\; Canada/Eastern>}$

t := d1 - d2;

$t≔536457600000⟦\mathrm{ms}⟧$

convert( t, 'units', 'days' );

$6209⟦d⟧$

(For more control over the units used in computing the time between two dates, use the DateDifference command in the Calendar package).

In fact, any affine combination of Date objects results in an expression involving units of time.

A convex combination of Date objects results in another Date object.  For instance, to compute the average value of two Date objects, you can use an expression such as the following one.

( d1 + d2 ) / 2;

$\mathrm{<Date:\; 2009-06-26T01:00:00\; Canada/Eastern>}$

You can specify a date in a particular time zone by using the timezone option to the Date constructor. Suppose, for example, that a flight leaves Toronto at $8$ p.m. on March 12, 2007, and arrives in Paris at $9$ a.m. on March 13.

depart := Date( 2007, 3, 12, 20, 44, 'timezone' = "America/Toronto" );

$\mathrm{depart}≔\mathrm{<Date:\; 2007-03-12T20:44:00\; America/Toronto>}$

arrive := Date( 2007, 3, 13, 9, 3, 'timezone' = "Europe/Paris" );

$\mathrm{arrive}≔\mathrm{<Date:\; 2007-03-13T09:03:00\; Europe/Paris>}$

To compute the flight time, simply subtract the two dates.

flight_time := arrive - depart;

$\mathrm{flight\_time}≔26340000⟦\mathrm{ms}⟧$

convert( flight_time, 'units', 'hours' );

$\frac{439}{60}⟦h⟧$

The Calendar package provides a number of useful routines for working with dates.

with( Calendar );

$\left[\mathrm{AdjustDateField}\&comma;\mathrm{DateDifference}\&comma;\mathrm{DayOfWeek}\&comma;\mathrm{DayOfYear}\&comma;\mathrm{DaysInMonth}\&comma;\mathrm{DaysInYear}\&comma;\mathrm{HostTimeZone}\&comma;\mathrm{IsDaylightSavingTime}\&comma;\mathrm{IsLeapYear}\&comma;\mathrm{IsWeekend}\&comma;\mathrm{JulianDayNumber}\&comma;\mathrm{ModifiedJulianDayNumber}\&comma;\mathrm{Today}\right]$

For example, you can check whether a year is a leap year.

IsLeapYear( 2000 );

$\mathrm{true}$

IsLeapYear( 1900 );

$\mathrm{false}$

You can compute the day of the week or year for any given date. For example, Christmas of 2017 occurred on a Monday.

DayOfWeek( 2017, 12, 25 );

$2$

And, it was the $359$-th day of the year.

DayOfYear( 2017, 12, 25 );

$359$

Since Date objects can be specified with respect to particular time zones, it is useful to be able to determine the time zone of computer on which Maple is running.  To do this, use the HostTimeZone command.

HostTimeZone();

$''Canada/Eastern''$

The DateDifference command gives you finer control over the units used to compute the time difference between two dates.  For our flight example above, we can compute as follows.

DateDifference( depart, arrive, 'units' = 'h' );

$\frac{439}{60}⟦h⟧$

It is sometimes more convenient to use "mixed" units in the output, as illustrated here:

DateDifference( depart, arrive, 'units' = 'mixed' );

$7⟦h⟧+19⟦\min ⟧$

The AdjustDateField command provides for the ability to add amounts to individual Date object fields, such as the month or the hour of the day.

d := Date( 2000, 1, 14, 10, 55, 3 );

$d≔\mathrm{<Date:\; 2000-01-14T10:55:03\; Canada/Eastern>}$

AdjustDateField( d, "minute", -3 );

$\mathrm{<Date:\; 2000-01-14T10:52:03\; Eastern\; Standard\; Time>}$

Notice the effect of adding many months to the date here:

AdjustDateField( d, "month", 30 );

$\mathrm{<Date:\; 2002-07-14T10:55:03\; Eastern\; Standard\; Time>}$

By default, changes to a particular date field can potentially lead to changes to date fields at a higher level of granularity.  The method = "roll" option confines modifications to a single field, keeping its values within the valid ranges for that field.

AdjustDateField( d, "month", 30, 'method' = "roll" );

$\mathrm{<Date:\; 2000-07-14T10:55:03\; Eastern\; Standard\; Time>}$

The default behavior is obtained by using the method = "add" option.

AdjustDateField( d, "month", 30, 'method' = "add" );

$\mathrm{<Date:\; 2002-07-14T10:55:03\; Eastern\; Standard\; Time>}$

For more information on the Calendar package, see the package overview page.