The GRTensor package, developed by K. Lake, P. Musgrave and D. Polleny, has long provided the general relativity community with an excellent collection of command for symbolic computations in general relativity. This functionality is also now available within the DifferentialGeometry package and its subpackage Tensor, as well as within the Physics package.

This worksheet provides a quick introduction to General Relativity computations using DifferentialGeometry.

with(DifferentialGeometry): with(Tensor): with(Tools):

DGsetup([t, r, theta, phi], M1, verbose);

$\mathrm{The\; following\; coordinates\; have\; been\; protected:}$

$\left[t\,r\,\mathrm{\theta }\,\mathrm{\phi }\right]$

$\mathrm{The\; following\; vector\; fields\; have\; been\; defined\; and\; protected:}$

$\left[\mathrm{D\_t}\,\mathrm{D\_r}\,\mathrm{D\_\θ}\,\mathrm{D\_\φ}\right]$

$\mathrm{The\; following\; differential\; 1-forms\; have\; been\; defined\; and\; protected:}$

$\left[\mathrm{dt}\,\mathrm{dr}\,\mathrm{d\θ}\,\mathrm{d\φ}\right]$

$\mathrm{frame\; name:\; M1}$

g := evalDG( A(r) *dt &t dt + B(r)* dr &t dr + r^2*(dtheta &t dtheta + sin(theta)^2* dphi &t dphi));

$g≔A\left(r\right)\mathrm{dt}\mathrm{dt}+B\left(r\right)\mathrm{dr}\mathrm{dr}+r^2\mathrm{d\θ}\mathrm{d\θ}+r^2{\sin \left(\mathrm{\theta }\right)}^2\mathrm{d\φ}\mathrm{d\φ}$

Ein := EinsteinTensor(g);

$\mathrm{Ein}≔-\frac{\left(r\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)+{B\left(r\right)}^2-B\left(r\right)\right)\mathrm{D\_t}}{A\left(r\right)r^2{B\left(r\right)}^2}\mathrm{D\_t}-\frac{\left(A\left(r\right)B\left(r\right)-\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-A\left(r\right)\right)\mathrm{D\_r}}{A\left(r\right){B\left(r\right)}^2{r}^2}\mathrm{D\_r}-\frac{\left(\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)A\left(r\right)\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-2B\left(r\right)\left(\frac{{\ⅆ}^2}{\ⅆr^2}A\left(r\right)\right)A\left(r\right)r+B\left(r\right){\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)}^{2}r+2\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right){A\left(r\right)}^2-2\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)B\left(r\right)A\left(r\right)\right)\mathrm{D\_\θ}}{4r^3{B\left(r\right)}^2{A\left(r\right)}^2}\mathrm{D\_\θ}-\frac{\left(\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)A\left(r\right)\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-2B\left(r\right)\left(\frac{{\ⅆ}^2}{\ⅆr^2}A\left(r\right)\right)A\left(r\right)r+B\left(r\right){\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)}^{2}r+2\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right){A\left(r\right)}^2-2\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)B\left(r\right)A\left(r\right)\right)\mathrm{D\_\φ}}{4r^3{B\left(r\right)}^2{A\left(r\right)}^2{\sin \left(\mathrm{\theta }\right)}^2}\mathrm{D\_\φ}$

EinEq := DGinfo(Ein, "CoefficientSet");

