Number(self): return the number of iterations required to step through the iterator, assuming it started at rank one.

Rank(self,L): return the rank of the current iteration. Optionally pass L, a list or one-dimensional rtable, and return its rank.

Unrank(self,rnk): return a one-dimensional Array corresponding to the iterator output with rank rnk.

VecToStr := proc(V)
local i;
    cat("",seq('(i,`if`(V[i]=0,"+","*"))',i=1..8),"9=100")
end proc:

$\mathrm{iter}≔\mathrm{BinaryGrayCode}\left(8\right)$

$\mathrm{iter}≔\mathrm{BinaryGrayCode}\left(8\right)$

$$\begin{gathered} \mathbf{for}v\mathbf{in}\mathrm{iter}\mathbf{do} \\ s≔\mathrm{VecToStr}\left(v\right); \\ \mathbf{if}\mathrm{parse}\left(s\right)\mathbf{then} \\ \mathrm{printf}\left(''\%s\backslash n''\,s\right) \\ \mathbf{end}\mathbf{if} \\ \mathbf{end}\mathbf{do}\: \end{gathered}$$

1*2*3*4+5+6+7*8+9=100
1*2*3+4+5+6+7+8*9=100
1+2+3+4+5+6+7+8*9=100

Permanent := proc(M::Matrix)
local G, J, V, aj, g, h, i, k, m, n, s, sj, sig;
    m, n := op(1, M);
    if m <> n then
        error "expecting a square Matrix, got dimensions %1, %2", m, n
    end if;
    G := Iterator:-BinaryGrayCode(n,'append_change');
    V := Vector(n);
    (h,g) := ModuleIterator(G);
    h();
    J := g();
    s := 0;
    sig := -1;
    while h() do
        sj := sign(J[-1]);
        aj := abs(J[-1]);
        for i to n do
            V[i] := V[i] + sj * M[i,aj];
        end do;
        s := s + sig*mul(V[k], k=1..n);
        sig := -sig;
    end do;
    expand((-1)^n*s);
end proc:

$M≔\mathrm{Matrix}\left(11\&comma;\mathrm{rand}\left(11\right)\right)\&colon;$

$\mathrm{CodeTools}:-\mathrm{Usage}\left(\mathrm{Permanent}\left(M\right)\right)$

memory used=1.78MiB, alloc change=0 bytes, cpu time=39.00ms, real time=40.00ms, gc time=0ns

$4852455795314422$

$\mathrm{CodeTools}:-\mathrm{Usage}\left(\mathrm{LinearAlgebra}:-\mathrm{Permanent}\left(M\right)\right)$

memory used=3.10MiB, alloc change=0 bytes, cpu time=37.00ms, real time=38.00ms, gc time=0ns

$4852455795314422$