The binary member selection operator, $:-$, is used to name module exports outside the scope in which they are defined. It is a non-commutative, left-associative operator. The first (left) operand is evaluated and must evaluate to a module. The second (right) operand is not evaluated and must be a symbol exported by the module to which the first operand evaluates.

Important: It is a syntax error for the second operand of the $:-$ operator to be other than a symbol. It is a runtime error for the first operand of the $:-$ operator to evaluate to anything other than a module.

The $:-$ operator can also be used as a unary, prefix operator, whose sole operand is a symbol. The expression :-sym evaluates to the global instance of $\mathrm{sym}$, even if there is a local binding for $\mathrm{sym}$ in scope.

The fact that the second operand of the $:-$ operator is not evaluated can be problematic when you want to construct the member selection expression dynamically using an export name that is provided at runtime. For this reason, the indexing operation ($\left[\right]$) has been overloaded in such a way that, for a module m, the expression m[e] evaluates to the member selection expression $m:-f$ after first evaluating the expression e, resulting in $f$.

Since the subexpression e in m[e] is evaluated, it is often necessary to use unevaluation (right) quotes when accessing module members using this syntax, with e a name. Moreover, if a local name with the same external representation is in scope, the unary prefix form of the $:-$ operator must be used (assuming that the index is supposed to be a global name). For example, to call the exported procedure Chi of the combinat package, use combinat[':-Chi']. (Alternatively, since the combinat package is implemented as a module, you could equally use combinat:-Chi, but the latter syntax works only with module-based packages.) See also UsingPackages.

$m≔\mathbf{module}\left(\right)\mathrm{\_export}\left(e\right)\;e≔2\mathbf{end\; module}\:$

$m:-e$

$2$

$m:-f$

Error, module does not export `f`

$\mathrm{StringTools}:-\mathrm{Reverse}\left(''abc''\right)$

$''cba''$

$S≔\mathrm{SimpleStack}\left(a\,b\,c\right)\:$

$S:-\mathrm{pop}\left(\right)\;$$S:-\mathrm{pop}\left(\right)\;$$S:-\mathrm{pop}\left(\right)$

$c$

$b$

$a$

$\mathrm{with}\left(\mathrm{combinat}\right)\:$

$\mathrm{Chi}\left(1.+\mathrm{I}\right)$

Error, (in combinat:-Chi) two partitions of the same sum expected

$:-\mathrm{Chi}\left(1.+\mathrm{I}\right)$

$0.8821721806+1.283547193\mathrm{I}$

$r≔\mathrm{Record}\left('a'=2\,'b'=3\,'c'=4\right)\:$

$r:-a,r:-b,r:-c$

$2,3,4$

$\mathrm{slots}≔\mathrm{seq}\left(r\left[e\right]\,e=\left[a\,b\,c\right]\right)$

$\mathrm{slots}≔2,3,4$

Q := module()
 export    `+`;
 `+` := proc( a, b )
    local    answer;
    if andmap(type,[a,b],'specfunc( algebraic, :-QUAT )' )
     and map( nops, [ a, b ] ) = [ 4, 4 ] then
      answer := ':-QUAT'( seq( op( i, a ) + op( i, b ), i = 1 .. 4 ) );
      if andmap( Testzero, [op]( 2 .. 4, answer ) ) then
        op( 1, answer )
      else
        answer
      end if
    elif type(a,'specfunc( algebraic, :-QUAT )' ) then
      procname( a, ':-QUAT'( b, 0, 0, 0 ) )
    elif type(b,'specfunc( algebraic, :-QUAT )' ) then
      procname( ':-QUAT'( a, 0, 0, 0 ), b )
    else
      # Call the global `+`
      :-`+`( a, b )
    end if;
  end proc;
end module:

$\mathbf{use}Q\mathbf{in}\'\mathrm{QUAT}\'\left(1\,2\,3\,4\right)\+\'\mathrm{QUAT}\'\left(1\,-2\,-3\,-4\right)\+x\;\'\mathrm{QUAT}\'\left(1\,2\,3\,4\right)\+\'\mathrm{QUAT}\'\left(-1\,2\,4\,3-y\right)\+x\;2x\+y\mathbf{end\; use}$

$2x+y$

$\mathrm{midpoint}≔2\:$

p1 := proc(a, b)
    local    midpoint;
    midpoint := 3;
    2 * student[ ':-midpoint' ]( a, b ) / midpoint
end proc:

p2 := proc(a, b)
    local    midpoint;
    midpoint := 3;
    2 * student[ 'midpoint' ]( a, b ) / midpoint
end proc:

p3 := proc(a, b)
    local    midpoint;
    midpoint := 3;
    2 * student[ :-midpoint ]( a, b ) / midpoint
end proc:

$\mathrm{p1}\left(\left[1\,2\right]\,\left[3\,4\right]\right)$

$\left[\frac{4}{3}\,2\right]$

$\mathrm{p2}\left(\left[1\,2\right]\,\left[3\,4\right]\right)$

$\frac{2\mathrm{student}\left[\mathrm{midpoint}\right]\left(\left[1\,2\right]\,\left[3\,4\right]\right)}{3}$

$\mathrm{p3}\left(\left[1\,2\right]\,\left[3\,4\right]\right)$

$\frac{2\mathrm{student}\left[2\right]\left(\left[1\,2\right]\,\left[3\,4\right]\right)}{3}$