$\mathrm{EinEq}≔\left\{-\frac{\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)A\left(r\right)\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-2B\left(r\right)\left(\frac{{\ⅆ}^2}{\ⅆr^2}A\left(r\right)\right)A\left(r\right)r+B\left(r\right){\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)}^{2}r+2\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right){A\left(r\right)}^2-2\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)B\left(r\right)A\left(r\right)}{4r^3{B\left(r\right)}^2{A\left(r\right)}^2}\,-\frac{r\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)+{B\left(r\right)}^2-B\left(r\right)}{A\left(r\right)r^2{B\left(r\right)}^2}\,-\frac{A\left(r\right)B\left(r\right)-\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-A\left(r\right)}{A\left(r\right){B\left(r\right)}^2{r}^2}\,-\frac{\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right)A\left(r\right)\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)r-2B\left(r\right)\left(\frac{{\ⅆ}^2}{\ⅆr^2}A\left(r\right)\right)A\left(r\right)r+B\left(r\right){\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)}^{2}r+2\left(\frac{\ⅆ}{\ⅆr}B\left(r\right)\right){A\left(r\right)}^2-2\left(\frac{\ⅆ}{\ⅆr}A\left(r\right)\right)B\left(r\right)A\left(r\right)}{4r^3{B\left(r\right)}^2{A\left(r\right)}^2{\sin \left(\mathrm{\theta }\right)}^2}\right\}$

Soln := pdsolve(EinEq);

$\mathrm{Soln}≔\left\{A\left(r\right)=\frac{\left(r+\mathrm{c\_\_1}\right)\mathrm{c\_\_2}}{r}\,B\left(r\right)=\frac{r}{r+\mathrm{c\_\_1}}\right\}$

gS := subs({_C1 = - 2*m, _C2= -1},subs(Soln, g));

$\mathrm{gS}≔-\frac{\left(r-2m\right)\mathrm{dt}}{r}\mathrm{dt}+\frac{r\mathrm{dr}}{r-2m}\mathrm{dr}+r^2\mathrm{d\θ}\mathrm{d\θ}+r^2{\sin \left(\mathrm{\theta }\right)}^2\mathrm{d\φ}\mathrm{d\φ}$

EinsteinTensor(gS);

$0\mathrm{D\_t}\mathrm{D\_t}$

K := KillingVectors(gS);

$K≔\left[-\mathrm{D\_t}\,\sin \left(\mathrm{\phi }\right)\mathrm{D\_\θ}+\cos \left(\mathrm{\phi }\right)\cot \left(\mathrm{\theta }\right)\mathrm{D\_\φ}\,\cos \left(\mathrm{\phi }\right)\mathrm{D\_\θ}-\sin \left(\mathrm{\phi }\right)\cot \left(\mathrm{\theta }\right)\mathrm{D\_\φ}\,\mathrm{D\_\φ}\right]$

subs({sqrt(1-cos(2*theta)) = sqrt(2)*sin(theta)}, K);

$\left[-\mathrm{D\_t}\,\sin \left(\mathrm{\phi }\right)\mathrm{D\_\θ}+\cos \left(\mathrm{\phi }\right)\cot \left(\mathrm{\theta }\right)\mathrm{D\_\φ}\,\cos \left(\mathrm{\phi }\right)\mathrm{D\_\θ}-\sin \left(\mathrm{\phi }\right)\cot \left(\mathrm{\theta }\right)\mathrm{D\_\φ}\,\mathrm{D\_\φ}\right]$

PetrovType(gS);

$''D''$

convert(convert(gS, DGArray), Matrix);

$\left[\begin{array}{cccc}-\frac{r-2m}{r}& 0& 0& 0\\ 0& \frac{r}{r-2m}& 0& 0\\ 0& 0& r^2& 0\\ 0& 0& 0& r^2{\sin \left(\mathrm{\theta }\right)}^2\end{array}\right]$

DGsetup([x, y, z], M2);

$\mathrm{frame\; name:\; M2}$

g2 := evalDG(z*(dx&t dy + dy &t dx) + x^2*dz &t dz);

$\mathrm{g2}≔z\mathrm{dx}\mathrm{dy}+z\mathrm{dy}\mathrm{dx}+x^2\mathrm{dz}\mathrm{dz}$

h := InverseMetric(g2);

$h≔\frac{\mathrm{D\_x}}{z}\mathrm{D\_y}+\frac{\mathrm{D\_y}}{z}\mathrm{D\_x}+\frac{\mathrm{D\_z}}{x^2}\mathrm{D\_z}$

T := evalDG(dx &t D_y &t dz);

$T≔\mathrm{dx}\mathrm{D\_y}\mathrm{dz}$

