Lie Algebra Cohomology - Maple Help
For the best experience, we recommend viewing online help using Google Chrome or Microsoft Edge.

Online Help

All Products    Maple    MapleSim


DifferentialGeometry Tutorials

 

Relative Lie Algebra Cohomology and the de Rham cohomology of Homogeneous Spaces.

 

 

 Overview

 Procedures Illustrated

 Example 1. The 3 sphere as SO(4)/SO(3)

 Example 2.  The 4 sphere as SO(5)/SO(4)

 Example 3.  The 5 sphere as SU(3)/SU(2)

 Example 4.  The 7 sphere as Sp(2)/Sp(1)

 Example 5.  The 6 sphere as G2/SU(3)

 Example 6.  The 7 sphere as Spin(7)/G2

 Example 7.  Complex projective space CP^4 as SU(3)/U(2)

 Example 8.  The oriented Grassmannian of 3 planes in R^6 as SO(6)/(SO(3) x SO(3))

 Overview

Let G be a compact Lie group and H a closed subgroup. Then the relative Lie algebra cohomology H^*(g, h) computes the de Rham cohomology of the homogeneous space G/H.

 

In this tutorial we shall use this result to calculate the de Rham cohomology of some classical homogeneous spaces. For each example we shall check to see if the homogeneous space under consideration is reductive or symmetric.

 Procedures Illustrated

 

In this tutorial we shall make use of the following packages and commands:

DifferentialGeometry, LieAlgebras, Tensor, DGsetup, MatrixAlgebras, CanonicalTensors, Cohomology, IntersectSubspaces, LieAlgebraData, RelativeChains 

 

We follow the method described in the help page MatrixAlgebras, the LieAlgebra Lesson on Matrix Algebras, and the Tutorials entitled Classical Matrix Algebras for constructing the Lie algebras we need in this tutorial.

 Example 1. The 3 sphere as SO(4)/SO(3)

 

In this example we construct the Lie algebra pair (g, h) = (so(4), so(3)) . The relative Lie algebra cohomology is computed and gives the cohomology of the 3 sphere. We show that (so(4), so(3)) is a symmetric pair.

 

> 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 4 dimensional space (on which gl(4) will act) and a metric tensor g and a vector V on E4.  We construct so4 as the subalgebra of gl4 which fixes g and

so3 as the subalgebra of gl4 which fixes both g and V.

> 

DGsetup([x1, x2, x3, x4], E4):

E4 > 

g := CanonicalTensors("Metric", "bas",4,0);

g≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3+dx4⁢dx4

(3.1)
E4 > 

V := D_x4;

V≔D_x4

(3.2)

 

Define and initialize the general linear Lie algebra gl4.

E4 > 

gl4 := MatrixAlgebras("Full",4, gl4R):

E4 > 

DGsetup(gl4):

 

Calculate so4 and so3 as subalgebras of gl4.

gl4R > 

so4_subalg := MatrixAlgebras("Subalgebra", gl4R,[g]);

so4_subalg≔e12−e21,e13−e31,e14−e41,e23−e32,e24−e42,e34−e43

(3.3)
gl4R > 

so3_subalg := MatrixAlgebras("Subalgebra",gl4R,[g,V]);

so3_subalg≔e12−e21,e13−e31,e23−e32

(3.4)

 

Calculate the structure equations for so4 and find the component expressions for the vectors in so3 in terms of the vectors in so4.

gl4R > 

g, h0 := LieAlgebraData(so4_subalg,[so3_subalg],so4);

g,h0≔e1,e2=−e4,e1,e3=−e5,e1,e4=e2,e1,e5=e3,e2,e3=−e6,e2,e4=−e1,e2,e6=e3,e3,e5=−e1,e3,e6=−e2,e4,e5=−e6,e4,e6=e5,e5,e6=−e4,1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,1,0,0

(3.5)
gl4R > 

DGsetup(g);

Lie algebra: so4

(3.6)

 

Find so3 as a subalgebra of so4.

so4 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6

(3.7)
so4 > 

so3 := map(DGzip,h0[1], Fr, "plus");

so3≔e1,e2,e4

(3.8)

 

Calculate the forms omega on so4 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in so3.  These are the so3 relative chains.

so4 > 

C := RelativeChains(so3);

C≔,,,−θ3⁢⋀⁢θ5⁢⋀⁢θ6,

(3.9)

 

Calculate the Lie algebra cohomology of so4 relative to so3.

so4 > 

H := Cohomology(C);

H≔,,−θ3⁢⋀⁢θ5⁢⋀⁢θ6

(3.10)

 

Show that so4 = m + so3 is a symmetric decomposition.

so4 > 

m := [e3,e5,e6]:

so4 > 

Query(so3, m, "SymmetricPair");

true

(3.11)

 

 Example 2.  The 4 sphere as SO(5)/SO(4)

 

This example is just a higher dimensional version of Example 1.  We construct the Lie algebra pair (g, h) = (so(5), so(4)) . The relative Lie algebra cohomology is computed and gives the cohomology of the 4 sphere. We show that (so(5), so(4)) is a symmetric pair.

 

so4 > 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 5 dimensional space (on which gl(5) will act) and a metric tensor g and a vector V on E5.  We construct so5 as the subalgebra of gl4 which fixes g and

so3 as the subalgebra of gl5 which fixes both g and V.

 

so4 > 

DGsetup([x1, x2, x3, x4, x5], E5):

E5 > 

g := CanonicalTensors("Metric", "bas", 5,0);

g≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3+dx4⁢dx4+dx5⁢dx5

(4.1)
E5 > 

V := D_x5;

V≔D_x5

(4.2)

 

Define and initialize the general linear Lie algebra gl5.

E5 > 

gl5 := MatrixAlgebras("Full", 5):

E5 > 

DGsetup(gl5):

 

Calculate so5 and so4 as subalgebras of gl5.

gl5R > 

so5_subalg := MatrixAlgebras("Subalgebra", gl5R,[g]);

so5_subalg≔e12−e21,e13−e31,e14−e41,e15−e51,e23−e32,e24−e42,e25−e52,e34−e43,e35−e53,e45−e54

(4.3)
gl5R > 

so4_subalg := MatrixAlgebras("Subalgebra",gl5R,[g,V]);

so4_subalg≔e12−e21,e13−e31,e14−e41,e23−e32,e24−e42,e34−e43

(4.4)

 

Calculate the structure equations for so5 and find the component expressions for the vectors in so4 in terms of the vectors in so5.

gl5R > 

g, h0 := LieAlgebraData(so5_subalg,[so4_subalg],so5);

g,h0≔e1,e2=−e5,e1,e3=−e6,e1,e4=−e7,e1,e5=e2,e1,e6=e3,e1,e7=e4,e2,e3=−e8,e2,e4=−e9,e2,e5=−e1,e2,e8=e3,e2,e9=e4,e3,e4=−e10,e3,e6=−e1,e3,e8=−e2,e3,e10=e4,e4,e7=−e1,e4,e9=−e2,e4,e10=−e3,e5,e6=−e8,e5,e7=−e9,e5,e8=e6,e5,e9=e7,e6,e7=−e10,e6,e8=−e5,e6,e10=e7,e7,e9=−e5,e7,e10=−e6,e8,e9=−e10,e8,e10=e9,e9,e10=−e8,1,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,1,0,0

(4.5)
gl5R > 

DGsetup(g);

Lie algebra: so5

(4.6)
so5 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10

(4.7)
so5 > 

so4 := map(DGzip,h0[1], Fr, "plus");

so4≔e1,e2,e3,e5,e6,e8

(4.8)

 

