LieAlgebras[SymbolAlgebra] - find the symbol algebra for a distribution
Calling Sequences
SymbolAlgebra(D, pt, alg, option)
Parameters
D - a list of vectors on a manifold M
pt - a list of equations specifying a point on M
alg - a name or string, the name to be assigned to the symbol algebra
option - (optional keyword arguments) output = "WeakDerivedFlag" , order = "Increasing", order = "Decreasing",
Description
In differential geometry a distribution is a set of vector fields 𝒟 defined on a manifold M. The sequence of distributions defined inductively by
𝒟0 = 𝒟 , 𝒟1= [𝒟0 , 𝒟0] + 𝒟0 , ..., 𝒟i+1= [𝒟0 , 𝒟i] + 𝒟i
is called the weak derived flag of the distribution. These distributions satisfy 𝒟i ⊂ 𝒟i+1 and [𝒟i , 𝒟j]⊂𝒟i+j. The symbol algebra 𝔪x𝒟 for the distribution 𝒟 at the point x ∈M is the graded nilpotent Lie algebra defined by
𝔪x𝒟= ⨁p= −1p = − μ 𝔤px where 𝔤−1x = 𝒟x0, 𝔤−2x = 𝒟x−1/𝒟x0 , ... , 𝔤−px = 𝒟x−p +1/𝒟x−p+2, ...
The grading weight of 𝔤px is p.
The command SymbolAlgebra((D, pt, alg) returns the structure equations for the symbol algebra of 𝒟 at the point specified by the second argument. These structure equations can be initialized with DGsetup. The command DGinfo can be used to view the grading of the symbol algebra.
With the keyword argument output = "WeakDerivedFlag", the structure equations for the symbol algebra and the vector fields defining the weak derived flag [𝒟0, 𝒟1, 𝒟2, ...] are returned.
The basis used to define the symbol algebra is given in terms of decreasing weights. For example, if 𝔪 = 𝔤−1⊕ 𝔤−2⊕𝔤−3 with dim 𝔤−1= 4, dim 𝔤−2= 2 and dim 𝔤−3= 1, then 𝔤−1 =e1, e2, e3, e4, 𝔤−2 =e5, e6 and 𝔤−3 =e7. With the keyword argument order = "Increasing", the basis used to define the symbol algebra is given in terms of increasing weights so that, for example, if 𝔪= 𝔤−3⊕ 𝔤−2⊕𝔤−1, then 𝔤−3 =e1, 𝔤−2 =e2, e3 and 𝔤−1 =e4, e5, e6 ,e7.
See Also
DifferentialGeometry
LieAlgebras
DGinfo
Query
TanakaProlongation
Examples
with(DifferentialGeometry): with(LieAlgebras):
Example 1.
In this example we find the symbol algebra for the Hilbert-Cartan equation z' = y''2.
First create a 5-dimensional manifold.
DGsetup([x, y, z, y1, y2], M);
frame name: M
Define the rank 3 distribution for the Hilbert-Cartan equation z''=y''2.
Delta := [D_x + y1*D_y + y2*D_y1 + y2^2*D_z, D_y2];
Δ:=D_x+y1D_y+y2D_y1+y22D_z,D_y2
Calculate the symbol algebra and initialize.
LD := SymbolAlgebra(Delta, [x = 0, y = 0, y1 = 0, y2 = 0, z = 0], alg);
LD:=e1,e2=−e3,e1,e3=e4,e2,e3=e5
DGsetup(LD);
Lie algebra: alg
Here is the multiplication table.
MultiplicationTable("LieTable");
The algebra is nilpotent
Query("Nilpotent");
true
Here is the grading of the algebra as a list and in table format.
Gr := Tools:-DGinfo("Grading");
Gr:=−1,−1,−2,−3,−3
convert(Gr, DGgrading, "table", [e1, e2, e3, e4, e5]);
table−3=e4,e5,−2=e3,−1=e1,e2
Example 2.
We continue with the distribution given in Example 1. We use the keyword argument output = "WeakDerivedFlag" to display the weak derived flag used to calculate the symbol algebra.
SymbolAlgebra(Delta, [x = 0, y = 0, y1 = 0, y2 = 0, z = 0], alg, output = "WeakDerivedFlag");
e1,e2=−e3,e1,e3=e4,e2,e3=e5,D_x+y1D_y+y22D_z+y2D_y1,D_y2,−2y2D_z−D_y1,D_y,−2D_z
We use the second calling sequence to give the symbol algebra in ascending grading order.
LD2 := SymbolAlgebra(Delta, [x = 0, y = 0, y1 = 0, y2 = 0, z = 0], alg2, order = "Increasing");
LD2:=e3,e4=−e1,e3,e5=−e2,e4,e5=e3
DGsetup(LD2);
Lie algebra: alg2
Here is the multiplication table and the grading.
MultiplicationTable("LieTable"), Tools:-DGinfo("Grading");
Example 3.
In this example we find the symbol algebra for the jet space J2R2,R. First create an 8 dimensional manifold.
DGsetup([x, y, z, p, q, r, s, t], M3);
frame name: M3
Define the rank 3 distribution for the canonical system on jet space.
Delta3 := evalDG([D_x + p*D_z + r*D_p + s*D_q, D_y + q*D_z + s*D_p + t*D_q, D_r, D_s, D_t]);
Δ3:=D_x+pD_z+rD_p+sD_q,D_y+qD_z+sD_p+tD_q,D_r,D_s,D_t
Calculate the symbol algebra and initialize it.
LD3 := SymbolAlgebra(Delta3, [x = 0, y = 0, z = 0, p =0, q = 0, r = 0, s = 0, t = 0], alg3);
LD3:=e1,e4=−e6,e2,e4=−e7,e2,e5=−e6,e3,e5=−e7,e4,e6=e8,e5,e7=e8
DGsetup(LD3);
Lie algebra: alg3
Download Help Document