RaiseLowerIndices(g2, T, [2]);

$z\mathrm{dx}\mathrm{dx}\mathrm{dz}$

RaiseLowerIndices(h, T, [1,3]);

$\frac{\mathrm{D\_y}}{z{x}^2}\mathrm{D\_y}\mathrm{D\_z}$

RearrangeIndices(T, [[1,2]]);

$\mathrm{D\_y}\mathrm{dx}\mathrm{dz}$

SymmetrizeIndices(T, [1, 3], "Symmetric");

$\frac{\mathrm{dx}}{2}\mathrm{D\_y}\mathrm{dz}+\frac{\mathrm{dz}}{2}\mathrm{D\_y}\mathrm{dx}$

DGsetup([x, y, z], N);

$\mathrm{frame\; name:\; N}$

omega := evalDG(sin(x) *dy + x^2*dz);

$\mathrm{\omega }≔\sin \left(x\right)\mathrm{dy}+x^2\mathrm{dz}$

ExteriorDerivative(omega);

$\cos \left(x\right)\mathrm{dx}\bigwedge \mathrm{dy}+2x\mathrm{dx}\bigwedge \mathrm{dz}$

X := evalDG(y*D_x + x*D_z);

$X≔y\mathrm{D\_x}+x\mathrm{D\_z}$

T := evalDG(x^2*D_y &t dz);

$T≔x^2\mathrm{D\_y}\mathrm{dz}$

LieDerivative(X, T);

$-x^2\mathrm{D\_x}\mathrm{dz}+x^2\mathrm{D\_y}\mathrm{dx}+2yx\mathrm{D\_y}\mathrm{dz}$

C := Connection(a*D_z &t dx &t dy);

$C≔a\mathrm{D\_z}\mathrm{dx}\mathrm{dy}$

CovariantDerivative(T, C);

$-a{x}^2\mathrm{D\_y}\mathrm{dx}\mathrm{dy}+2x\mathrm{D\_y}\mathrm{dz}\mathrm{dx}$

DGsetup([x, y, z], N);

$\mathrm{frame\; name:\; N}$

S := GenerateSymmetricTensors([dx, dy , dz], 2);

$S≔\left[\mathrm{dx}\mathrm{dx}\,\frac{\mathrm{dx}}{2}\mathrm{dy}+\frac{\mathrm{dy}}{2}\mathrm{dx}\,\frac{\mathrm{dx}}{2}\mathrm{dz}+\frac{\mathrm{dz}}{2}\mathrm{dx}\,\mathrm{dy}\mathrm{dy}\,\frac{\mathrm{dy}}{2}\mathrm{dz}+\frac{\mathrm{dz}}{2}\mathrm{dy}\,\mathrm{dz}\mathrm{dz}\right]$

g := DGzip([a1,a2,a3,a4,a5,a6](x, y, z), S, "plus");

$g≔\mathrm{a1}\left(x\,y\,z\right)\mathrm{dx}\mathrm{dx}+\frac{\mathrm{a2}\left(x\,y\,z\right)\mathrm{dx}}{2}\mathrm{dy}+\frac{\mathrm{a3}\left(x\,y\,z\right)\mathrm{dx}}{2}\mathrm{dz}+\frac{\mathrm{a2}\left(x\,y\,z\right)\mathrm{dy}}{2}\mathrm{dx}+\mathrm{a4}\left(x\,y\,z\right)\mathrm{dy}\mathrm{dy}+\frac{\mathrm{a5}\left(x\,y\,z\right)\mathrm{dy}}{2}\mathrm{dz}+\frac{\mathrm{a3}\left(x\,y\,z\right)\mathrm{dz}}{2}\mathrm{dx}+\frac{\mathrm{a5}\left(x\,y\,z\right)\mathrm{dz}}{2}\mathrm{dy}+\mathrm{a6}\left(x\,y\,z\right)\mathrm{dz}\mathrm{dz}$

B := evalDG([dx , dx -dy, dx +2*dy -dz]);