Calculate the forms omega on so5 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in so4.  These are the so4 relative chains.

so5 > 

C := RelativeChains(so4);

C≔,,,,θ4⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10,

(4.9)

 

Calculate the Lie algebra cohomology of so5 relative to so4.

so5 > 

H := Cohomology(C);

H≔,,,θ4⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10

(4.10)

 

Show that so5 = m + so4 is a symmetric decomposition.

so5 > 

M := [e4,e7,e9, e10]:

so5 > 

Query(so4, M, "SymmetricPair");

true

(4.11)

 

 Example 3.  The 5 sphere as SU(3)/SU(2)

 

The same manifold often admits different transitive group actions leading to different realizations as homogeneous spaces. Here is a realization of the 5 sphere as the homogeneous space Su(3)/Su(2) which is different from the more familiar realization as SO(6)/SO(5).  We construct the Lie algebra pair (g, h) = (su(3), su(2)) . The relative Lie algebra cohomology is computed and gives the cohomology of the 5 sphere. We show that (su(3), su(2)) is a reductive pair but not symmetric.

 

so5 > 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 6 dimensional space (on which gl(6) will act). On E6 define a metric tensor g, a complex structure J, a pair of 3 forms nuR and nuI and a vector V.  We construct su3 as the subalgebra of gl6 which fixes g, J, nuI, and nuR and su2 as the subalgebra of gl6 which also fixes V.

so5 > 

DGsetup([x1, x2, x3, y1, y2, y3], E6);

frame name: E6

(5.1)
E6 > 

g := CanonicalTensors("Metric", "bas", 6, 0);

g≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3+dy1⁢dy1+dy2⁢dy2+dy3⁢dy3

(5.2)
E6 > 

J := CanonicalTensors("ComplexStructure","bas");

J≔−dx1⁢D_y1−dx2⁢D_y2−dx3⁢D_y3+dy1⁢D_x1+dy2⁢D_x2+dy3⁢D_x3

(5.3)
E6 > 

dz1 := DGzip([1,I],[dx1,dy1], "plus"):
dz2 := DGzip([1,I],[dx2,dy2], "plus"):
dz3 := DGzip([1,I],[dx3,dy3], "plus"):
nu  :=dz1&wedge dz2 &wedge dz3:

E6 > 

nuR := (1/2) &mult (nu &plus Tools:-DGmap(1, conjugate, nu));

nuR≔dx1⁢⋀⁢dx2⁢⋀⁢dx3−dx1⁢⋀⁢dy2⁢⋀⁢dy3+dx2⁢⋀⁢dy1⁢⋀⁢dy3−dx3⁢⋀⁢dy1⁢⋀⁢dy2

(5.4)
E6 > 

nuI := (I/2) &mult (nu &minus Tools:-DGmap(1, conjugate, nu));

nuI≔−dx1⁢⋀⁢dx2⁢⋀⁢dy3+dx1⁢⋀⁢dx3⁢⋀⁢dy2−dx2⁢⋀⁢dx3⁢⋀⁢dy1+dy1⁢⋀⁢dy2⁢⋀⁢dy3

(5.5)
E6 > 

V := D_y3;

V≔D_y3

(5.6)

 

Define and initialize the general linear Lie algebra gl6.

E6 > 

DGsetup(MatrixAlgebras("Full",6)):

gl6R > 

su3_subalg := MatrixAlgebras("Subalgebra", gl6R, [g, J, nuI, nuR]);

su3_subalg≔e12−e21+e45−e54,e13−e31+e46−e64,e14−e36−e41+e63,e15+e24−e42−e51,e16+e34−e43−e61,e23−e32+e56−e65,e25−e36−e52+e63,e26+e35−e53−e62

(5.7)

 

Calculate su(3) and su(2) as subalgebras of gl6.

gl6R > 

su2_subalg := MatrixAlgebras("Subalgebra", gl6R, [g,J,nuI,nuR,V]):

gl6R > 

g, h0 := LieAlgebraData(su3_subalg,[su2_subalg], su3):

 

Calculate the structure equations for su3 and express the component expressions for the vectors in su2 in terms of the vectors in su3.

gl6R > 

DGsetup(g);

Lie algebra: su3

(5.8)

 

su3 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8

(5.9)
su3 > 

su2 := map(DGzip,h0[1], Fr, "plus");

su2≔e1,e3−e7,e4

(5.10)

 

Calculate the forms omega on su3 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in su2.  These are the su2 relative chains.

su3 > 

C := RelativeChains(su2);

C≔,θ3+θ7,−θ2⁢⋀⁢θ5−θ6⁢⋀⁢θ8,−θ2⁢⋀⁢θ6+θ5⁢⋀⁢θ8,−θ2⁢⋀⁢θ8−θ5⁢⋀⁢θ6,−θ2⁢⋀⁢θ3⁢⋀⁢θ5+θ2⁢⋀⁢θ5⁢⋀⁢θ7+θ3⁢⋀⁢θ6⁢⋀⁢θ8−θ6⁢⋀⁢θ7⁢⋀⁢θ8,−θ2⁢⋀⁢θ3⁢⋀⁢θ6+θ2⁢⋀⁢θ6⁢⋀⁢θ7−θ3⁢⋀⁢θ5⁢⋀⁢θ8+θ5⁢⋀⁢θ7⁢⋀⁢θ8,θ2⁢⋀⁢θ3⁢⋀⁢θ8+θ2⁢⋀⁢θ7⁢⋀⁢θ8−θ3⁢⋀⁢θ5⁢⋀⁢θ6−θ5⁢⋀⁢θ6⁢⋀⁢θ7,θ2⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ8,θ2⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ8+θ2⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ7⁢⋀⁢θ8,

(5.11)

 

Calculate the Lie algebra cohomology of su3 relative to su2.

su3 > 

H := Cohomology(C);

H≔,,,,θ2⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ8+θ2⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ7⁢⋀⁢θ8

(5.12)

 

We calculate the general complement to su2 in su3 and use the Query program to find all possible reductive complements.

su3 > 

m0 := ComplementaryBasis(su2,Fr,a);

m0≔a1⁢e1+e2+a2⁢e3+a3⁢e4−a2⁢e7,a4⁢e1+a5+1⁢e3+a6⁢e4−a5⁢e7,a7⁢e1+a8⁢e3+a9⁢e4+e5−a8⁢e7,a10⁢e1+a11⁢e3+a12⁢e4+e6−a11⁢e7,a13⁢e1+a14⁢e3+a15⁢e4−a14⁢e7+e8,a1,a10,a11,a12,a13,a14,a15,a2,a3,a4,a5,a6,a7,a8,a9

(5.13)
su3 > 

TF, Eq, Soln, ReductivePairs:= Query(su2,m0,"ReductivePair");

TF,Eq,Soln,ReductivePairs≔true,0,a1,a11,a14,a15,a2,a7,a8,a9,−a10,−a11,−a12,−a13,−a14,−a2,−a3,−2⁢a4,2⁢a4,−2⁢a6,2⁢a6,−a8,−a1−2⁢a14,−a1+2⁢a9,−a10−2⁢a8,a10+2⁢a15,−a11−2⁢a3,−a11+2⁢a7,a11+2⁢a3,a11−2⁢a7,−a12+2⁢a2,a12−2⁢a13,−a13+2⁢a12,a13−2⁢a2,−a14−2⁢a1,−a14−2⁢a9,a14+2⁢a1,a14+2⁢a9,−a15−2⁢a10,−a15+2⁢a8,−a2+2⁢a12,−a2+2⁢a13,a2−2⁢a12,a2−2⁢a13,−a3−2⁢a7,a3+2⁢a11,−2⁢a5−1,2⁢a5+1,a7−2⁢a11,a7+2⁢a3,−a8−2⁢a10,−a8+2⁢a15,a8+2⁢a10,a8−2⁢a15,a9−2⁢a1,a9+2⁢a14,a1=0,a10=0,a11=0,a12=0,a13=0,a14=0,a15=0,a2=0,a3=0,a4=0,a5=−12,a6=0,a7=0,a8=0,a9=0,e1,e3−e7,e4,e2,e32+e72,e5,e6,e8

