The useunits option to the plot and plot3d commands has been overhauled. It now rescales the plot data to conform to the units you specify (in most cases; there is one exception detailed on its help page).

height := acceleration/2 * time^2 + initial_velocity * time;

$\mathrm{height}≔\frac{1}{2}\mathrm{acceleration}{\mathrm{time}}^2+\mathrm{initial\_velocity}\mathrm{time}$

acceleration := -9.81*Unit(m/s^2);

$\mathrm{acceleration}≔-9.81⟦\frac{m}{s^2}⟧$

initial_velocity := 19*Unit(m/s);

$\mathrm{initial\_velocity}≔19⟦\frac{m}{s}⟧$

The default units are seconds on the horizontal axis and meters on the vertical axis.

plot(height, time = 0 .. 4*Unit(s));

We can override this with the useunits option. Note that the plot data are scaled.

plot(height, time = 0 .. 4*Unit(s), useunits=[ms, ft]);

If you specify an incompatible unit, Maple issues an error.

plot(height, time = 0 .. 4*Unit(s), useunits=[ms, ft/s]);

Error, (in plot) incompatible units found: expected units compatible with Units:-Unit(ft/s), but found -4.905000000*Units:-Unit(m/s^2)*time^2+19*Units:-Unit(m/s)*time

This also works with the plot3d command.

unassign('initial_velocity');

plot3d(height, time = 0 .. 10*Unit(s), initial_velocity = 0 .. 20*Unit(m/s));

plot3d(height, time = 0 .. 10*Unit(s), initial_velocity = 0 .. 20*Unit(m/s), useunits=[ms, ft/s, ft]);

As of Maple 2022, Maple accepts units in calls to the plot and plot3d commands when the object to be plotted is a list of procedures.

f_expr := 2.5*sin(t)*Unit(m);

$\mathrm{f\_expr}≔2.5\sin \left(t\right)⟦m⟧$

f_proc := t -> 2.5*sin(t)*Unit(m);

$\mathrm{f\_proc}≔t\mapsto 2.5\cdot \sin \left(t\right)\cdot ⟦m⟧$

g_expr := 1400*cos(t)*Unit(mm);

$\mathrm{g\_expr}≔1400\cos \left(t\right)⟦\mathrm{mm}⟧$

g_proc := t -> 1400*cos(t)*Unit(mm);

$\mathrm{g\_proc}≔t\mapsto 1400\cdot \cos \left(t\right)\cdot ⟦\mathrm{mm}⟧$

The following three calls to plot already worked as expected before Maple 2022.

plot(f_expr, t=0..2*Pi);

plot([f_expr, g_expr], t=0..2*Pi);

plot(f_proc, 0..2*Pi, useunits);

The following one, however, works only from Maple 2022 onwards.

plot([f_proc, g_proc], 0..2*Pi, useunits);

The plot and plot3d commands have supported parametric plots for many, many releases. They have supported units since Maple 13. However, before Maple 2022, parametric plots have not supported units. Now they do. Here is a 2-D example with a spiral:

radius := 2*sqrt(t/Unit(s)) * Unit(m);

$\mathrm{radius}≔2\sqrt{\frac{t}{⟦s⟧}}⟦m⟧$

plot([radius * sin(t/Unit(s)), radius * cos(t/Unit(s)), t = 0 .. 10*Unit(s)]);

This 3-D example also uses the useunits option discussed above; it also applies to parametric plots.

c1 := [cos(x) - 2*cos(0.4*y*Unit(Hz)), sin(x) - 2*sin(0.4*y*Unit(Hz)), y];

$\mathrm{c1}≔\left[\cos \left(x\right)-2\cos \left(0.4y⟦\mathrm{Hz}⟧\right)\,\sin \left(x\right)-2\sin \left(0.4y⟦\mathrm{Hz}⟧\right)\,y\right]$

c2 := [cos(x) + 2*cos(0.4*y*Unit(Hz)), sin(x) + 2*sin(0.4*y*Unit(Hz)), y];

$\mathrm{c2}≔\left[\cos \left(x\right)+2\cos \left(0.4y⟦\mathrm{Hz}⟧\right)\,\sin \left(x\right)+2\sin \left(0.4y⟦\mathrm{Hz}⟧\right)\,y\right]$

c3 := [cos(x) + 2*sin(0.4*y*Unit(Hz)), sin(x) - 2*cos(0.4*y*Unit(Hz)), y];

$\mathrm{c3}≔\left[\cos \left(x\right)+2\sin \left(0.4y⟦\mathrm{Hz}⟧\right)\,\sin \left(x\right)-2\cos \left(0.4y⟦\mathrm{Hz}⟧\right)\,y\right]$

c4 := [cos(x) - 2*sin(0.4*y*Unit(Hz)), sin(x) + 2*cos(0.4*y*Unit(Hz)), y];

$\mathrm{c4}≔\left[\cos \left(x\right)-2\sin \left(0.4y⟦\mathrm{Hz}⟧\right)\,\sin \left(x\right)+2\cos \left(0.4y⟦\mathrm{Hz}⟧\right)\,y\right]$

plot3d({c1, c2, c3, c4}, x = 0 .. 2*Pi, y = 0 .. 10*Unit(s), grid = [25, 15]);

plot3d({c1, c2, c3, c4}, x = 0 .. 2*Pi, y = 0 .. 10*Unit(s), grid = [25, 15], useunits=[default, default, Unit(ms)]);