$B≔\left[\mathrm{dx}\,\mathrm{dx}-\mathrm{dy}\,\mathrm{dx}+2\mathrm{dy}-\mathrm{dz}\right]$

alpha := evalDG(dx - 3*dy + 5*dz);

$\mathrm{\alpha }≔\mathrm{dx}-3\mathrm{dy}+5\mathrm{dz}$

GetComponents(alpha, B);

$\left[13\,\mathrm{-7}\,\mathrm{-5}\right]$

DGsetup([x, y, z, t], M5);

$\mathrm{frame\; name:\; M5}$

omega := evalDG(dt + exp(x)*dz);

$\mathrm{\omega }≔{\ⅇ}^x\mathrm{dz}+\mathrm{dt}$

g5 := evalDG(dx &t dx + dy &t dy +1/2*exp(2*x)*dz &t dz - omega &t omega);

$\mathrm{g5}≔\mathrm{dx}\mathrm{dx}+\mathrm{dy}\mathrm{dy}-\frac{{\ⅇ}^{2x}\mathrm{dz}}{2}\mathrm{dz}-{\ⅇ}^x\mathrm{dz}\mathrm{dt}-{\ⅇ}^x\mathrm{dt}\mathrm{dz}-\mathrm{dt}\mathrm{dt}$

CurvatureTensor(g5);

$\frac{3{\ⅇ}^{2x}\mathrm{D\_x}}{4}\mathrm{dz}\mathrm{dx}\mathrm{dz}+\frac{{\ⅇ}^x\mathrm{D\_x}}{2}\mathrm{dz}\mathrm{dx}\mathrm{dt}-\frac{3{\ⅇ}^{2x}\mathrm{D\_x}}{4}\mathrm{dz}\mathrm{dz}\mathrm{dx}-\frac{{\ⅇ}^x\mathrm{D\_x}}{2}\mathrm{dz}\mathrm{dt}\mathrm{dx}+\frac{{\ⅇ}^x\mathrm{D\_x}}{2}\mathrm{dt}\mathrm{dx}\mathrm{dz}+\frac{\mathrm{D\_x}}{2}\mathrm{dt}\mathrm{dx}\mathrm{dt}-\frac{{\ⅇ}^x\mathrm{D\_x}}{2}\mathrm{dt}\mathrm{dz}\mathrm{dx}-\frac{\mathrm{D\_x}}{2}\mathrm{dt}\mathrm{dt}\mathrm{dx}-\frac{\mathrm{D\_z}}{2}\mathrm{dx}\mathrm{dx}\mathrm{dz}+\frac{\mathrm{D\_z}}{2}\mathrm{dx}\mathrm{dz}\mathrm{dx}+\frac{{\ⅇ}^x\mathrm{D\_z}}{2}\mathrm{dz}\mathrm{dz}\mathrm{dt}-\frac{{\ⅇ}^x\mathrm{D\_z}}{2}\mathrm{dz}\mathrm{dt}\mathrm{dz}+\frac{\mathrm{D\_z}}{2}\mathrm{dt}\mathrm{dz}\mathrm{dt}-\frac{\mathrm{D\_z}}{2}\mathrm{dt}\mathrm{dt}\mathrm{dz}+{\ⅇ}^x\mathrm{D\_t}\mathrm{dx}\mathrm{dx}\mathrm{dz}+\frac{\mathrm{D\_t}}{2}\mathrm{dx}\mathrm{dx}\mathrm{dt}-{\ⅇ}^x\mathrm{D\_t}\mathrm{dx}\mathrm{dz}\mathrm{dx}-\frac{\mathrm{D\_t}}{2}\mathrm{dx}\mathrm{dt}\mathrm{dx}-\frac{{\ⅇ}^{2x}\mathrm{D\_t}}{4}\mathrm{dz}\mathrm{dz}\mathrm{dt}+\frac{{\ⅇ}^{2x}\mathrm{D\_t}}{4}\mathrm{dz}\mathrm{dt}\mathrm{dz}-\frac{{\ⅇ}^x\mathrm{D\_t}}{2}\mathrm{dt}\mathrm{dz}\mathrm{dt}+\frac{{\ⅇ}^x\mathrm{D\_t}}{2}\mathrm{dt}\mathrm{dt}\mathrm{dz}$