(5.14)

 

Interestingly, there is a unique reductive complement but this does not make (su(3), su(2)) symmetric.

su3 > 

M_reductive[4];

M_reductive4

(5.15)
su3 > 

ReductivePairs[1];

e1,e3−e7,e4,e2,e32+e72,e5,e6,e8

(5.16)
su3 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

false

(5.17)

 Example 4.  The 7 sphere as Sp(2)/Sp(1)

 

In addition to being a SO(8) and SU(4) homogeneous space, the 7 sphere is also admits a transitive action of the symplectic group Sp(2). We construct the Lie algebra pair (g, h) = (sp(2), sp(1)) . The relative Lie algebra cohomology is computed and gives the cohomology of the 7 sphere. We show that (sp(2), su(1)) is a reductive pair but not symmetric.

 

su3 > 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define an 8 dimensional space (on which gl(8) will act). On E8 define a metric tensor g, a pair of complex structures J and K, and a vector V.  We construct sp2 as the subalgebra of gl7 which fixes g, J, and K and sp1 as the subalgebra of gl8 which also fixes V.

 

su3 > 

DGsetup([x1, y1, u1, v1, x2, y2, u2, v2], E8):

E8 > 

J := CanonicalTensors("ComplexStructure", "bas");

J≔−dx1⁢D_x2−dy1⁢D_y2−du1⁢D_u2−dv1⁢D_v2+dx2⁢D_x1+dy2⁢D_y1+du2⁢D_u1+dv2⁢D_v1

(6.1)
E8 > 

K1 := evalDG( -dx1 &t D_u1 - dy1 &t D_v1 + du1 &t D_x1 + dv1 &t D_y1):

E8 > 

K2:= evalDG( -dx2 &t D_u2 - dy2 &t D_v2 + du2 &t D_x2 + dv2 &t D_y2):

E8 > 

K:= K1 &minus K2;

K≔−dx1⁢D_u1−dy1⁢D_v1+du1⁢D_x1+dv1⁢D_y1+dx2⁢D_u2+dy2⁢D_v2−du2⁢D_x2−dv2⁢D_y2

(6.2)
E8 > 

g := CanonicalTensors("Metric", "bas", 8,0);

g≔dx1⁢dx1+dy1⁢dy1+du1⁢du1+dv1⁢dv1+dx2⁢dx2+dy2⁢dy2+du2⁢du2+dv2⁢dv2

(6.3)
E8 > 

V := D_v2:

 

Define and initialize the general linear Lie algebra gl8.

E8 > 

DGsetup(MatrixAlgebras("Full", 8, gl8R)):

 

Calculate sp2 and sp1 as subalgebras of gl8.

gl8R > 

sp2_subalg := MatrixAlgebras("Subalgebra", gl8R, [J, K, g]);

sp2_subalg≔e12−e21+e34−e43+e56−e65+e78−e87,e13−e31+e57−e75,e14+e23−e32−e41+e58+e67−e76−e85,e15−e37−e51+e73,e16+e25−e38−e47−e52−e61+e74+e83,e17+e35−e53−e71,e18+e27+e36+e45−e54−e63−e72−e81,e24−e42+e68−e86,e26−e48−e62+e84,e28+e46−e64−e82

(6.4)
gl8R > 

sp1_subalg := MatrixAlgebras("Subalgebra", gl8R, [J, K, g, V]);

sp1_subalg≔e13−e31+e57−e75,e15−e37−e51+e73,e17+e35−e53−e71

(6.5)

 

Calculate the structure equations for sp2 and express the component expressions for the vectors in sp1 in terms of the vectors in sp2.

gl8R > 

g, h0:= LieAlgebraData(sp2_subalg,[sp1_subalg],sp2);

g,h0≔e1,e2=−e3,e1,e3=2⁢e2−2⁢e8,e1,e4=−e5,e1,e5=2⁢e4−2⁢e9,e1,e6=−e7,e1,e7=−2⁢e10+2⁢e6,e1,e8=e3,e1,e9=e5,e1,e10=e7,e2,e3=−e1,e2,e4=−2⁢e6,e2,e5=−e7,e2,e6=2⁢e4,e2,e7=e5,e3,e4=−e7,e3,e5=−2⁢e10−2⁢e6,e3,e6=e5,e3,e7=2⁢e4+2⁢e9,e3,e8=−e1,e3,e9=−e7,e3,e10=e5,e4,e5=−e1,e4,e6=−2⁢e2,e4,e7=−e3,e5,e6=−e3,e5,e7=−2⁢e2−2⁢e8,e5,e8=e7,e5,e9=−e1,e5,e10=−e3,e6,e7=−e1,e7,e8=−e5,e7,e9=e3,e7,e10=−e1,e8,e9=−2⁢e10,e8,e10=2⁢e9,e9,e10=−2⁢e8,0,1,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0

(6.6)
gl8R > 

DGsetup(g);

Lie algebra: sp2

(6.7)
sp2 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10

(6.8)
sp2 > 

sp1 := map(DGzip,h0[1], Fr, "plus");

sp1≔e2,e4,e6

(6.9)

 

Calculate the forms omega on sp2 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in sp1.  These are the sp1 relative chains.

sp2 > 

C := RelativeChains(sp1);

C≔,θ8,θ9,θ10,−θ1⁢⋀⁢θ3−θ5⁢⋀⁢θ7,−θ1⁢⋀⁢θ5+θ3⁢⋀⁢θ7,−θ1⁢⋀⁢θ7−θ3⁢⋀⁢θ5,−θ8⁢⋀⁢θ9,−θ8⁢⋀⁢θ10,−θ9⁢⋀⁢θ10,−θ1⁢⋀⁢θ3⁢⋀⁢θ8−θ5⁢⋀⁢θ7⁢⋀⁢θ8,−θ1⁢⋀⁢θ5⁢⋀⁢θ8+θ3⁢⋀⁢θ7⁢⋀⁢θ8,−θ1⁢⋀⁢θ7⁢⋀⁢θ8−θ3⁢⋀⁢θ5⁢⋀⁢θ8,−θ1⁢⋀⁢θ3⁢⋀⁢θ9−θ5⁢⋀⁢θ7⁢⋀⁢θ9,−θ1⁢⋀⁢θ5⁢⋀⁢θ9+θ3⁢⋀⁢θ7⁢⋀⁢θ9,−θ1⁢⋀⁢θ7⁢⋀⁢θ9−θ3⁢⋀⁢θ5⁢⋀⁢θ9,−θ1⁢⋀⁢θ3⁢⋀⁢θ10−θ5⁢⋀⁢θ7⁢⋀⁢θ10,−θ1⁢⋀⁢θ5⁢⋀⁢θ10+θ3⁢⋀⁢θ7⁢⋀⁢θ10,−θ1⁢⋀⁢θ7⁢⋀⁢θ10−θ3⁢⋀⁢θ5⁢⋀⁢θ10,−θ8⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10+θ3⁢⋀⁢θ5⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7,θ1⁢⋀⁢θ3⁢⋀⁢θ8⁢⋀⁢θ9+θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9,θ1⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9−θ3⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9,θ1⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9+θ3⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9,θ1⁢⋀⁢θ3⁢⋀⁢θ8⁢⋀⁢θ10+θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ10,θ1⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ10−θ3⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ10,θ1⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ10+θ3⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ10,θ1⁢⋀⁢θ3⁢⋀⁢θ9⁢⋀⁢θ10+θ5⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ5⁢⋀⁢θ9⁢⋀⁢θ10−θ3⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8,θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ9,θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ10,θ1⁢⋀⁢θ3⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10+θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10−θ3⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10,θ1⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10+θ3⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10,−θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9,−θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ10,−θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ9⁢⋀⁢θ10,−θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10,

