New user-level functionality for building case discussions of the solutions of polynomial equations are now available as the new SolveTools[Parametric] command, and the new parametric option for the solve command.

SolveTools[Parametric]({a*x}, {x}, {a});

$\left\{\begin{array}{cc}\left[\left\{x=x\right\}\right]& a=0\\ \left[\left\{x=0\right\}\right]& a\ne 0\end{array}\right.$

By default these new commands return piecewise answers containing answers for the most general cases and the other branches containing inert function calls.

result := SolveTools[Parametric]({a*x^2-(b+a)*x+b}, {x});

$\mathrm{result}≔\left\{\begin{array}{cc}{\mathrm{SolveTools}}_{\mathrm{Parametric}}\left(\left\{-xb+b\right\}\,\left\{x\right\}\,\left\{b\right\}\right)& a=0\\ \left[\left\{x=1\right\}\,\left\{x=\frac{b}{a}\right\}\right]& a\ne 0\end{array}\right.$

result := eval(result, a=0);

$\mathrm{result}≔{\mathrm{SolveTools}}_{\mathrm{Parametric}}\left(\left\{-xb+b\right\}\,\left\{x\right\}\,\left\{b\right\}\right)$

value(result);

$\left\{\begin{array}{cc}\left[\left\{x=x\right\}\right]& b=0\\ \left[\left\{x=1\right\}\right]& b\ne 0\end{array}\right.$

The new solve option does some additional processing of the input, but uses the same backend as SolveTools[Parametric] and produces the same answers.  See the solve/parametric help page for more details.

solve( a*x^2-(b+a)*x+b, x, 'parametric');

$\left\{\begin{array}{cc}{\mathrm{SolveTools}}_{\mathrm{Parametric}}\left(\left\{-xb+b\right\}\,\left\{x\right\}\,\left\{b\right\}\right)& a=0\\ \left[\left\{x=1\right\}\,\left\{x=\frac{b}{a}\right\}\right]& a\ne 0\end{array}\right.$

The sum command has been enhanced for the case of definite sums with parametric bounds. The behavior can be can be controlled via the optional keyword parametric.

sum(1/k, k=a..b);

$\sum _{k=a}^b\frac{1}{k}$

sum(1/k, k=a..b, parametric);

$\left\{\begin{array}{cc}0& a=b+1\\ \mathrm{\Psi }\left(b+1\right)-\mathrm{\Psi }\left(a\right)& 1\le a\mathbf{and}0\le b\\ \mathrm{\Psi }\left(-b\right)-\mathrm{\Psi }\left(1-a\right)& a\le 0\mathbf{and}b\le \mathrm{-1}\\ \mathrm{FAIL}& \mathrm{otherwise}\end{array}\right.$

In addition to the sum command itself, the definite summation command SumTools[DefiniteSum][Definite] has been extended by a new option parametric.

with(SumTools):

DefiniteSum[Definite](binomial(2*k-3, k)/4^k, k=0..n, parametric);

$\left\{\begin{array}{cc}\frac{\left(\genfrac{}{}{0ex}{}{2n-1}{n}\right)\left(2n+4\right)}{4^{n+1}}& n\le 0\\ \frac{3}{4}& n=1\\ \frac{\left(\genfrac{}{}{0ex}{}{2n-1}{n}\right)\left(2n+4\right)}{4^{n+1}}+\frac{3}{8}& 2\le n\end{array}\right.$

For the case of non-parametric definite sums, handling of removable singularities has been improved. By default, they will be removed, but this can be disabled by setting _EnvFormal to false.

sum(1/GAMMA(k), k=-1..5);

$\frac{65}{24}$

_EnvFormal := false;

$\mathrm{\_EnvFormal}≔\mathrm{false}$

sum(1/GAMMA(k), k=-1..5);

Error, (in SumTools:-DefiniteSum:-ClosedForm) summand is singular in the interval of summation

Two new commands have been added to the SumTools package and its subpackages: BottomSequence and SummableSpace.

The indefinite summation commands SumTools[IndefiniteSum][Indefinite], SumTools[IndefiniteSum][Hypergeometric], and SumTools[IndefiniteSum][Rational] were extended by a new option failpoints.

A new optional argument was added to the command SumTools[Hypergeometric][Gosper] to return the rational certificate in Gosper's algorithm.

with(SumTools[Hypergeometric]):

Gosper((-1)^k*binomial(n,k), k, 'r');
r;

$-\frac{k{\left(\mathrm{-1}\right)}^k\left(\genfrac{}{}{0ex}{}{n}{k}\right)}{n}$

$-\frac{k}{n}$

The command SumTools[Hypergeometric][DefiniteSumAsymptotic] was enhanced to handle bivariate rational functions.

DefiniteSum(1/(m^2+k^2)^2, m, k, 0..m);

$\sum _{k=0}^m\frac{1}{{\left(k^2+m^2\right)}^2}$

DefiniteSumAsymptotic(1/(m^2+k^2)^2, m, k, 0..m);

$\frac{\mathrm{\pi }+2}{8m^3}+\frac{5}{8m^4}-\frac{1}{24m^5}+\mathrm{O}\left(\frac{1}{m^7}\right)$

The possible minimizations via the keyword option minimize in the command SumTools[Hypergeometric][SumDecomposition] were extended.

In Maple 15, the RegularChains library offers a variety of tools to compute the real solutions of polynomial systems. The three new commands RealTriangularize, LazyRealTriangularize, and SamplePoints deal with arbitrary semi-algebraic systems. That is, given any system $S$ of polynomial equations, polynomial inequations and polynomial inequalities (strict or large) these commands produce information about the real solutions of this system.

RegularChains[RealTriangularize] returns a full description of the real solutions of $S$: it computes a family of simpler systems such that a point is a solution of $S$ if and only if it is a solution of one of the simpler systems.  Each simpler system has a triangular shape and remarkable properties: for this reason it is called a regular semi-algebraic system and the set of the simpler systems is called a full triangular decomposition of $S$.

RegularChains[LazyRealTriangularize] allows the user to compute a triangular decomposition of $S$ in an interactive manner. This feature is particularly well adapted for systems that are hard to solve.  For such systems, LazyRealTriangularize returns the components of $S$ of maximum dimension together with unevaluated recursive calls, such that, when fully evaluated, these calls produce the other components of S (which are generally harder to compute).

RegularChains[SamplePoints] is even a lazier (and thus much cheaper) way of solving: it produces at least one sample point per connected component of the solution set of $S$. This way of solving is often sufficient in practical problems.

RegularChains[Display] is a new pretty-printing command that handles any object types in used in the RegularChains library.

RegularChains[ChainTools][Extend] is a new command that decomposes a triangular set into regular chains.

RegularChains[ParametricSystemTools][RealRootClassification] has two new output options, namely formula and samples.  These options allow you to obtain either a formal description or simply sample points of the computed set.

with(RegularChains):

R := PolynomialRing([z,y,x]):

The Zeck algebraic surface is defined by the following equation to which we added inequality constraints in order to select part of this surface

F := [x^2+y^2-z^3*(1-z) = 0, 5*y> 1, z<=2];

$F≔\left[x^2+y^2-z^3\left(1-z\right)=0\&comma;1<5y\&comma;z\le 2\right]$

Below is a complete description of the real solutions in terms of formulas  

RealTriangularize(F, R,output=record);

$\left\{\begin{array}{cc}{z}^4-z^3+y^2+x^2=0& \\ 2-z>0& \\ 256x^2+256y^2<27& \\ 5y-1>0& \end{array}\right.,\left\{\begin{array}{cc}4z-3=0& \\ 256y^2+256x^2-27=0& \\ 5y-1>0& \\ 6400x^2<419& \end{array}\right.$

Now we provide witness solutions

SamplePoints(F, R,output=record);

$\left\{\begin{array}{cc}z=\left[\frac{67}{128}\&comma;\frac{17}{32}\right]& \\ y=\frac{269}{1024}& \\ x=0& \end{array}\right.,\left\{\begin{array}{cc}z=\left[\frac{29}{32}\&comma;\frac{117}{128}\right]& \\ y=\frac{269}{1024}& \\ x=0& \end{array}\right.,\left\{\begin{array}{cc}z=\frac{3}{4}& \\ y=\left[\frac{83}{256}\&comma;\frac{21}{64}\right]& \\ x=0& \end{array}\right.$

A snow flake can be described by the following equation

F2 := [x^3+y^2*z^3-y*z^4 ];

$\mathrm{F2}≔\left[y^2{z}^3-y{z}^4+x^3\right]$

Below is a complete description of the real solutions.

RealTriangularize(F2, R, output=record);

$\left\{\begin{array}{cc}y{z}^4-y^2{z}^3-x^3=0& \\ 27y^5+256x^3>0& \\ y>0& \\ x\ne 0& \end{array}\right.,\left\{\begin{array}{cc}y{z}^4-y^2{z}^3-x^3=0& \\ 27y^5+256x^3<0& \\ y<0& \\ x\ne 0& \end{array}\right.,\left\{\begin{array}{cc}z-y=0& \\ y\ne 0& \\ x=0& \end{array}\right.,\left\{\begin{array}{cc}z=0& \\ y\ne 0& \\ x=0& \end{array}\right.,\left\{\begin{array}{cc}64z^3-16y{z}^2-12y^{2}z-9y^3=0& \\ 27y^5+256x^3=0& \\ x\ne 0& \end{array}\right.,\left\{\begin{array}{cc}y=0& \\ x=0& \end{array}\right.$

The RegularChains library can be used in RootFinding[Parametric][CellDecomposition] through this command's new option, method.

with(RootFinding[Parametric]):

m := CellDecomposition([x^2+a*x+b = 0], [x], 'method' = 'RC'):

CellPlot(m, 'samplepoints');

NumberOfSolutions(m);

$\left[\left[1\&comma;2\right]\&comma;\left[2\&comma;2\right]\&comma;\left[3\&comma;0\right]\&comma;\left[4\&comma;2\right]\right]$

unassign('m'):