RicciTensor(g5);

${\ⅇ}^{2x}\mathrm{dz}\mathrm{dz}+{\ⅇ}^x\mathrm{dz}\mathrm{dt}+{\ⅇ}^x\mathrm{dt}\mathrm{dz}+\mathrm{dt}\mathrm{dt}$

RicciScalar(g5);

$\mathrm{-1}$

DGsetup([x, y, z, t], M6);

$\mathrm{frame\; name:\; M6}$

omega := evalDG(dt + exp(x)*dz);

$\mathrm{\omega }≔{\ⅇ}^x\mathrm{dz}+\mathrm{dt}$

g6 := evalDG(dx &t dx + dy &t dy +1/2*exp(2*x)*dz &t dz - omega &t omega);

$\mathrm{g6}≔\mathrm{dx}\mathrm{dx}+\mathrm{dy}\mathrm{dy}-\frac{{\ⅇ}^{2x}\mathrm{dz}}{2}\mathrm{dz}-{\ⅇ}^x\mathrm{dz}\mathrm{dt}-{\ⅇ}^x\mathrm{dt}\mathrm{dz}-\mathrm{dt}\mathrm{dt}$

Omega := evalDG([dx, dy, 1/sqrt(2)*exp(x)*dz, omega]);

$\mathrm{\Omega }≔\left[\mathrm{dx}\,\mathrm{dy}\,\frac{\sqrt{2}{\ⅇ}^x\mathrm{dz}}{2}\,{\ⅇ}^x\mathrm{dz}+\mathrm{dt}\right]$

TensorInnerProduct(g6, Omega, Omega);

$\left[\begin{array}{cccc}1& 0& 0& 0\\ 0& 1& 0& 0\\ 0& 0& 1& 0\\ 0& 0& 0& \mathrm{-1}\end{array}\right]$

FD := FrameData(Omega, O6);

$\mathrm{FD}≔\left[d\mathrm{\Θ1}=0\,d\mathrm{\Θ2}=0\,d\mathrm{\Θ3}=\mathrm{\Θ1}\bigwedge \mathrm{\Θ3}\,d\mathrm{\Θ4}=\sqrt{2}\mathrm{\Θ1}\bigwedge \mathrm{\Θ3}\right]$

DGsetup(FD, [E], [theta]);

$\mathrm{frame\; name:\; O6}$

newg6 := evalDG(theta1 &t theta1 + theta2 &t theta2 + theta3 &t theta3 - theta4 &t theta4);

$\mathrm{newg6}≔\mathrm{\θ1}\mathrm{\θ1}+\mathrm{\θ2}\mathrm{\θ2}+\mathrm{\θ3}\mathrm{\θ3}-\mathrm{\θ4}\mathrm{\θ4}$

CurvatureTensor(newg6);

$\frac{\mathrm{E1}}{2}\mathrm{\θ3}\mathrm{\θ1}\mathrm{\θ3}-\frac{\mathrm{E1}}{2}\mathrm{\θ3}\mathrm{\θ3}\mathrm{\θ1}+\frac{\mathrm{E1}}{2}\mathrm{\θ4}\mathrm{\θ1}\mathrm{\θ4}-\frac{\mathrm{E1}}{2}\mathrm{\θ4}\mathrm{\θ4}\mathrm{\θ1}-\frac{\mathrm{E3}}{2}\mathrm{\θ1}\mathrm{\θ1}\mathrm{\θ3}+\frac{\mathrm{E3}}{2}\mathrm{\θ1}\mathrm{\θ3}\mathrm{\θ1}+\frac{\mathrm{E3}}{2}\mathrm{\θ4}\mathrm{\θ3}\mathrm{\θ4}-\frac{\mathrm{E3}}{2}\mathrm{\θ4}\mathrm{\θ4}\mathrm{\θ3}+\frac{\mathrm{E4}}{2}\mathrm{\θ1}\mathrm{\θ1}\mathrm{\θ4}-\frac{\mathrm{E4}}{2}\mathrm{\θ1}\mathrm{\θ4}\mathrm{\θ1}+\frac{\mathrm{E4}}{2}\mathrm{\θ3}\mathrm{\θ3}\mathrm{\θ4}-\frac{\mathrm{E4}}{2}\mathrm{\θ3}\mathrm{\θ4}\mathrm{\θ3}$