(6.10)

 

Calculate the Lie algebra cohomology of sp2 relative to sp1.

sp2 > 

H := Cohomology(C);

H≔,,,,,,−θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10

(6.11)

 

We calculate the general complement to sp1 in sp2 and use the Query program to find all possible reductive complements.

sp2 > 

m0 := ComplementaryBasis(sp1, Fr, a);

m0≔e1+a1⁢e2+a2⁢e4+a3⁢e6,a4⁢e2+e3+a5⁢e4+a6⁢e6,a7⁢e2+a8⁢e4+e5+a9⁢e6,a10⁢e2+a11⁢e4+a12⁢e6+e7,a13⁢e2+a14⁢e4+a15⁢e6+e8,a16⁢e2+a17⁢e4+a18⁢e6+e9,a19⁢e2+a20⁢e4+a21⁢e6+e10,a1,a10,a11,a12,a13,a14,a15,a16,a17,a18,a19,a2,a20,a21,a3,a4,a5,a6,a7,a8,a9

(6.12)
> 

TF, Eq, Soln, ReductivePairs:= Query(sp1, m0, "ReductivePair");

TF,Eq,Soln,ReductivePairs≔true,0,a11,a12,a4,a6,a7,a8,−a1,−a10,−2⁢a13,2⁢a13,−2⁢a14,2⁢a14,−2⁢a15,2⁢a15,−2⁢a16,2⁢a16,−2⁢a17,2⁢a17,−2⁢a18,2⁢a18,−2⁢a19,2⁢a19,−a2,−2⁢a20,2⁢a20,−2⁢a21,2⁢a21,−a3,−a5,−a9,−a1−2⁢a11,−a1+2⁢a9,a10−2⁢a2,a10+2⁢a6,−a11−2⁢a9,a11+2⁢a1,−a12+2⁢a8,a12−2⁢a4,−a2+2⁢a10,−a2−2⁢a6,−a3+2⁢a5,−a3−2⁢a7,−a4+2⁢a12,a4−2⁢a8,a5−2⁢a3,a5+2⁢a7,−a6−2⁢a10,a6+2⁢a2,−a7−2⁢a5,a7+2⁢a3,−a8+2⁢a4,a8−2⁢a12,a9−2⁢a1,a9+2⁢a11,a1=0,a10=0,a11=0,a12=0,a13=0,a14=0,a15=0,a16=0,a17=0,a18=0,a19=0,a2=0,a20=0,a21=0,a3=0,a4=0,a5=0,a6=0,a7=0,a8=0,a9=0,e2,e4,e6,e1,e3,e5,e7,e8,e9,e10

(6.13)
sp2 > 

ReductivePairs[1];

e2,e4,e6,e1,e3,e5,e7,e8,e9,e10

(6.14)

 

There is a unique reductive complement but this does not make (sp2, sp1)) symmetric.

sp2 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

false

(6.15)

 

 Example 5.  The 6 sphere as G2/SU(3)

 

The exceptional  Lie group G2 can be defined as a subgroup of SO(7) and therefore there is a natural action of G2 on the 6 sphere. This action is transitive and the isotropy subalgebra is SU(3). In this section we compute the Lie algebra pair (g2, su3), calculate the Lie algebra cohomology of g2 relative to su3 and check that the pair (g2, su3) is reductive but not symmetric.

> 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 7 dimensional space (on which gl(7) will act). On E7, define a 3 form phi and a vector V.

sp2 > 

DGsetup([x1, x2, x3, x4, x5, x6, x7],E7):

E7 > 

phi := evalDG( dx1 &w dx2 &w dx3  + dx1 &w dx4 &w dx5 -dx1 &w dx6 &w dx7 + dx2 &w dx4 &w dx6+ dx2 &w dx5 &w dx7 +dx3 &w dx4 &w dx7 -dx3 &w dx5 &w dx6);

φ≔dx1⁢⋀⁢dx2⁢⋀⁢dx3+dx1⁢⋀⁢dx4⁢⋀⁢dx5−dx1⁢⋀⁢dx6⁢⋀⁢dx7+dx2⁢⋀⁢dx4⁢⋀⁢dx6+dx2⁢⋀⁢dx5⁢⋀⁢dx7+dx3⁢⋀⁢dx4⁢⋀⁢dx7−dx3⁢⋀⁢dx5⁢⋀⁢dx6

(7.1)
E7 > 

V:= D_x1;

V≔D_x1

(7.2)

 

Define and initialize the general linear Lie algebra gl7.

E7 > 

DGsetup(MatrixAlgebras("Full", 7 , gl7)):

 

Calculate gl7 and su3 as subalgebras of gl7.

gl7 > 

g2_subalg := MatrixAlgebras("Subalgebra", gl7, [phi]);

g2_subalg≔e12−e21+e56−e65,e13−e31+e57−e75,e14−e36−e41+e63,e15−e37−e51+e73,e16+e34−e43−e61,e17+e35−e53−e71,e23−e32+e67−e76,e24+e35−e42−e53,e25−e34+e43−e52,e26−e37−e62+e73,e27+e36−e63−e72,e45−e54+e67−e76,e46−e57−e64+e75,e47+e56−e65−e74

(7.3)
gl7 > 

su3_subalg := MatrixAlgebras("Subalgebra",gl7,[phi,V]):

 

Calculate the structure equations for g2 and find the component expressions for the vectors in su3 in terms of the vectors in g2.

gl7 > 

g, h0 :=  LieAlgebraData(g2_subalg,[su3_subalg],g2);

g,h0≔e1,e2=−e7,e1,e3=−e8,e1,e4=−e5−e9,e1,e5=−e10+e4,e1,e6=−e11,e1,e7=e2,e1,e8=e3,e1,e9=−e10+e4,e1,e10=e5+e9,e1,e11=e6,e1,e12=−e13,e1,e13=e12,e2,e3=−e5,e2,e4=−2⁢e6,e2,e5=e3,e2,e6=2⁢e4,e2,e7=−e1,e2,e8=e4,e2,e9=−e11−e3,e2,e10=−e6,e2,e11=e5+e9,e2,e12=−e14,e2,e14=e12,e3,e4=−e12,e3,e5=−2⁢e13−2⁢e2,e3,e6=−e14,e3,e7=e10,e3,e8=−e1,e3,e9=e13+e2,e3,e10=−e7,e3,e12=e4,e3,e13=e5,e3,e14=e6,e4,e5=−e14,e4,e6=−2⁢e2,e4,e7=e11,e4,e8=−e2,e4,e9=−e1+e14,e4,e11=−e7,e4,e12=−e3,e4,e13=−e6,e4,e14=e5,e5,e6=−e12,e5,e7=e6−e8,e5,e8=−e12+e7,e5,e10=−e1+e14,e5,e11=−e13−e2,e5,e12=e6,e5,e13=−e3,e5,e14=−e4,e6,e7=−e5−e9,e6,e9=−e12+e7,e6,e10=e2,e6,e11=−e1,e6,e12=−e5,e6,e13=e4,e6,e14=−e3,e7,e8=e9,e7,e9=−e8,e7,e10=−2⁢e11,e7,e11=2⁢e10,e7,e13=−e14,e7,e14=e13,e8,e9=−2⁢e12+2⁢e7,e8,e10=−e13,e8,e11=−e14,e8,e12=e9,e8,e13=e10,e8,e14=e11,e9,e10=−e14,e9,e11=e13,e9,e12=−e8,e9,e13=−e11,e9,e14=e10,e10,e11=−2⁢e7,e10,e12=e11,e10,e13=−e8,e10,e14=−e9,e11,e12=−e10,e11,e13=e9,e11,e14=−e8,e12,e13=−2⁢e14,e12,e14=2⁢e13,e13,e14=−2⁢e12,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1

