If infolevel is set to a greater integer (possible settings are 1 through 5), more detailed information about the computation method is displayed.

with(DEtools):

with(PDEtools, declare):

declare(y(x), prime=x); # Turn ON the enhanced DEdisplay feature

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

infolevel[dsolve] := 3;

${\mathrm{infolevel}}_{\mathrm{dsolve}}≔3$

ode1 := diff(y(x), x)-y(x)^2+y(x)*sin(x)-cos(x);

$\mathrm{ode1}≔\mathrm{y\text{'}}-y^2+y\sin \left(x\right)-\cos \left(x\right)$

This ODE is recognized by the system as of Riccati type

odeadvisor(ode1);

$\left[\mathrm{\_Riccati}\right]$

and solved accordingly:

dsolve(ode1);

Methods for first order ODEs:
--- Trying classification methods ---
trying a quadrature
trying 1st order linear
trying Bernoulli
trying separable
trying inverse linear
trying homogeneous types:
trying Chini
differential order: 1; looking for linear symmetries
trying exact
Looking for potential symmetries
trying Riccati
trying Riccati sub-methods:
   <- Riccati with symmetry of the form [0, exp(-Int(f,x))/P*(y*P-f)^2] successful

$y=-\frac{{\&ExponentialE;}^{-\cos \left(x\right)}}{\mathrm{c\_\_1}+\int {\&ExponentialE;}^{-\cos \left(x\right)}\&DifferentialD;x}+\sin \left(x\right)$

To know more about this type of ODE and related solving methods one can give the extra argument help:

odeadvisor(ode1, help);

A table with all the classifications recognized in Maple is found at odeadvisor, classifications.

A linear ODE

ode_L := sin(x)*diff(y(x), x)-cos(x)*y(x)=0;

$\mathrm{ode\_L}≔\mathrm{y\text{'}}\sin \left(x\right)-\cos \left(x\right)y=0$

Although dsolve has its own strategy and defaults, one can also indicate to dsolve the use of any specific sequence of 'methods' to tackle the ODE. In this example the method for 'linear' ODEs is specified; in addition the optional argument 'useInt' makes dsolve not evaluating the integral appearing in the answer

dsolve(ode_L, [linear], useInt);

Classification methods on request
Methods to be used are: [linear]
----------------------------
* Tackling ODE using method: linear
--- Trying classification methods ---
trying 1st order linear
<- 1st order linear successful

$y=\mathrm{c\_\_1}{\&ExponentialE;}^{\int \cot \left(x\right)\&DifferentialD;x}$

Solutions like this one - before evaluating integrals - are useful to understand how the solution was obtained; integrals can be evaluated afterwards using value

value((7));

$y=\mathrm{c\_\_1}\sin \left(x\right)$

This particular linear ODE is also separable, hence it can also be solved via

dsolve(ode_L, [separable], useInt);

Classification methods on request
Methods to be used are: [separable]
----------------------------
* Tackling ODE using method: separable
--- Trying classification methods ---
trying separable
<- separable successful

$\int \cot \left(x\right)\&DifferentialD;x-\left({\int }_{\phantom{\mathrm{`\; `}}}^y\frac{1}{\mathrm{\_a}}\&DifferentialD;\mathrm{\_a}\right)+\mathrm{c\_\_1}=0$

value((9));

$\ln \left(\sin \left(x\right)\right)-\ln \left(y\right)+\mathrm{c\_\_1}=0$

The linear first order ODE of the previous section can be solved by first determining an integrating factor for it

mu := intfactor(ode_L);

$\mathrm{\mu }≔\frac{1}{{\sin \left(x\right)}^2}$

Integrating factors turn ODEs exact, that is: the product $\mathrm{\mu }$ times the ODE is a total derivative. One can combine the determination of an integrating factor with indicating to dsolve the use of the method for exact ODEs:

dsolve(mu * ode_L, [exact]);

Classification methods on request
Methods to be used are: [exact]
----------------------------
* Tackling ODE using method: exact
--- Trying classification methods ---
trying exact
<- exact successful

$y=-\frac{\mathrm{c\_\_1}}{\csc \left(x\right)}$

simplify(convert((12), sincos));

$y=-\mathrm{c\_\_1}\sin \left(x\right)$

For linear ODEs (LODEs) of order 2 or greater, it is possible to calculate integrating factors by solving the adjoint of the LODE. This could be as difficult as the original problem, or much easier, depending on the example. The set of DEtools available permits a discussion of such a strategy in details.

ode := diff(y(x), x, x) =
(y(x)*x+y(x)*ln(x)*x^2+diff(y(x), x)*ln(x)*x^2)/ln(x)/x^2*exp(x)-
y(x)/ln(x)/x^2;

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}=\frac{\left(yx+y\ln \left(x\right)x^2+\mathrm{y\text{'}}\ln \left(x\right)x^2\right){\&ExponentialE;}^x}{\ln \left(x\right)x^2}-\frac{y}{\ln \left(x\right)x^2}$

This ODE has the following adjoint

DEtools[adjoint](ode, y(x));

$-\frac{\left({\&ExponentialE;}^{x}x-1\right)y}{\ln \left(x\right)x^2}+{\&ExponentialE;}^x\mathrm{y\text{'}}+\mathrm{y\text{'}\text{'}}$

This adjoint equation is in turn solvable by dsolve

dsolve((15));

Methods for second order ODEs:
--- Trying classification methods ---
trying a symmetry of the form [xi=0, eta=F(x)]
   <- BRANCH 2 successful. Symmetry is:, [0, exp(Int(1/x/ln(x),x))]
<- linear_1 successful

$y=\left(\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\mathrm{c\_\_1}+\mathrm{c\_\_2}\right)\ln \left(x\right)$

Now the solutions to the adjoint equation are integrating factors of the original LODE, so the two independent solutions implied in the general solution above

eval(rhs((16)), {_C1=0, _C2=1});

$\ln \left(x\right)$

eval(rhs((16)), {_C1=1, _C2=2});

$\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x+2\right)\ln \left(x\right)$

are integrating factors of ode. These integrating factors could also be found using the intfactor directly

Mu := intfactor(ode);

trying a symmetry of the form [xi=0, eta=F(x)]<- linear_1 successful
Trying an integrating factor as the solution to the adjoint linear ODE
trying a symmetry of the form [xi=0, eta=F(x)]
<- linear_1 successful

$\mathrm{The\; integrating\; factors\; are:},\left[\ln \left(x\right)\&comma;\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\ln \left(x\right)\right]$

$\mathrm{{\rm M}}≔\ln \left(x\right),\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\ln \left(x\right)$

How are these integrating factors transformed into a solution to the original problem? By using them to construct two first integrals; that is: two ODEs of lower order (in this case two first order ODEs). For that purpose it is provided the firint command which receives an exact ODE and returns a first integral. The idea is simple: an exact ODE is a total derivative - say dR/dx; firint returns the R + _C1:

firint(Mu[1]*ode);

$-\frac{\left(\ln \left(x\right)x^2{\&ExponentialE;}^x+x\right)y}{x^2}+\ln \left(x\right)\mathrm{y\text{'}}+\mathrm{c\_\_1}=0$

firint(Mu[2]*ode);

$-\frac{\left(\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right){\ln \left(x\right)}^2{\&ExponentialE;}^x{x}^2+\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\ln \left(x\right)x+{\&ExponentialE;}^{-{\&ExponentialE;}^x}{x}^2\right)y}{\ln \left(x\right)x^2}+\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\ln \left(x\right)\mathrm{y\text{'}}+\mathrm{c\_\_1}=0$

Eliminating y' from these two first integrals (and replacing _C1 by _C2 in one of them) leads to the solution $f\left(x\&comma;y\&comma;\mathrm{c\_\_1}\&comma;\mathrm{c\_\_2}\right)=0$ to this ode. So all this process could be ran interactively, as shown, or in one step

dsolve(ode);

Methods for second order ODEs:
--- Trying classification methods ---
trying a symmetry of the form [xi=0, eta=F(x)]
checking if the LODE is missing 'y'
-> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius'
-> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f)
-> Trying changes of variables to rationalize or make the ODE simpler
   trying a symmetry of the form [xi=0, eta=F(x)]
   checking if the LODE is missing 'y'
   -> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius'
   -> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f)
   -> Tackling the "Normal Form" of the given linear ODE:
      trying a symmetry of the form [xi=0, eta=F(x)]
   -> Tackling the linear ODE using alternative approaches:
      trying 2nd order exact linear
      trying symmetries linear in x and y(x)
      trying to convert to a linear ODE with constant coefficients
         testing BRANCH 1 ->
   trying a symmetry of the form [xi=0, eta=F(x)]
   checking if the LODE is missing 'y'
   -> Heun: Equivalence to the GHE or one of its 4 confluent cases under 'a power @ Moebius'
   -> trying a solution of the form r0(x) * Y + r1(x) * Y' where Y = exp(int(r(x), dx)) * 2F1([a1, a2], [b1], f)
   -> Tackling the "Normal Form" of the given linear ODE:
      trying a symmetry of the form [xi=0, eta=F(x)]
   -> Tackling the linear ODE using alternative approaches:
      trying 2nd order exact linear
      trying symmetries linear in x and y(x)
      trying to convert to a linear ODE with constant coefficients
         testing BRANCH 1 ->
<- unable to find a useful change of variables
-> Tackling the "Normal Form" of the given linear ODE:
   trying a symmetry of the form [xi=0, eta=F(x)]
-> Tackling the linear ODE using alternative approaches:
   trying 2nd order exact linear
   trying symmetries linear in x and y(x)
   trying to convert to a linear ODE with constant coefficients
      testing BRANCH 1 ->
   trying 2nd order, integrating factor of the form mu(x,y)
   <- 2nd order, integrating factors of the form mu(x,y) successful

$y=\mathrm{c\_\_1}{\&ExponentialE;}^{{\&ExponentialE;}^x}\ln \left(x\right)+\mathrm{c\_\_2}{\&ExponentialE;}^{{\&ExponentialE;}^x}\left(\int \frac{{\&ExponentialE;}^{-{\&ExponentialE;}^x}}{{\ln \left(x\right)}^2}\&DifferentialD;x\right)\ln \left(x\right)$

There are algorithms in dsolve for determining integrating factors for nonlinear ODEs too:

for second order ODEs, integrating factors depending on two variables (x, y) or (x, y') or (y, y') - when they exist - can be systematically determined;

for third order ODEs, integrating factors depending only on (y'') can also be systematically determined.

infolevel[dsolve] := 0;     # Turn OFF userinfos for dsolve

${\mathrm{infolevel}}_{\mathrm{dsolve}}≔0$

ode := diff(y(x), x, x, x) = -diff(y(x), x, x)^2/diff(y(x), x);

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}\text{'}}=-\frac{{\mathrm{y\text{'}\text{'}}}^2}{\mathrm{y\text{'}}}$

For this ODE, three integrating factors are

intfactor((24));

$\mathrm{y\text{'}},\mathrm{y\text{'}}x,\frac{1}{\mathrm{y\text{'}\text{'}}}$

The product of any of them times the ode is a total derivative, from where a first integral can be obtained; for instance taking the third one

firint((25)[3] * ode);

$\ln \left(\mathrm{y\text{'}}\right)+\ln \left(\mathrm{y\text{'}\text{'}}\right)+\mathrm{c\_\_1}=0$

Solving for y'' this reduced ODE,

isolate((26), diff(y(x), x, x));

$\mathrm{y\text{'}\text{'}}=\frac{1}{\mathrm{y\text{'}}{\&ExponentialE;}^{\mathrm{c\_\_1}}}$

we are able to calculate more integrating factors (in this case intfactor succeeds again):

intfactor((27));

$\mathrm{y\text{'}}$

and obtain a lower order first integral as in the previous step

firint((28) * ((27)));

${\mathrm{y\text{'}}}^2-\frac{2x}{{\&ExponentialE;}^{\mathrm{c\_\_1}}}+\mathrm{c\_\_2}=0$

Finally, this is a simple first order ODE which can be solved directly, leading to the general solution for the original ode problem:

dsolve((29));

$y=-\frac{\left(\mathrm{c\_\_2}{\&ExponentialE;}^{\mathrm{c\_\_1}}-2x\right)\sqrt{-{\&ExponentialE;}^{\mathrm{c\_\_1}}\left(\mathrm{c\_\_2}{\&ExponentialE;}^{\mathrm{c\_\_1}}-2x\right)}}{3{\&ExponentialE;}^{\mathrm{c\_\_1}}}+\mathrm{c\_\_3},y=\frac{\left(\mathrm{c\_\_2}{\&ExponentialE;}^{\mathrm{c\_\_1}}-2x\right)\sqrt{-{\&ExponentialE;}^{\mathrm{c\_\_1}}\left(\mathrm{c\_\_2}{\&ExponentialE;}^{\mathrm{c\_\_1}}-2x\right)}}{3{\&ExponentialE;}^{\mathrm{c\_\_1}}}+\mathrm{c\_\_3}$

map(odetest, [(30)], ode);

$\left[0\&comma;0\right]$

where in above we map the odetest command over each of the solutions. As a general comment, the integration constants entering the general solution of an ODE are arbitrary, we can always rename ${\&ExponentialE;}^{\mathrm{\_C1}}\to \mathrm{\_C1}$, simplifying a bit the solution. This ode here solved using the integrating factor approach can also be solved using the symmetry approach (following the steps shown in the next section).

Also interesting in the integrating factor approach is the inverse problem; that is: to determine the most general ODE family having a given integrating factor (related worked examples are found in redode).

The following worked example aims at illustrating how the solving process can be performed step-by-step, using the symmetry approach, and with instructions easy to re-use. The commands to be used are: symgen (for calculating the symmetries), reduce_order (for reducing the order using these symmetries), and buildsol (to build the solution to the original problem from the solutions to the reduced ODE problems)

This is a fifth order ODE (from Kamke's book, high order ODE example 17):

ode5 := 9*diff(y(x), x, x)^2*diff(y(x), x, x, x, x, x)
- 45*diff(y(x), x, x)*diff(y(x), x, x, x)*diff(y(x), x, x, x, x) +
40*diff(y(x), x, x, x)=0;

$\mathrm{ode5}≔9{\mathrm{y\text{'}\text{'}}}^2\mathrm{y\text{'}\text{'}\text{'}\text{'}\text{'}}-45\mathrm{y\text{'}\text{'}}\mathrm{y\text{'}\text{'}\text{'}}\mathrm{y\text{'}\text{'}\text{'}\text{'}}+40\mathrm{y\text{'}\text{'}\text{'}}=0$

Classifying using odeadvisor (classifying ODEs is now a menu option available when "right clicking" on the ODE above)

odeadvisor(ode5);

$\left[\left[\mathrm{\_high\_order}\&comma;\mathrm{\_missing\_x}\right]\&comma;\left[\mathrm{\_high\_order}\&comma;\mathrm{\_missing\_y}\right]\&comma;\left[\mathrm{\_high\_order}\&comma;\mathrm{\_with\_linear\_symmetries}\right]\right]$

it is apparent that there are various possible departure points to start reducing the ODE order: the ODE is missing the dependent and independent variables, it also has linear symmetries. In connection with all these starting points there are the symmetries:

X5 := symgen(ode5);

$\mathrm{X5}≔\left[\mathrm{\_\&xi;}=0\&comma;\mathrm{\_\&eta;}=1\right],\left[\mathrm{\_\&xi;}=1\&comma;\mathrm{\_\&eta;}=0\right],\left[\mathrm{\_\&xi;}=0\&comma;\mathrm{\_\&eta;}=x\right],\left[\mathrm{\_\&xi;}=1\&comma;\mathrm{\_\&eta;}=x\right],\left[\mathrm{\_\&xi;}=\frac{x}{3}\&comma;\mathrm{\_\&eta;}=y\right]$

The result above means, basically, that dsolve is able to solve the ODE by itself. With the purpose of illustrating the method, these symmetries are used below interactively to solve the ODE. The simplest manner of doing that is: reduce the order of the ODE by one and restart the discussion around this reduced ODE. When this approach is successful, build the solution to the original problem from the solution to the last reduced ODE. The steps below can be re-used with others ODE examples, as for instance the one solved interactively in the previous section by using integrating factors.

So we start reducing the order using just one of the symmetries above

OFF;    # Turn OFF the enhanced DEdisplay feature

R_5_to_4 := reduce_order(ode5, X5[1], u(t));

$\mathrm{R\_5\_to\_4}≔y\left(x\right)=\left(\int u\left(t\right)\&DifferentialD;t+\mathrm{c\_\_1}\right)\mathbf{where}\left[\left\{\frac{{\&DifferentialD;}^4}{\&DifferentialD;t^4}u\left(t\right)=\frac{5\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;t^2}u\left(t\right)\right)\left(\frac{{\&DifferentialD;}^3}{\&DifferentialD;t^3}u\left(t\right)\right)}{\frac{\&DifferentialD;}{\&DifferentialD;t}u\left(t\right)}-\frac{40\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;t^2}u\left(t\right)\right)}{9{\left(\frac{\&DifferentialD;}{\&DifferentialD;t}u\left(t\right)\right)}^2}\right\}\&comma;\left\{t=x\&comma;u\left(t\right)=\frac{\&DifferentialD;}{\&DifferentialD;x}y\left(x\right)\right\}\&comma;\left\{x=t\&comma;y\left(x\right)=\int u\left(t\right)\&DifferentialD;t+\mathrm{c\_\_1}\right\}\right]$

The structure of the solution above contains the answer in terms of a new function, u(t), which satisfy the fourth order differential equation being shown.

Now select this fourth order ODE and consider the same cycle again (finding symmetries plus reducing its order again):

ode4 := op([2, 2, 1, 1], R_5_to_4);

$\mathrm{ode4}≔\frac{{\&DifferentialD;}^4}{\&DifferentialD;t^4}u\left(t\right)=\frac{5\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;t^2}u\left(t\right)\right)\left(\frac{{\&DifferentialD;}^3}{\&DifferentialD;t^3}u\left(t\right)\right)}{\frac{\&DifferentialD;}{\&DifferentialD;t}u\left(t\right)}-\frac{40\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;t^2}u\left(t\right)\right)}{9{\left(\frac{\&DifferentialD;}{\&DifferentialD;t}u\left(t\right)\right)}^2}$

X4 := symgen(ode4);

$\mathrm{X4}≔\left[\mathrm{\_\&xi;}=0\&comma;\mathrm{\_\&eta;}=1\right],\left[\mathrm{\_\&xi;}=1\&comma;\mathrm{\_\&eta;}=0\right],\left[\mathrm{\_\&xi;}=1\&comma;\mathrm{\_\&eta;}=1\right],\left[\mathrm{\_\&xi;}=\frac{t}{2}\&comma;\mathrm{\_\&eta;}=u\right]$

With the symmetries of ode4 in hands we can proceed in the same way to obtain a reduction of order from 4 to 3, now expressing the third order differential equation in terms of a new function s(r)

R_4_to_3 := reduce_order(ode4, X4[1], s(r));

$\mathrm{R\_4\_to\_3}≔u\left(t\right)=\left(\int s\left(r\right)\&DifferentialD;r+\mathrm{c\_\_1}\right)\mathbf{where}\left[\left\{\frac{{\&DifferentialD;}^3}{\&DifferentialD;r^3}s\left(r\right)=\frac{5\left(\frac{\&DifferentialD;}{\&DifferentialD;r}s\left(r\right)\right)\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;r^2}s\left(r\right)\right)}{s\left(r\right)}-\frac{40\left(\frac{\&DifferentialD;}{\&DifferentialD;r}s\left(r\right)\right)}{9{s\left(r\right)}^2}\right\}\&comma;\left\{r=t\&comma;s\left(r\right)=\frac{\&DifferentialD;}{\&DifferentialD;t}u\left(t\right)\right\}\&comma;\left\{t=r\&comma;u\left(t\right)=\int s\left(r\right)\&DifferentialD;r+\mathrm{c\_\_1}\right\}\right]$

Selecting the third order ODE and calculating its symmetries leads to

ode3 := op([2, 2, 1, 1], R_4_to_3);

$\mathrm{ode3}≔\frac{{\&DifferentialD;}^3}{\&DifferentialD;r^3}s\left(r\right)=\frac{5\left(\frac{\&DifferentialD;}{\&DifferentialD;r}s\left(r\right)\right)\left(\frac{{\&DifferentialD;}^2}{\&DifferentialD;r^2}s\left(r\right)\right)}{s\left(r\right)}-\frac{40\left(\frac{\&DifferentialD;}{\&DifferentialD;r}s\left(r\right)\right)}{9{s\left(r\right)}^2}$

X3 := symgen(ode3);

$\mathrm{X3}≔\left[\mathrm{\_\&xi;}=1\&comma;\mathrm{\_\&eta;}=0\right],\left[\mathrm{\_\&xi;}=r\&comma;\mathrm{\_\&eta;}=s\right]$

These symmetries can be used to reduced the order further, obtaining a second order ODE - we choose z(v) as new unknown function:

R_3_to_2 := reduce_order(ode3, X3[1], z(v));

$\mathrm{R\_3\_to\_2}≔s\left(r\right)=v\mathbf{where}\left[\left\{\frac{{\&DifferentialD;}^2}{\&DifferentialD;v^2}z\left(v\right)=\frac{3{\left(\frac{\&DifferentialD;}{\&DifferentialD;v}z\left(v\right)\right)}^2}{z\left(v\right)}+\frac{40{z\left(v\right)}^3}{9v^2}+\frac{5\left(\frac{\&DifferentialD;}{\&DifferentialD;v}z\left(v\right)\right)}{v}\right\}\&comma;\left\{v=s\left(r\right)\&comma;z\left(v\right)=\frac{1}{\frac{\&DifferentialD;}{\&DifferentialD;r}s\left(r\right)}\right\}\&comma;\left\{r=\int z\left(v\right)\&DifferentialD;v+\mathrm{c\_\_1}\&comma;s\left(r\right)=v\right\}\right]$

ode2 := op([2, 2, 1, 1], R_3_to_2);

$\mathrm{ode2}≔\frac{{\&DifferentialD;}^2}{\&DifferentialD;v^2}z\left(v\right)=\frac{3{\left(\frac{\&DifferentialD;}{\&DifferentialD;v}z\left(v\right)\right)}^2}{z\left(v\right)}+\frac{40{z\left(v\right)}^3}{9v^2}+\frac{5\left(\frac{\&DifferentialD;}{\&DifferentialD;v}z\left(v\right)\right)}{v}$

One more cycle reduce the problem to a first order linear ODE which is a problem having solution in the general case in terms of integrals

X2 := symgen(ode2);

$\mathrm{X2}≔\left[\mathrm{\_\&xi;}=0\&comma;\mathrm{\_\&eta;}=z^3\right],\left[\mathrm{\_\&xi;}=v\&comma;\mathrm{\_\&eta;}=0\right]$

R_2_to_1 := reduce_order(ode2, X2[1], a(b));

$\mathrm{R\_2\_to\_1}≔z\left(v\right)=\left(\sqrt{-\frac{1}{2\left(\int a\left(b\right)\&DifferentialD;b+\mathrm{c\_\_1}\right)}}\right)\mathbf{where}\left[\left\{\frac{\&DifferentialD;}{\&DifferentialD;b}a\left(b\right)=\frac{5a\left(b\right)}{b}+\frac{40}{9b^2}\right\}\&comma;\left\{b=v\&comma;a\left(b\right)=\frac{\frac{\&DifferentialD;}{\&DifferentialD;v}z\left(v\right)}{{z\left(v\right)}^3}\right\}\&comma;\left\{v=b\&comma;z\left(v\right)=\sqrt{-\frac{1}{2\left(\int a\left(b\right)\&DifferentialD;b+\mathrm{c\_\_1}\right)}}\right\}\right]$

ode1 := op([2, 2, 1, 1], R_2_to_1);

$\mathrm{ode1}≔\frac{\&DifferentialD;}{\&DifferentialD;b}a\left(b\right)=\frac{5a\left(b\right)}{b}+\frac{40}{9b^2}$

The answer to this easy ODE found at the end of the reduction process is

sol1 := dsolve(ode1);

$\mathrm{sol1}≔a\left(b\right)=\left(-\frac{20}{27b^6}+\mathrm{c\_\_1}\right)b^5$

Now, how could we build the solution to the original fifth order ode5? As follows: first use this solution above to build the solution to ode2 (the second order ODE one step above and rename integration constants which appeared as _C1 in all reductions):

buildsol(subs(_C1=_C2, R_2_to_1), sol1);

$z\left(v\right)=\sqrt{-\frac{1}{2\left(\int \left(v^5\mathrm{c\_\_1}-\frac{20}{27v}\right)\&DifferentialD;v+\mathrm{c\_\_2}\right)}}$

The integral can be evaluated via

sol2 := value((47));

$\mathrm{sol2}≔z\left(v\right)=\sqrt{-\frac{1}{2\left(-\frac{20\ln \left(v\right)}{27}+\frac{\mathrm{c\_\_1}{v}^6}{6}+\mathrm{c\_\_2}\right)}}$

And now repeat the process until arriving at the solution to the original fifth order ode

sol3 := buildsol(subs(_C1=_C3, R_3_to_2), sol2);

$\mathrm{sol3}≔s\left(r\right)=\mathrm{RootOf}\left(-r+3\sqrt{3}\left({\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{\_Z}}\sqrt{-\frac{1}{9\mathrm{c\_\_1}{\mathrm{\_a}}^6-40\ln \left(\mathrm{\_a}\right)+54\mathrm{c\_\_2}}}\&DifferentialD;\mathrm{\_a}\right)+\mathrm{c\_\_3}\right)$

sol4 := buildsol(subs(_C1=_C4, R_4_to_3), sol3);

$\mathrm{sol4}≔u\left(t\right)=\int \mathrm{RootOf}\left(-t+3\sqrt{3}\left({\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{\_Z}}\sqrt{-\frac{1}{9\mathrm{c\_\_1}{\mathrm{\_a}}^6-40\ln \left(\mathrm{\_a}\right)+54\mathrm{c\_\_2}}}\&DifferentialD;\mathrm{\_a}\right)+\mathrm{c\_\_3}\right)\&DifferentialD;t+\mathrm{c\_\_4}$

sol5 := buildsol(subs(_C1=_C5, R_5_to_4), sol4);

$\mathrm{sol5}≔y\left(x\right)=\int \left(\int \mathrm{RootOf}\left(-x+3\sqrt{3}\left({\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{\_Z}}\sqrt{-\frac{1}{9\mathrm{c\_\_1}{\mathrm{\_a}}^6-40\ln \left(\mathrm{\_a}\right)+54\mathrm{c\_\_2}}}\&DifferentialD;\mathrm{\_a}\right)+\mathrm{c\_\_3}\right)\&DifferentialD;x+\mathrm{c\_\_4}\right)\&DifferentialD;x+\mathrm{c\_\_5}$

This result can be tested using odetest

odetest(sol5, ode5);

$0$

For more examples see dsolve, Lie, , reduce_order and the help pages linked from DEtools, Lie.

Also interesting in the symmetry approach is the inverse problem; that is: to determine the most general ODE family having given symmetries (see equinv), or the symmetries of an 'unknown' ODE when its solution is given (see buildsym). Combining these two tools it is possible to depart from the form of the solution and arrive at the most general ODE problem having the symmetries of that type of solution (examples are found in the mentioned help-pages).