RicciTensor(newg6);

$\mathrm{\θ4}\mathrm{\θ4}$

DGsetup([r, u, x, y], M7);

$\mathrm{frame\; name:\; M7}$

g7 := evalDG(dr &t du + du &t dr -((2*(3*x*r+m))*du &t du)/r-(1/4)*(r^2*dx &t dx)/x^3-(1/4)*(r^2*dy &t dy)/x^3);

$\mathrm{g7}≔\mathrm{dr}\mathrm{du}+\mathrm{du}\mathrm{dr}-\frac{2\left(3xr+m\right)\mathrm{du}}{r}\mathrm{du}-\frac{r^2\mathrm{dx}}{4x^3}\mathrm{dx}-\frac{r^2\mathrm{dy}}{4x^3}\mathrm{dy}$

NT := evalDG([D_r, (3*x*r+m)*D_r/r+D_u, I*sqrt(2)*x^(3/2)*D_x/r+sqrt(2)*x^(3/2)*D_y/r, -I*sqrt(2)*x^(3/2)*D_x/r+sqrt(2)*x^(3/2)*D_y/r]);

$\mathrm{NT}≔\left[\mathrm{D\_r}\,\frac{\left(3xr+m\right)\mathrm{D\_r}}{r}+\mathrm{D\_u}\,\frac{\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_x}}{r}+\frac{\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_y}}{r}\,-\frac{\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_x}}{r}+\frac{\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_y}}{r}\right]$

NP := NPCurvatureScalars(NT, output = ["WeylScalars"]);

$\mathrm{NP}≔table\left(\left[''Psi3''=\frac{-3\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}{r^2}\,''Psi1''=0\,''Psi0''=0\,''Psi4''=\frac{18x^2}{r^2}\,''Psi2''=-\frac{m}{r^3}\right]\right)$

DGsetup([r, u, x, y], [z1, z2, w1, w2], M8);

$\mathrm{frame\; name:\; M8}$

g8 := evalDG(dr &t du + du &t dr -((2*(3*x*r+m))*du &t du)/r-(1/4)*(r^2*dx &t dx)/x^3-(1/4)*(r^2*dy &t dy)/x^3);

$\mathrm{g8}≔\mathrm{dr}\mathrm{du}+\mathrm{du}\mathrm{dr}-\frac{2\left(3rx+m\right)\mathrm{du}}{r}\mathrm{du}-\frac{r^2\mathrm{dx}}{4x^3}\mathrm{dx}-\frac{r^2\mathrm{dy}}{4x^3}\mathrm{dy}$

NT := evalDG([D_r, (3*x*r+m)*D_r/r+D_u, I*sqrt(2)*x^(3/2)*D_x/r+sqrt(2)*x^(3/2)*D_y/r, -I*sqrt(2)*x^(3/2)*D_x/r+sqrt(2)*x^(3/2)*D_y/r]);

$\mathrm{NT}≔\left[\mathrm{D\_r}\,\frac{\left(3rx+m\right)\mathrm{D\_r}}{r}+\mathrm{D\_u}\,\frac{\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_x}}{r}+\frac{\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_y}}{r}\,-\frac{\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_x}}{r}+\frac{\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_y}}{r}\right]$

OT := OrthonormalTetrad(NT);

$\mathrm{OT}≔\left[\frac{\sqrt{2}\left(3rx+m+r\right)\mathrm{D\_r}}{2r}+\frac{\sqrt{2}\mathrm{D\_u}}{2}\,\frac{2x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_y}}{r}\,\frac{2x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{D\_x}}{r}\,-\frac{\sqrt{2}\left(3rx+m-r\right)\mathrm{D\_r}}{2r}-\frac{\sqrt{2}\mathrm{D\_u}}{2}\right]$