(7.4)
gl7 > 

DGsetup(g);

Lie algebra: g2

(7.5)
g2 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10,e11,e12,e13,e14

(7.6)
g2 > 

su3 := map(DGzip,h0[1], Fr, "plus");

su3≔e7,e8,e9,e10,e11,e12,e13,e14

(7.7)

 

Calculate the forms omega on g2 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in su3.  These are the su3 relative chains.

g2 > 

C := RelativeChains(su3);

C≔,,−θ1⁢⋀⁢θ2−θ3⁢⋀⁢θ4+θ5⁢⋀⁢θ6,−θ1⁢⋀⁢θ3⁢⋀⁢θ5−θ1⁢⋀⁢θ4⁢⋀⁢θ6−θ2⁢⋀⁢θ3⁢⋀⁢θ6+θ2⁢⋀⁢θ4⁢⋀⁢θ5,θ1⁢⋀⁢θ3⁢⋀⁢θ6−θ1⁢⋀⁢θ4⁢⋀⁢θ5−θ2⁢⋀⁢θ3⁢⋀⁢θ5−θ2⁢⋀⁢θ4⁢⋀⁢θ6,θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4−θ1⁢⋀⁢θ2⁢⋀⁢θ5⁢⋀⁢θ6−θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6,,−θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6,

(7.8)

 

Calculate the Lie algebra cohomology of g2 relative to su3.

g2 > 

H := Cohomology(C);

H≔,,,,,−θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6

(7.9)

 

We calculate the general complement to su3 in g2 and use the Query program to find all possible reductive complements.

g2 > 

m0 := ComplementaryBasis(su3,Fr,a);

m0≔e1+a1⁢e7+a2⁢e8+a3⁢e9+a4⁢e10+a5⁢e11+a6⁢e12+a7⁢e13+a8⁢e14,e2+a9⁢e7+a10⁢e8+a11⁢e9+a12⁢e10+a13⁢e11+a14⁢e12+a15⁢e13+a16⁢e14,e3+a17⁢e7+a18⁢e8+a19⁢e9+a20⁢e10+a21⁢e11+a22⁢e12+a23⁢e13+a24⁢e14,e4+a25⁢e7+a26⁢e8+a27⁢e9+a28⁢e10+a29⁢e11+a30⁢e12+a31⁢e13+a32⁢e14,e5+a33⁢e7+a34⁢e8+a35⁢e9+a36⁢e10+a37⁢e11+a38⁢e12+a39⁢e13+a40⁢e14,e6+a41⁢e7+a42⁢e8+a43⁢e9+a44⁢e10+a45⁢e11+a46⁢e12+a47⁢e13+a48⁢e14,a1,a10,a11,a12,a13,a14,a15,a16,a17,a18,a19,a2,a20,a21,a22,a23,a24,a25,a26,a27,a28,a29,a3,a30,a31,a32,a33,a34,a35,a36,a37,a38,a39,a4,a40,a41,a42,a43,a44,a45,a46,a47,a48,a5,a6,a7,a8,a9

(7.10)
g2 > 

TF, Eq, Soln, ReductivePairs:= Query(su3,m0,"ReductivePair"):

g2 > 

ReductivePairs;

e7,e8,e9,e10,e11,e12,e13,e14,e1−e142,e2+e132,e3+e112,e4−e102,e5+e92,e6−e82

(7.11)
g2 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

false

(7.12)

 

 Example 6.  The 7 sphere as Spin(7)/G2

 

 

In this example we find that  in order to compute the relative chains , it is essential to change to a basis in so(7) adapted to gl2 to avoid serious memory problems.

 

g2 > 

with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

Define and initialize the general linear Lie algebra gl7.

> 

DGsetup([x1, x2, x3, x4, x5, x6, x7], E7):

E7 > 

phi := evalDG(dx1 &w dx2 &w dx3  + dx1 &w dx4 &w dx5 -dx1 &w dx6 &w dx7 + dx2 &w dx4 &w dx6+ dx2 &w dx5 &w dx7 +dx3 &w dx4 &w dx7 -dx3 &w dx5 &w dx6);

φ≔dx1⁢⋀⁢dx2⁢⋀⁢dx3+dx1⁢⋀⁢dx4⁢⋀⁢dx5−dx1⁢⋀⁢dx6⁢⋀⁢dx7+dx2⁢⋀⁢dx4⁢⋀⁢dx6+dx2⁢⋀⁢dx5⁢⋀⁢dx7+dx3⁢⋀⁢dx4⁢⋀⁢dx7−dx3⁢⋀⁢dx5⁢⋀⁢dx6

(8.1)
E7 > 

g := CanonicalTensors("Metric","bas",7,0):

E7 > 

DGsetup(MatrixAlgebras("Full", 7, gl7R));

Lie algebra: gl7R

(8.2)
gl7R > 

so7_subalg := MatrixAlgebras("Subalgebra",gl7R,[g]):

gl7R > 

g2_subalg := MatrixAlgebras("Subalgebra",gl7R,[phi,g]):

gl7R > 

g, h0 := LieAlgebraData(so7_subalg, [g2_subalg],so7);

g,h0≔e1,e2=−e7,e1,e3=−e8,e1,e4=−e9,e1,e5=−e10,e1,e6=−e11,e1,e7=e2,e1,e8=e3,e1,e9=e4,e1,e10=e5,e1,e11=e6,e2,e3=−e12,e2,e4=−e13,e2,e5=−e14,e2,e6=−e15,e2,e7=−e1,e2,e12=e3,e2,e13=e4,e2,e14=e5,e2,e15=e6,e3,e4=−e16,e3,e5=−e17,e3,e6=−e18,e3,e8=−e1,e3,e12=−e2,e3,e16=e4,e3,e17=e5,e3,e18=e6,e4,e5=−e19,e4,e6=−e20,e4,e9=−e1,e4,e13=−e2,e4,e16=−e3,e4,e19=e5,e4,e20=e6,e5,e6=−e21,e5,e10=−e1,e5,e14=−e2,e5,e17=−e3,e5,e19=−e4,e5,e21=e6,e6,e11=−e1,e6,e15=−e2,e6,e18=−e3,e6,e20=−e4,e6,e21=−e5,e7,e8=−e12,e7,e9=−e13,e7,e10=−e14,e7,e11=−e15,e7,e12=e8,e7,e13=e9,e7,e14=e10,e7,e15=e11,e8,e9=−e16,e8,e10=−e17,e8,e11=−e18,e8,e12=−e7,e8,e16=e9,e8,e17=e10,e8,e18=e11,e9,e10=−e19,e9,e11=−e20,e9,e13=−e7,e9,e16=−e8,e9,e19=e10,e9,e20=e11,e10,e11=−e21,e10,e14=−e7,e10,e17=−e8,e10,e19=−e9,e10,e21=e11,e11,e15=−e7,e11,e18=−e8,e11,e20=−e9,e11,e21=−e10,e12,e13=−e16,e12,e14=−e17,e12,e15=−e18,e12,e16=e13,e12,e17=e14,e12,e18=e15,e13,e14=−e19,e13,e15=−e20,e13,e16=−e12,e13,e19=e14,e13,e20=e15,e14,e15=−e21,e14,e17=−e12,e14,e19=−e13,e14,e21=e15,e15,e18=−e12,e15,e20=−e13,e15,e21=−e14,e16,e17=−e19,e16,e18=−e20,e16,e19=e17,e16,e20=e18,e17,e18=−e21,e17,e19=−e16,e17,e21=e18,e18,e20=−e16,e18,e21=−e17,e19,e20=−e21,e19,e21=e20,e20,e21=−e19,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,1,0,0,0,0,0,0,0,0,0,0,−1,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,−1,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,1,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,−1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,−1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,−1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,1,0,0

