Integrating factors - depending on two variables - for second order ODEs

For second order ODEs integrating factors depending on three variables, (x,y,y') always exist - their determination however may be as difficult as solving the ODEs themselves. However, integrating factors of the form mu(x,y), mu(x,y'), mu(y,y'), that is, depending on just two variables, when they exist, can be determined systematically (see E.S. Cheb-Terrab and A.D. Roche, "Integrating factors for second order ODEs", Journal of Symbolic Computation V. 27, No. 5 (1999) 501). This method is implemented in dsolve.

The main idea of this method consists of algorithmically determining whether or not a given second order ODE is member of one of the three reducible ODE families respectively admitting integrating factors of the forms mu(x,y), mu(x,y'), mu(y,y') (see redode):

with(DEtools,redode):

PDEtools[declare](y(x), prime=x);

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

subs(_F1 = G, redode(mu(x,y(x)),y(x),2) );            # ODE family admitting mu(x,y)

$\mathrm{y\text{'}\text{'}}=-\frac{{\mathrm{D}}_2\left(\mathrm{\mu }\right)\left(x\,y\right){\mathrm{y\text{'}}}^2+{\mathrm{D}}_1\left(\mathrm{\mu }\right)\left(x\,y\right)\mathrm{y\text{'}}+{\mathrm{D}}_2\left(G\right)\left(x\,y\right)\mathrm{y\text{'}}+{\mathrm{D}}_1\left(G\right)\left(x\,y\right)}{\mathrm{\mu }\left(x\,y\right)}$

convert( subs(diff(y(x),x,x) = `y''`, diff(y(x),x) = `y'`,y(x)=y,(2)), diff);

$\mathrm{y\text{'}\text{'}}=-\frac{{\mathrm{\mu }}_y{\mathrm{y\text{'}}}^2+{\mathrm{\mu }}_x\mathrm{y\text{'}}+G_y\mathrm{y\text{'}}+G_x}{\mathrm{\mu }\left(x\,y\right)}$

subs(_F1 = G, redode(mu(x,diff(y(x),x)),y(x),2) );    # ODE family admitting mu(x,y')

$\mathrm{y\text{'}\text{'}}=-\frac{{\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{y\text{'}}}{\mathrm{\mu }}_x\ⅆ\mathrm{\_a}+{\mathrm{D}}_1\left(G\right)\left(x\,y\right)+{\mathrm{D}}_2\left(G\right)\left(x\,y\right)\mathrm{y\text{'}}}{\mathrm{\mu }\left(x\,\mathrm{y\text{'}}\right)}$

convert( subs(diff(y(x),x,x) = `y''`, diff(y(x),x) = `y'`,y(x)=y,(4)), diff);

$\mathrm{y\text{'}\text{'}}=-\frac{{\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{y\text{'}}}{\mathrm{\mu }}_x\ⅆ\mathrm{\_a}+G_x+G_y\mathrm{y\text{'}}}{\mathrm{\mu }\left(x\,\mathrm{y\text{'}}\right)}$

subs(_F1 = G, redode(mu(y(x),diff(y(x),x)),y(x),2) ); # ODE family admitting mu(y,y')

$\mathrm{y\text{'}\text{'}}=-\frac{{\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{y\text{'}}}{\mathrm{D}}_1\left(\mathrm{\mu }\right)\left(y\,\mathrm{\_a}\right)\mathrm{y\text{'}}\ⅆ\mathrm{\_a}+{\mathrm{D}}_1\left(G\right)\left(x\,y\right)+{\mathrm{D}}_2\left(G\right)\left(x\,y\right)\mathrm{y\text{'}}}{\mathrm{\mu }\left(y\,\mathrm{y\text{'}}\right)}$

convert( subs(diff(y(x),x,x) = `y''`, diff(y(x),x) = `y'`,y(x)=y,(6)), diff);

$\mathrm{y\text{'}\text{'}}=-\frac{{\int }_{\phantom{\mathrm{`\; `}}}^{\mathrm{y\text{'}}}{\mathrm{\mu }}_y\mathrm{y\text{'}}\ⅆ\mathrm{\_a}+G_x+G_y\mathrm{y\text{'}}}{\mathrm{\mu }\left(y\,\mathrm{y\text{'}}\right)}$

and in doing that, determining mu. Concretely, this means that members of these three ODE families can now be systematically reduced to first order ODEs - for arbitrary mu and G - as if they were simple exact equations (total derivatives). This has enlarged in a noticeable way the decision procedures available for tackling second order ODEs in the nonlinear case.

with(DEtools, firint, intfactor, mutest, odeadvisor):

ode := diff(y(x),x,x) - diff(y(x),x)^2/y(x) + sin(x)*y(x)*diff(y(x),x) +
cos(x)*y(x)^2=0;

$\mathrm{ode}≔\mathrm{y\text{'}\text{'}}-\frac{{\mathrm{y\text{'}}}^2}{y}+\sin \left(x\right)y\mathrm{y\text{'}}+\cos \left(x\right)y^2=0$

Mu := intfactor(ode,y(x));

$\mathrm{{\rm M}}≔\frac{1}{y}$

mutest(Mu, ode);  # returns zero whem Mu is an integrating factor

$0$

first_integral := firint( Mu*ode, y(x));

$\mathrm{first\_integral}≔\sin \left(x\right)y+\frac{\mathrm{y\text{'}}}{y}+\mathrm{c\_\_1}=0$

odeadvisor(first_integral, y(x));

$\left[\mathrm{\_Bernoulli}\right]$

dsolve(first_integral);

odetest((13),ode);   # test this result

$0$

dsolve(ode, y(x));

dsolve(ode, y(x), [reducible]);

dsolve(ode, y(x), [mu_xy]);     # mu(x,y)

dsolve(ode, y(x), [mu_y_y1]);   # mu(y,y')

dsolve(ode, y(x), [mu_x_y1]);   # mu(x,y')

sys := DEtools[gensys](ode, [xi(x,y), eta(x,y)]);

$\mathrm{sys}≔-{\mathrm{\xi }}_{y,y}{y}^2-{\mathrm{\xi }}_{y}y,2{\mathrm{\xi }}_y\sin \left(x\right)y^3+{\mathrm{\eta }}_{y,y}{y}^2-2{\mathrm{\xi }}_{x,y}{y}^2-{\mathrm{\eta }}_{y}y+\mathrm{\eta }\left(x\,y\right),3{\mathrm{\xi }}_y\cos \left(x\right)y^4+{\mathrm{\xi }}_x\sin \left(x\right)y^3+\mathrm{\xi }\left(x\,y\right)\cos \left(x\right)y^3+\mathrm{\eta }\left(x\,y\right)\sin \left(x\right)y^2+2{\mathrm{\eta }}_{x,y}{y}^2-{\mathrm{\xi }}_{x,x}{y}^2-2{\mathrm{\eta }}_{x}y,2{\mathrm{\xi }}_x\cos \left(x\right)y^4-{\mathrm{\eta }}_y\cos \left(x\right)y^4-\mathrm{\xi }\left(x\,y\right)\sin \left(x\right)y^4+2\mathrm{\eta }\left(x\,y\right)\cos \left(x\right)y^3+{\mathrm{\eta }}_x\sin \left(x\right)y^3+{\mathrm{\eta }}_{x,x}{y}^2$

nops([sys]);        # number of PDEs in the resulting system

$4$

PDEtools[casesplit]([sys]);

$\left[\mathrm{\eta }\left(x\,y\right)=0\,\mathrm{\xi }\left(x\,y\right)=0\right]\mathbf{where}\left[\right]$