sigma := SolderForm(OT);

$\mathrm{\sigma }≔\mathrm{dr}\mathrm{D\_z1}\mathrm{D\_w1}-\frac{\left(3rx+m\right)\mathrm{du}}{r}\mathrm{D\_z1}\mathrm{D\_w1}+\mathrm{du}\mathrm{D\_z2}\mathrm{D\_w2}-\frac{\frac{\mathrm{I}}{4}r\sqrt{2}\mathrm{dx}}{x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}\mathrm{D\_z1}\mathrm{D\_w2}+\frac{\frac{\mathrm{I}}{4}r\sqrt{2}\mathrm{dx}}{x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}\mathrm{D\_z2}\mathrm{D\_w1}+\frac{r\sqrt{2}\mathrm{dy}}{4x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}\mathrm{D\_z1}\mathrm{D\_w2}+\frac{r\sqrt{2}\mathrm{dy}}{4x^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}\mathrm{D\_z2}\mathrm{D\_w1}$

convert(D_r, DGspinor, sigma, [1]);

$\mathrm{D\_z1}\mathrm{D\_w1}$

SpinorInnerProduct(sigma, sigma);

$\mathrm{dr}\mathrm{du}+\mathrm{du}\mathrm{dr}-\frac{2\left(3rx+m\right)\mathrm{du}}{r}\mathrm{du}-\frac{r^2\mathrm{dx}}{4x^3}\mathrm{dx}-\frac{r^2\mathrm{dy}}{4x^3}\mathrm{dy}$

WeylSpinor(sigma);

$\frac{m\mathrm{dz1}}{r^3}\mathrm{dz1}\mathrm{dz2}\mathrm{dz2}+\frac{m\mathrm{dz1}}{r^3}\mathrm{dz2}\mathrm{dz1}\mathrm{dz2}+\frac{m\mathrm{dz1}}{r^3}\mathrm{dz2}\mathrm{dz2}\mathrm{dz1}+\frac{3\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{dz1}}{r^2}\mathrm{dz2}\mathrm{dz2}\mathrm{dz2}+\frac{m\mathrm{dz2}}{r^3}\mathrm{dz1}\mathrm{dz1}\mathrm{dz2}+\frac{m\mathrm{dz2}}{r^3}\mathrm{dz1}\mathrm{dz2}\mathrm{dz1}+\frac{3\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{dz2}}{r^2}\mathrm{dz1}\mathrm{dz2}\mathrm{dz2}+\frac{m\mathrm{dz2}}{r^3}\mathrm{dz2}\mathrm{dz1}\mathrm{dz1}+\frac{3\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{dz2}}{r^2}\mathrm{dz2}\mathrm{dz1}\mathrm{dz2}+\frac{3\mathrm{I}\sqrt{2}{x}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}\mathrm{dz2}}{r^2}\mathrm{dz2}\mathrm{dz2}\mathrm{dz1}-\frac{18x^2\mathrm{dz2}}{r^2}\mathrm{dz2}\mathrm{dz2}\mathrm{dz2}$

U := D_r;

$U≔\mathrm{D\_r}$

V := evalDG((3*x*r+m)*D_r/r+D_u);

$V≔\frac{\left(3rx+m\right)\mathrm{D\_r}}{r}+\mathrm{D\_u}$

W := WeylTensor(g8):

GRQuery(U, g8, W, "PrincipalNullDirection");

$\mathrm{true}$

CongruenceProperties(g8, U, V);

$table\left(\left[''RotationScalar''=0\,''RotationNormSquared''=0\,''Raychaudhuri''=0\,''RotationTensor''=0\mathrm{dr}\mathrm{dr}\,''ShearNormSquared''=0\,''Expansion''=\frac{2}{r}\,''ShearTensor''=0\mathrm{dr}\mathrm{dr}\right]\right)$