(8.3)
gl7R > 

DGsetup(g);

Lie algebra: so7

(8.4)
so7 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10,e11,e12,e13,e14,e15,e16,e17,e18,e19,e20,e21

(8.5)
so7 > 

g2 := map(DGzip,h0[1], Fr, "plus");

g2≔e1+e19,e2+e20,e3−e14,e4−e15,e5+e12,e6+e13,e7+e21,e8+e13,e9−e12,e10−e15,e11+e14,e16+e21,e17−e20,e18+e19

(8.6)
so7 > 

nops(g2);

14

(8.7)
so7 > 

m := ComplementaryBasis(g2,Fr);

m≔e1,e2,e3,e4,e5,e6,e7

(8.8)
so7 > 

newBasis := [op(m), op(g2)];

newBasis≔e1,e2,e3,e4,e5,e6,e7,e1+e19,e2+e20,e3−e14,e4−e15,e5+e12,e6+e13,e7+e21,e8+e13,e9−e12,e10−e15,e11+e14,e16+e21,e17−e20,e18+e19

(8.9)
so7 > 

L := LieAlgebraData(newBasis, new_so7):

so7 > 

DGsetup(L);

Lie algebra: new_so7

(8.10)
new_so7 > 

new_g2 := [seq(e||i, i = 8 .. 21)];

new_g2≔e8,e9,e10,e11,e12,e13,e14,e15,e16,e17,e18,e19,e20,e21

(8.11)
new_so7 > 

C := RelativeChains(new_g2);

C≔,,,−θ1⁢⋀⁢θ2⁢⋀⁢θ7+θ1⁢⋀⁢θ3⁢⋀⁢θ6−θ1⁢⋀⁢θ4⁢⋀⁢θ5−θ2⁢⋀⁢θ3⁢⋀⁢θ5−θ2⁢⋀⁢θ4⁢⋀⁢θ6−θ3⁢⋀⁢θ4⁢⋀⁢θ7+θ5⁢⋀⁢θ6⁢⋀⁢θ7,−θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4+θ1⁢⋀⁢θ2⁢⋀⁢θ5⁢⋀⁢θ6+θ1⁢⋀⁢θ3⁢⋀⁢θ5⁢⋀⁢θ7+θ1⁢⋀⁢θ4⁢⋀⁢θ6⁢⋀⁢θ7+θ2⁢⋀⁢θ3⁢⋀⁢θ6⁢⋀⁢θ7−θ2⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ7+θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6,,,−θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ7,

(8.12)
new_so7 > 

H := Cohomology(C);

H≔,,,,,,−θ1⁢⋀⁢θ2⁢⋀⁢θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ7

(8.13)
new_so7 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10,e11,e12,e13,e14,e15,e16,e17,e18,e19,e20,e21

(8.14)
new_so7 > 

M0 := ComplementaryBasis(new_g2,Fr,a);

M0≔e1+a1⁢e8+a2⁢e9+a3⁢e10+a4⁢e11+a5⁢e12+a6⁢e13+a7⁢e14+a8⁢e15+a9⁢e16+a10⁢e17+a11⁢e18+a12⁢e19+a13⁢e20+a14⁢e21,e2+a15⁢e8+a16⁢e9+a17⁢e10+a18⁢e11+a19⁢e12+a20⁢e13+a21⁢e14+a22⁢e15+a23⁢e16+a24⁢e17+a25⁢e18+a26⁢e19+a27⁢e20+a28⁢e21,e3+a29⁢e8+a30⁢e9+a31⁢e10+a32⁢e11+a33⁢e12+a34⁢e13+a35⁢e14+a36⁢e15+a37⁢e16+a38⁢e17+a39⁢e18+a40⁢e19+a41⁢e20+a42⁢e21,e4+a43⁢e8+a44⁢e9+a45⁢e10+a46⁢e11+a47⁢e12+a48⁢e13+a49⁢e14+a50⁢e15+a51⁢e16+a52⁢e17+a53⁢e18+a54⁢e19+a55⁢e20+a56⁢e21,e5+a57⁢e8+a58⁢e9+a59⁢e10+a60⁢e11+a61⁢e12+a62⁢e13+a63⁢e14+a64⁢e15+a65⁢e16+a66⁢e17+a67⁢e18+a68⁢e19+a69⁢e20+a70⁢e21,e6+a71⁢e8+a72⁢e9+a73⁢e10+a74⁢e11+a75⁢e12+a76⁢e13+a77⁢e14+a78⁢e15+a79⁢e16+a80⁢e17+a81⁢e18+a82⁢e19+a83⁢e20+a84⁢e21,e7+a85⁢e8+a86⁢e9+a87⁢e10+a88⁢e11+a89⁢e12+a90⁢e13+a91⁢e14+a92⁢e15+a93⁢e16+a94⁢e17+a95⁢e18+a96⁢e19+a97⁢e20+a98⁢e21,a1,a10,a11,a12,a13,a14,a15,a16,a17,a18,a19,a2,a20,a21,a22,a23,a24,a25,a26,a27,a28,a29,a3,a30,a31,a32,a33,a34,a35,a36,a37,a38,a39,a4,a40,a41,a42,a43,a44,a45,a46,a47,a48,a49,a5,a50,a51,a52,a53,a54,a55,a56,a57,a58,a59,a6,a60,a61,a62,a63,a64,a65,a66,a67,a68,a69,a7,a70,a71,a72,a73,a74,a75,a76,a77,a78,a79,a8,a80,a81,a82,a83,a84,a85,a86,a87,a88,a89,a9,a90,a91,a92,a93,a94,a95,a96,a97,a98

(8.15)
> 

TF, Eq, Soln, ReductivePairs:= Query(new_g2,M0,"ReductivePair"):

new_so7 > 

ReductivePairs[1];

e8,e9,e10,e11,e12,e13,e14,e15,e16,e17,e18,e19,e20,e21,e1−2⁢e83+e213,e2−2⁢e93−e203,e3−2⁢e103−e183,e4−2⁢e113+e173,e5−2⁢e123−e163,e6−2⁢e133+e153,e7−2⁢e143+e193

(8.16)
new_so7 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

false

(8.17)

 Example 7.  Complex projective space CP^4 as SU(3)/U(2)

 

We construct the Lie algebra pair (g, h) = (su(3), u(2)) . The relative Lie algebra cohomology is computed and this gives the cohomology of the complex projective space CP^4. We show that (su(3), u(2)) is a symmetric pair.

new_so7 > 

restart: with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 6 dimensional space (on which gl(6) will act). On E6 define a metric tensor g, a complex structure J, a pair of 3 forms nuR and nuI and a vector V.  We construct su3 as the subalgebra of gl6 which fixes g, J, nuI, and nuR.

> 

DGsetup([x1, x2, x3, y1, y2, y3], E6):

E6 > 

g := CanonicalTensors("Metric", "bas", 6,0);

g≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3+dy1⁢dy1+dy2⁢dy2+dy3⁢dy3

(9.1)
E6 > 

J := CanonicalTensors("ComplexStructure", "bas");

J≔−dx1⁢D_y1−dx2⁢D_y2−dx3⁢D_y3+dy1⁢D_x1+dy2⁢D_x2+dy3⁢D_x3

(9.2)
E6 > 

dz1 := DGzip([1,I],[dx1, dy1], "plus"):
dz2 := DGzip([1,I],[dx2, dy2], "plus"):
dz3 := DGzip([1,I],[dx3, dy3], "plus"):
nu := dz1&wedge dz2 &wedge dz3:

E6 > 

nuR := (1/2) &mult (nu &plus Tools:-DGmap(1,conjugate,nu));

nuR≔dx1⁢⋀⁢dx2⁢⋀⁢dx3−dx1⁢⋀⁢dy2⁢⋀⁢dy3+dx2⁢⋀⁢dy1⁢⋀⁢dy3−dx3⁢⋀⁢dy1⁢⋀⁢dy2

(9.3)
E6 > 

nuI := (I/2) &mult (nu &minus Tools:-DGmap(1, conjugate,nu));

nuI≔−dx1⁢⋀⁢dx2⁢⋀⁢dy3+dx1⁢⋀⁢dx3⁢⋀⁢dy2−dx2⁢⋀⁢dx3⁢⋀⁢dy1+dy1⁢⋀⁢dy2⁢⋀⁢dy3

(9.4)

 

Define and initialize the general linear Lie algebra gl6R.

E6 > 

DGsetup(MatrixAlgebras("Full",6)):

 

Calculate su3 as subalgebras of gl6R.

gl6R > 

su3_subalg := MatrixAlgebras("Subalgebra",gl6R,[g,J,nuR,nuI]);

su3_subalg≔e12−e21+e45−e54,e13−e31+e46−e64,e14−e36−e41+e63,e15+e24−e42−e51,e16+e34−e43−e61,e23−e32+e56−e65,e25−e36−e52+e63,e26+e35−e53−e62

(9.5)

 

Identify u2 as a 4 -dimensional subalgebra of su3.

gl6R > 

u2_subalg := [su3_subalg[1],su3_subalg[3],su3_subalg[4],su3_subalg[7]];

u2_subalg≔e12−e21+e45−e54,e14−e36−e41+e63,e15+e24−e42−e51,e25−e36−e52+e63

(9.6)

 

Calculate the structure equations for su3 and find the component expressions for the vectors in u2 in terms of the vectors in su3.

gl6R > 

g, h0 := LieAlgebraData(su3_subalg, [u2_subalg], su3):

gl6R > 

DGsetup(g);

Lie algebra: su3

(9.7)
su3 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8

(9.8)
su3 > 

u2 := map(DGzip,h0[1], Fr, "plus");

u2≔e1,e3,e4,e7

(9.9)

 

Calculate the forms omega on su3 which satisfy Hook(X, omega) = 0 and Hook(X, d(omega)) = 0 for all X in u2.  These are the su3 relative chains.

su3 > 

C := RelativeChains(u2);

C≔,,−θ2⁢⋀⁢θ5−θ6⁢⋀⁢θ8,,θ2⁢⋀⁢θ5⁢⋀⁢θ6⁢⋀⁢θ8,

(9.10)

 

Calculate the Lie algebra cohomology of su3 relative to u2. We find 1 generator in degrees 2 and 4.

su3 > 

H := Cohomology(C):

 

We calculate the general complement to u2 in su3 and use the Query program to find all possible reductive complements.

su3 > 

m0 := ComplementaryBasis(u2, Fr, a);

m0≔a1⁢e1+e2+a2⁢e3+a3⁢e4+a4⁢e7,a5⁢e1+a6⁢e3+a7⁢e4+e5+a8⁢e7,a9⁢e1+a10⁢e3+a11⁢e4+e6+a12⁢e7,a13⁢e1+a14⁢e3+a15⁢e4+a16⁢e7+e8,a1,a10,a11,a12,a13,a14,a15,a16,a2,a3,a4,a5,a6,a7,a8,a9

(9.11)

 

We find that there is a unique reductive complement and that defines (su3, u2) to be a symmetric pair.

su3 > 

TF, Eq, Soln, ReductivePairs:= Query(u2,m0,"ReductivePair");

TF,Eq,Soln,ReductivePairs≔true,0,a1,a14,a15,a16,a5,a6,a7,a8,−2⁢a10,−a10,−a11,−2⁢a12,−a12,−a13,2⁢a14,2⁢a16,−2⁢a2,−a2,−a3,−2⁢a4,−a4,2⁢a6,2⁢a8,−a9,−2⁢a1+a7,−a1−a7,−a10−2⁢a3,−a10+2⁢a5,−2⁢a11+a13,−a11−a13,−a12+2⁢a3,−a12−2⁢a5,a13+a11,2⁢a13−a11,−a14−2⁢a7,a14+2⁢a1,a15−a9,2⁢a15+a9,−a16+2⁢a7,a16−2⁢a1,−a2+2⁢a13,a2−2⁢a11,−2⁢a3−a5,−a4−2⁢a13,a4+2⁢a11,a5−a3,2⁢a5+a3,a6−2⁢a15,a6+2⁢a9,a7+a1,2⁢a7−a1,a8+2⁢a15,a8−2⁢a9,−2⁢a9−a15,−a1+a16−a14,−a11−a4+a2,a13+a4−a2,−a15−a8+a6,a3−a12+a10,a5+a12−a10,a7−a16+a14,−a9+a8−a6,a1=0,a10=0,a11=0,a12=0,a13=0,a14=0,a15=0,a16=0,a2=0,a3=0,a4=0,a5=0,a6=0,a7=0,a8=0,a9=0,e1,e3,e4,e7,e2,e5,e6,e8

(9.12)
su3 > 

ReductivePairs[1];

e1,e3,e4,e7,e2,e5,e6,e8

(9.13)
su3 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

true

(9.14)

 

 Example 8.  The oriented Grassmannian of 3 planes in R^6 as SO(6)/(SO(3) x SO(3))

 

This example is  taken from Wolf  p. 253  (Actually Wolf  looks at the case SO(8)/SO(4) times SO(4) but this case takes a lot of computation time).We construct the Lie algebra pair (g, h) = (so6, so3 x so3).  The relative Lie algebra cohomology is computed and gives the cohomology of the oriented Grassmannian of 3 planes in R^6. We show that (so6, so3 x so3) is a symmetric pair.

su3 > 

restart: with(DifferentialGeometry):with(LieAlgebras):with(Tensor):

 

Define a 6 dimensional space (on which gl6 will act) and a metric tensor g and a symmetric tensor g1 on E6.  We construct so6 as the subalgebra of gl6 which fixes g and so3 x so3 as the subalgebra of gl6 which fixes both g and g1.

> 

DGsetup([x1, x2, x3, x4, x5, x6], E6);

frame name: E6

(10.1)
E6 > 

g := CanonicalTensors("Metric", "bas", 6, 0);

g≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3+dx4⁢dx4+dx5⁢dx5+dx6⁢dx6

(10.2)
E6 > 

g1 := evalDG(dx1 &t dx1 + dx2 &t dx2  + dx3 &t dx3);