DGsetup([t, x, y, z], M10);

$\mathrm{frame\; name:\; M10}$

g10 := evalDG(4/3*t^2* dx &t dx + t*(exp(-2*x)* dy &t dy + exp(2*x)*dz &t dz) - dt &t dt);

$\mathrm{g10}≔-\mathrm{dt}\mathrm{dt}+\frac{4t^2\mathrm{dx}}{3}\mathrm{dx}+t{\ⅇ}^{-2x}\mathrm{dy}\mathrm{dy}+t{\ⅇ}^{2x}\mathrm{dz}\mathrm{dz}$

RainichConditions(g10);

$\mathrm{true}$

F := RainichElectromagneticField(g10);

$F≔\frac{2\cos \left(\mathrm{c\_\_1}\right)\left(1+\mathrm{csgn}\left(\frac{1}{t^2}\right)\right)\mathrm{dt}}{\sqrt{6\mathrm{csgn}\left(\frac{1}{t^2}\right)+6}}\bigwedge \mathrm{dx}+\frac{\sin \left(\mathrm{c\_\_1}\right)\left(1+\mathrm{csgn}\left(\frac{1}{t^2}\right)\right)\mathrm{csgn}\left(\frac{1}{t^2}\right)\mathrm{dy}}{\sqrt{2\mathrm{csgn}\left(\frac{1}{t^2}\right)+2}}\bigwedge \mathrm{dz}$

F := simplify(F) assuming t > 0;

$F≔\frac{2\cos \left(\mathrm{c\_\_1}\right)\sqrt{3}\mathrm{dt}}{3}\bigwedge \mathrm{dx}+\sin \left(\mathrm{c\_\_1}\right)\mathrm{dy}\bigwedge \mathrm{dz}$

T := EnergyMomentumTensor("Electromagnetic", g10, F); E := EinsteinTensor(g10); E &minus T;

$T≔\frac{\mathrm{D\_t}}{2t^2}\mathrm{D\_t}-\frac{3\mathrm{D\_x}}{8t^4}\mathrm{D\_x}+\frac{{\ⅇ}^{2x}\mathrm{D\_y}}{2t^3}\mathrm{D\_y}+\frac{{\ⅇ}^{-2x}\mathrm{D\_z}}{2t^3}\mathrm{D\_z}$

$E≔\frac{\mathrm{D\_t}}{2t^2}\mathrm{D\_t}-\frac{3\mathrm{D\_x}}{8t^4}\mathrm{D\_x}+\frac{{\ⅇ}^{2x}\mathrm{D\_y}}{2t^3}\mathrm{D\_y}+\frac{{\ⅇ}^{-2x}\mathrm{D\_z}}{2t^3}\mathrm{D\_z}$

$0\mathrm{D\_t}\mathrm{D\_t}$

MatterFieldEquations("Electromagnetic", g10, F);

$0\mathrm{D\_t},0\mathrm{dt}\bigwedge \mathrm{dx}\bigwedge \mathrm{dy}$

Transformation between space-times can be constructed. See Transformation, Pullback, Pushforward 

The Segre classification of space-time can be calculated.

The KillingVector and PetrovType commands support case-splitting for metrics which depend upon arbitrary parameters or functions.

Killing tensors, Killing-Yano tensors, Killing spinors and recurrent tensors can all be calculated.  

The LieAlgebras package provides all the tools needed for a complete algebraic analysis of the Killing vectors of a space-time.

The isotropy subalgebra and isotropy type of a Lie algebra of Killing vectors can be determined. These are useful properties for classifying Killing vectors.

Invariant metrics for any Lie algebra of vector fields can be easily computed using the command InvariantGeometricObjectFields in the GroupActions package.

Residual diffeomorphism groups for reductions of space-times can be calculated with the command InfinitisimalPseudoGroupNormalizer 

Future releases of DifferentialGeometry will include commands for working with the Einstein-Yang-Mills equations and for abstractly solving the Einstein equations on homogeneous spaces and low cohomogeneity manifolds.