g1≔dx1⁢dx1+dx2⁢dx2+dx3⁢dx3

(10.3)

 

Define and initialize the general linear Lie algebra gl5.

E6 > 

DGsetup(MatrixAlgebras("Full", 6, gl6R));

Lie algebra: gl6R

(10.4)

 

Calculate so6 and so3 x so3  as subalgebras of gl6.

gl6R > 

so6_subalg := MatrixAlgebras("Subalgebra", gl6R, [g]);

so6_subalg≔e12−e21,e13−e31,e14−e41,e15−e51,e16−e61,e23−e32,e24−e42,e25−e52,e26−e62,e34−e43,e35−e53,e36−e63,e45−e54,e46−e64,e56−e65

(10.5)
gl6R > 

so3xso3_subalg := MatrixAlgebras("Subalgebra", gl6R,[g,g1]);

so3xso3_subalg≔e12−e21,e13−e31,e23−e32,e45−e54,e46−e64,e56−e65

(10.6)

 

Calculate the structure equations for so6 and find the component expressions for the vectors in so6 in terms of the vectors in so3 x so3.

gl6R > 

g, h0 := LieAlgebraData(so6_subalg,[so3xso3_subalg],so6);

g,h0≔e1,e2=−e6,e1,e3=−e7,e1,e4=−e8,e1,e5=−e9,e1,e6=e2,e1,e7=e3,e1,e8=e4,e1,e9=e5,e2,e3=−e10,e2,e4=−e11,e2,e5=−e12,e2,e6=−e1,e2,e10=e3,e2,e11=e4,e2,e12=e5,e3,e4=−e13,e3,e5=−e14,e3,e7=−e1,e3,e10=−e2,e3,e13=e4,e3,e14=e5,e4,e5=−e15,e4,e8=−e1,e4,e11=−e2,e4,e13=−e3,e4,e15=e5,e5,e9=−e1,e5,e12=−e2,e5,e14=−e3,e5,e15=−e4,e6,e7=−e10,e6,e8=−e11,e6,e9=−e12,e6,e10=e7,e6,e11=e8,e6,e12=e9,e7,e8=−e13,e7,e9=−e14,e7,e10=−e6,e7,e13=e8,e7,e14=e9,e8,e9=−e15,e8,e11=−e6,e8,e13=−e7,e8,e15=e9,e9,e12=−e6,e9,e14=−e7,e9,e15=−e8,e10,e11=−e13,e10,e12=−e14,e10,e13=e11,e10,e14=e12,e11,e12=−e15,e11,e13=−e10,e11,e15=e12,e12,e14=−e10,e12,e15=−e11,e13,e14=−e15,e13,e15=e14,e14,e15=−e13,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1

(10.7)

 

gl6R > 

DGsetup(g);

Lie algebra: so6

(10.8)

Find so3 x so3 as a subalgebra of so6.

so6 > 

Fr := Tools:-DGinfo("FrameBaseVectors");

Fr≔e1,e2,e3,e4,e5,e6,e7,e8,e9,e10,e11,e12,e13,e14,e15

(10.9)
so6 > 

so3xso3 := map(DGzip,h0[1], Fr, "plus");

so3xso3≔e1,e2,e6,e13,e14,e15

(10.10)
so6 > 

C := RelativeChains(so3xso3);

C≔,,,,θ3⁢⋀⁢θ4⁢⋀⁢θ7⁢⋀⁢θ8+θ3⁢⋀⁢θ4⁢⋀⁢θ10⁢⋀⁢θ11+θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ9+θ3⁢⋀⁢θ5⁢⋀⁢θ10⁢⋀⁢θ12+θ4⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9+θ4⁢⋀⁢θ5⁢⋀⁢θ11⁢⋀⁢θ12+θ7⁢⋀⁢θ8⁢⋀⁢θ10⁢⋀⁢θ11+θ7⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ12+θ8⁢⋀⁢θ9⁢⋀⁢θ11⁢⋀⁢θ12,θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ10+θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ11+θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ9⁢⋀⁢θ12+θ3⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10+θ3⁢⋀⁢θ7⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12+θ4⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ11+θ4⁢⋀⁢θ8⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12+θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ12+θ5⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12,,,,θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12,

(10.11)

 

Calculate the Lie algebra cohomology of so6 relative to so3 x so3.

so6 > 

H := Cohomology(C);

H≔,,,θ3⁢⋀⁢θ4⁢⋀⁢θ7⁢⋀⁢θ8+θ3⁢⋀⁢θ4⁢⋀⁢θ10⁢⋀⁢θ11+θ3⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ9+θ3⁢⋀⁢θ5⁢⋀⁢θ10⁢⋀⁢θ12+θ4⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ9+θ4⁢⋀⁢θ5⁢⋀⁢θ11⁢⋀⁢θ12+θ7⁢⋀⁢θ8⁢⋀⁢θ10⁢⋀⁢θ11+θ7⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ12+θ8⁢⋀⁢θ9⁢⋀⁢θ11⁢⋀⁢θ12,θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ10+θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ8⁢⋀⁢θ11+θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ9⁢⋀⁢θ12+θ3⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10+θ3⁢⋀⁢θ7⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12+θ4⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ11+θ4⁢⋀⁢θ8⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12+θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ12+θ5⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12,,,,θ3⁢⋀⁢θ4⁢⋀⁢θ5⁢⋀⁢θ7⁢⋀⁢θ8⁢⋀⁢θ9⁢⋀⁢θ10⁢⋀⁢θ11⁢⋀⁢θ12

(10.12)
so6 > 

m0 := ComplementaryBasis(so3xso3, Fr, a);

m0≔a1⁢e1+a2⁢e2+e3+a3⁢e6+a4⁢e13+a5⁢e14+a6⁢e15,a7⁢e1+a8⁢e2+e4+a9⁢e6+a10⁢e13+a11⁢e14+a12⁢e15,a13⁢e1+a14⁢e2+e5+a15⁢e6+a16⁢e13+a17⁢e14+a18⁢e15,a19⁢e1+a20⁢e2+a21⁢e6+e7+a22⁢e13+a23⁢e14+a24⁢e15,a25⁢e1+a26⁢e2+a27⁢e6+e8+a28⁢e13+a29⁢e14+a30⁢e15,a31⁢e1+a32⁢e2+a33⁢e6+e9+a34⁢e13+a35⁢e14+a36⁢e15,a37⁢e1+a38⁢e2+a39⁢e6+e10+a40⁢e13+a41⁢e14+a42⁢e15,a43⁢e1+a44⁢e2+a45⁢e6+e11+a46⁢e13+a47⁢e14+a48⁢e15,a49⁢e1+a50⁢e2+a51⁢e6+e12+a52⁢e13+a53⁢e14+a54⁢e15,a1,a10,a11,a12,a13,a14,a15,a16,a17,a18,a19,a2,a20,a21,a22,a23,a24,a25,a26,a27,a28,a29,a3,a30,a31,a32,a33,a34,a35,a36,a37,a38,a39,a4,a40,a41,a42,a43,a44,a45,a46,a47,a48,a49,a5,a50,a51,a52,a53,a54,a6,a7,a8,a9

(10.13)

 

We find that there is a unique reductive complement and that defines (so6, so3 x so3) to be a symmetric pair.

so6 > 

TF, Eq, Soln, ReductivePairs:= Query(so3xso3,m0,"ReductivePair"):

so6 > 

ReductivePairs[1];

e1,e2,e6,e13,e14,e15,e3,e4,e5,e7,e8,e9,e10,e11,e12

(10.14)
so6 > 

Query(op(ReductivePairs[1]),"SymmetricPair");

true

(10.15)